[gentoo-commits] repo/gentoo:master commit in: net-misc/remmina/

[Ben Kohler]

commit:     d49fe73c131b1e8b1a0b5816d958497004b1e5dc
Author:     Ben Kohler <bkohler <AT> gentoo <DOT> org>
AuthorDate: Wed Dec 22 12:41:46 2021 +0000
Commit:     Ben Kohler <bkohler <AT> gentoo <DOT> org>
CommitDate: Wed Dec 22 12:41:46 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=d49fe73c

net-misc/remmina: bump to 1.4.23

This version was supposed to have optional appindicator support but it
doesn't seem to be ready yet.

This does include a missing build dep fix for spice.

Package-Manager: Portage-3.0.30, Repoman-3.0.3
Signed-off-by: Ben Kohler <bkohler <AT> gentoo.org>

 net-misc/remmina/Manifest              |   1 +
 net-misc/remmina/remmina-1.4.23.ebuild | 100 +++++++++++++++++++++++++++++++++
 2 files changed, 101 insertions(+)

diff --git a/net-misc/remmina/Manifest b/net-misc/remmina/Manifest
index 1647dce98715..6e7a73b09ce7 100644
--- a/net-misc/remmina/Manifest
+++ b/net-misc/remmina/Manifest
@@ -1,2 +1,3 @@
 DIST Remmina-v1.4.21.tar.gz 2982350 BLAKE2B d076db92290ead724e6b5c13beba2ef94d16e8209c5095e5db754a8b25ee236ed7a87b5ce29ac0b9424d3c55e5443467b1cc628fb80a0f63c59d915d9fc7839e SHA512 3fb7a29bf9e001203bdc5c176a0cf11a5c98638d605a02e2edbb16669b9e85526706c11e15bd2c308919ee6ef14217356bbafa0328ce337053bba20da6f2905a
 DIST Remmina-v1.4.22.tar.gz 3277782 BLAKE2B d9502406e9a534de18358d9d6a7790a5bb25a5be79ee9bfa390cc2c7de01e0852337834fbe1213b5f683bb948f124d44e4006a6650dd3794ee8a1f707307ed53 SHA512 8b5b8c92d5d732aec1530fdd5c1c7f74b9bfe9a9e8e990f21e92780d57b3642508c6a8c36c741bad8caa765a9709afbd577b26fe196cf71d883f924237212551
+DIST Remmina-v1.4.23.tar.gz 3280050 BLAKE2B b62789dba4a4f0a0a12f4cc1da68431b0c386b618f3bf7babe8946cba3753bdfd8799731a254c18cf58e8a43efe6980d638adc9512303dfb229c5b340d957402 SHA512 151baead9c8e8051f6da2139691aa5644ccdd5752e1dd1be572b72fab01773caf261bfe44ebebc8524a36b447ee335275e6522bd2b6b65d4f0a790c92bd291d4

diff --git a/net-misc/remmina/remmina-1.4.23.ebuild b/net-misc/remmina/remmina-1.4.23.ebuild
new file mode 100644
index 000000000000..fe7f549ab031
--- /dev/null
+++ b/net-misc/remmina/remmina-1.4.23.ebuild
@@ -0,0 +1,100 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake optfeature xdg
+
+MY_P="${PN^}-v${PV}"
+
+DESCRIPTION="A GTK+ RDP, SPICE, VNC and SSH client"
+HOMEPAGE="https://remmina.org/"
+SRC_URI="https://gitlab.com/Remmina/Remmina/-/archive/v${PV}/${MY_P}.tar.gz"
+
+LICENSE="GPL-2+-with-openssl-exception"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="crypt cups examples gnome-keyring gvnc kwallet nls spice ssh rdp telemetry vnc webkit x2go zeroconf"
+
+COMMON_DEPEND="
+	dev-libs/glib:2
+	dev-libs/json-glib
+	dev-libs/libappindicator:3
+	dev-libs/libpcre2
+	dev-libs/libsodium:=
+	dev-libs/openssl:0=
+	net-libs/libsoup:2.4
+	x11-libs/gdk-pixbuf
+	x11-libs/gtk+:3
+	x11-libs/libX11
+	x11-libs/libxkbfile
+	crypt? ( dev-libs/libgcrypt:0= )
+	gnome-keyring? ( app-crypt/libsecret )
+	gvnc? ( net-libs/gtk-vnc )
+	kwallet? ( kde-frameworks/kwallet )
+	rdp? ( >=net-misc/freerdp-2.0.0_rc4_p1129[X]
+		<net-misc/freerdp-3[X]
+		cups? ( net-print/cups:= ) )
+	spice? ( net-misc/spice-gtk[gtk3] )
+	ssh? ( net-libs/libssh:0=[sftp]
+		x11-libs/vte:2.91 )
+	vnc? ( net-libs/libvncserver[jpeg] )
+	webkit? ( net-libs/webkit-gtk:4 )
+	x2go? ( net-misc/pyhoca-cli )
+	zeroconf? ( >=net-dns/avahi-0.8-r2[dbus,gtk] )
+"
+BDEPEND="
+	dev-util/intltool
+	virtual/pkgconfig
+	nls? ( sys-devel/gettext )
+"
+DEPEND="
+	${COMMON_DEPEND}
+	app-emulation/spice-protocol
+"
+RDEPEND="
+	${COMMON_DEPEND}
+	virtual/freedesktop-icon-theme
+"
+
+DOCS=( AUTHORS CHANGELOG.md README.md THANKS.md )
+
+S="${WORKDIR}/${MY_P}"
+
+src_prepare() {
+	xdg_environment_reset
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DWITH_AVAHI=$(usex zeroconf)
+		-DWITH_CUPS=$(usex cups)
+		-DWITH_EXAMPLES=$(usex examples)
+		-DWITH_FREERDP=$(usex rdp)
+		-DWITH_FREERDP3=OFF
+		-DWITH_GCRYPT=$(usex crypt)
+		-DWITH_GETTEXT=$(usex nls)
+		-DWITH_ICON_CACHE=OFF
+		-DWITH_KF5WALLET=$(usex kwallet)
+		-DWITH_LIBSECRET=$(usex gnome-keyring)
+		-DWITH_LIBSSH=$(usex ssh)
+		-DWITH_LIBVNCSERVER=$(usex vnc)
+		-DWITH_NEWS=$(usex telemetry)
+		-DWITH_SPICE=$(usex spice)
+		-DWITH_TRANSLATIONS=$(usex nls)
+		-DWITH_UPDATE_DESKTOP_DB=OFF
+		-DWITH_VTE=$(usex ssh)
+		-DWITH_WWW=$(usex webkit)
+		-DWITH_X2GO=$(usex x2go)
+		# when this feature is stable, add python eclass usage to optionally enable
+		-DWITH_PYTHON=OFF
+	)
+	cmake_src_configure
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+
+	optfeature "encrypted VNC connections" net-libs/libvncserver[gcrypt]
+}