[gentoo-commits] gentoo-x86 commit in x11-misc/i3status: i3status-2.4.ebuild ChangeLog i3status-2.3.ebuild

[Kacper Kowalik (xarthisius)]

xarthisius    11/12/27 14:17:01

  Modified:             ChangeLog
  Added:                i3status-2.4.ebuild
  Removed:              i3status-2.3.ebuild
  Log:
  Version bump, drop old
  
  (Portage version: 2.2.0_alpha81/cvs/Linux x86_64)

Revision  Changes    Path
1.3                  x11-misc/i3status/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/i3status/ChangeLog?rev=1.3&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/i3status/ChangeLog?rev=1.3&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/i3status/ChangeLog?r1=1.2&r2=1.3

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/x11-misc/i3status/ChangeLog,v
retrieving revision 1.2
retrieving revision 1.3
diff -u -r1.2 -r1.3
--- ChangeLog	18 Nov 2011 09:32:09 -0000	1.2
+++ ChangeLog	27 Dec 2011 14:17:01 -0000	1.3
@@ -1,6 +1,12 @@
 # ChangeLog for x11-misc/i3status
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-misc/i3status/ChangeLog,v 1.2 2011/11/18 09:32:09 tetromino Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-misc/i3status/ChangeLog,v 1.3 2011/12/27 14:17:01 xarthisius Exp $
+
+*i3status-2.4 (27 Dec 2011)
+
+  27 Dec 2011; Kacper Kowalik <xarthisius@g.o> +i3status-2.4.ebuild,
+  -i3status-2.3.ebuild:
+  Version bump, drop old
 
   18 Nov 2011; Alexandre Rostovtsev <tetromino@g.o> i3status-2.3.ebuild:
   Update fcaps() error message for recent kernels (bug #390903). Acked by



1.1                  x11-misc/i3status/i3status-2.4.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/i3status/i3status-2.4.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/i3status/i3status-2.4.ebuild?rev=1.1&content-type=text/plain

Index: i3status-2.4.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-misc/i3status/i3status-2.4.ebuild,v 1.1 2011/12/27 14:17:01 xarthisius Exp $

EAPI=4

inherit toolchain-funcs versionator

DESCRIPTION="generates a status bar for dzen2, xmobar or similar"
HOMEPAGE="http://i3wm.org/i3status/"
SRC_URI="http://i3wm.org/${PN}/${P}.tar.bz2"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="+caps"

RDEPEND="dev-libs/confuse
	media-libs/alsa-lib
	net-wireless/wireless-tools"
DEPEND="${RDEPEND}
	caps? ( sys-libs/libcap )"

# borrowed from GSoC2010_Gentoo_Capabilities by constanze and flameyeys
# @FUNCTION: fcaps
# @USAGE: fcaps {uid:gid} {file-mode} {cap1[,cap2,...]} {file}
# @RETURN: 0 if all okay; non-zero if failure and fallback
# @DESCRIPTION:
# fcaps sets the specified capabilities in the effective and permitted set of
# the given file. In case of failure fcaps sets the given file-mode.
# Requires versionator.eclass
fcaps() {
	local uid_gid=$1
	local perms=$2
	local capset=$3
	local path=$4
	local res

	chmod $perms $path && \
	chown $uid_gid $path
	res=$?

	use caps || return $res

	#set the capability
	setcap "$capset=ep" "$path" &> /dev/null
	#check if the capabilitiy got set correctly
	setcap -v "$capset=ep" "$path" &> /dev/null
	res=$?

	if [ $res -ne 0 ]; then
		ewarn "Failed to set capabilities. Probable reason is missing kernel support."
		ewarn "Your kernel must have <FS>_FS_SECURITY enabled (e.g. EXT4_FS_SECURITY)"
		ewarn "where <FS> is the filesystem to store ${path}"
		if ! version_is_at_least 2.6.33 "$(uname -r)"; then
			ewarn "For kernel 2.6.32 or older, you will also need to enable"
			ewarn "SECURITY_FILE_CAPABILITIES."
		fi
		ewarn
		ewarn "Falling back to suid now..."
		chmod u+s ${path}
	fi
	return $res
}

pkg_setup() {
	tc-export CC
}

src_prepare() {
	sed -i -e "/@echo/d" -e "s:@\$(:\$(:g" -e "/setcap/d" Makefile || die
}

pkg_postinst() {
	fcaps 0:users 550 cap_net_admin "${ROOT}"/usr/bin/${PN}
	elog "You need to install x11-misc/xmobar or x11-misc/dzen to use ${PN}."
	elog "Please refer to manual: man ${PN}"
}