[gentoo-commits] repo/gentoo:master commit in: dev-libs/weston/

[James Le Cuirot]

commit:     64a36e616a2c524af2375f75dbee9b952fe2030a
Author:     James Le Cuirot <chewi <AT> gentoo <DOT> org>
AuthorDate: Fri Nov 16 23:01:44 2018 +0000
Commit:     James Le Cuirot <chewi <AT> gentoo <DOT> org>
CommitDate: Fri Nov 16 23:04:51 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=64a36e61

dev-libs/weston: Version bump to 5.0.0

Bug: https://bugs.gentoo.org/634572
Package-Manager: Portage-2.3.51, Repoman-2.3.12
Signed-off-by: James Le Cuirot <chewi <AT> gentoo.org>

 dev-libs/weston/Manifest            |   1 +
 dev-libs/weston/weston-5.0.0.ebuild | 150 ++++++++++++++++++++++++++++++++++++
 2 files changed, 151 insertions(+)

diff --git a/dev-libs/weston/Manifest b/dev-libs/weston/Manifest
index e4a6d59c72c..2c30fde70a9 100644
--- a/dev-libs/weston/Manifest
+++ b/dev-libs/weston/Manifest
@@ -1 +1,2 @@
 DIST weston-3.0.0.tar.xz 1300340 BLAKE2B 38b46ecca03ffee7832a561348cb1d6604db7e0add8b5629141ce61593ae250625d71c6716f02296157ea5a61764ff10561fa7ffc8f3c1426a4c86589b13b5c3 SHA512 b824c39f2a884f6d50d607613f447090621f684c96f7d905f25f6e500dabd03ecb2b1cd1030babc193c3417223cb220103abb792437e1a5ead7229a76b5c7a58
+DIST weston-5.0.0.tar.xz 1467496 BLAKE2B 514bc4c4f09dc8bc5b068c66cf14b86687bee1e691f7dfcb251a5ae7fe02389b48626ed02c97eff9334b43e227ea8b83beef48c53a83b4691f59a65af53ad61d SHA512 b6f97eca014ea47f3de0c5ddd89712f896cd66423d0eb499e1d88d35aab616cef1e735ebb8e0cefd8b60085314b6ec3d56b39d7c4776188bb56d58efc84a52cf

diff --git a/dev-libs/weston/weston-5.0.0.ebuild b/dev-libs/weston/weston-5.0.0.ebuild
new file mode 100644
index 00000000000..61c5f7776cc
--- /dev/null
+++ b/dev-libs/weston/weston-5.0.0.ebuild
@@ -0,0 +1,150 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+if [[ ${PV} = 9999* ]]; then
+	EGIT_REPO_URI="https://anongit.freedesktop.org/git/wayland/weston.git"
+	GIT_ECLASS="git-r3"
+	EXPERIMENTAL="true"
+fi
+
+inherit autotools readme.gentoo-r1 toolchain-funcs $GIT_ECLASS
+
+DESCRIPTION="Wayland reference compositor"
+HOMEPAGE="https://wayland.freedesktop.org/"
+
+if [[ $PV = 9999* ]]; then
+	SRC_URI="${SRC_PATCHES}"
+	KEYWORDS=""
+else
+	SRC_URI="https://wayland.freedesktop.org/releases/${P}.tar.xz"
+	KEYWORDS="~amd64 ~arm ~x86"
+fi
+
+LICENSE="MIT CC-BY-SA-3.0"
+SLOT="0"
+
+IUSE="colord dbus +drm editor examples fbdev +gles2 headless ivi jpeg +launch lcms rdp +resize-optimization screen-sharing static-libs +suid systemd test wayland-compositor webp +X xwayland"
+
+REQUIRED_USE="
+	drm? ( gles2 )
+	screen-sharing? ( rdp )
+	systemd? ( dbus )
+	test? ( headless xwayland )
+	wayland-compositor? ( gles2 )
+"
+
+RDEPEND="
+	>=dev-libs/libinput-0.8.0
+	>=dev-libs/wayland-1.12.0
+	>=dev-libs/wayland-protocols-1.13
+	lcms? ( media-libs/lcms:2 )
+	media-libs/libpng:0=
+	webp? ( media-libs/libwebp:0= )
+	jpeg? ( virtual/jpeg:0= )
+	>=x11-libs/cairo-1.11.3
+	>=x11-libs/libdrm-2.4.68
+	>=x11-libs/libxkbcommon-0.5.0
+	>=x11-libs/pixman-0.25.2
+	x11-misc/xkeyboard-config
+	fbdev? (
+		>=sys-libs/mtdev-1.1.0
+		>=virtual/udev-136
+	)
+	colord? ( >=x11-misc/colord-0.1.27 )
+	dbus? ( >=sys-apps/dbus-1.6 )
+	drm? (
+		>=media-libs/mesa-17.1[gbm]
+		>=sys-libs/mtdev-1.1.0
+		>=virtual/udev-136
+	)
+	editor? ( x11-libs/pango )
+	gles2? (
+		media-libs/mesa[gles2,wayland]
+	)
+	rdp? ( >=net-misc/freerdp-1.1.0:= )
+	systemd? (
+		sys-auth/pambase[systemd]
+		>=sys-apps/systemd-209[pam]
+	)
+	launch? ( sys-auth/pambase )
+	X? (
+		>=x11-libs/libxcb-1.9
+		x11-libs/libX11
+	)
+	xwayland? (
+		x11-base/xorg-server[wayland]
+		x11-libs/cairo[xcb]
+		>=x11-libs/libxcb-1.9
+		x11-libs/libXcursor
+	)
+"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+"
+
+src_prepare() {
+	default
+	if [[ ${PV} = 9999* ]]; then
+		eautoreconf
+	else
+		elibtoolize
+	fi
+}
+
+src_configure() {
+	local myconf=()
+
+	if use examples || use test; then
+		myconf+=( --enable-simple-clients )
+	else
+		myconf+=( --disable-simple-clients )
+	fi
+
+	econf \
+		$(use_enable examples demo-clients-install) \
+		$(use_enable fbdev fbdev-compositor) \
+		$(use_enable dbus) \
+		$(use_enable drm drm-compositor) \
+		$(use_enable headless headless-compositor) \
+		$(use_enable ivi ivi-shell) \
+		$(use_enable lcms) \
+		$(use_enable rdp rdp-compositor) \
+		$(use_enable wayland-compositor) \
+		$(use_enable X x11-compositor) \
+		$(use_enable launch weston-launch) \
+		$(use_enable colord) \
+		$(use_enable gles2 egl) \
+		$(use_enable resize-optimization) \
+		$(use_enable screen-sharing) \
+		$(use_enable suid setuid-install) \
+		$(use_enable systemd systemd-login) \
+		$(use_enable systemd systemd-notify) \
+		$(use_enable xwayland) \
+		$(use_enable xwayland xwayland-test) \
+		$(use_with jpeg) \
+		$(use_with webp) \
+		--with-cairo=image \
+		--disable-junit-xml \
+		--disable-simple-dmabuf-drm-client \
+		--disable-simple-dmabuf-v4l-client \
+		--disable-simple-egl-clients \
+		--disable-vaapi-recorder \
+		"${myconf[@]}"
+}
+
+src_test() {
+	export XDG_RUNTIME_DIR="${T}/runtime-dir"
+	mkdir "${XDG_RUNTIME_DIR}" || die
+	chmod 0700 "${XDG_RUNTIME_DIR}" || die
+
+	cd "${BUILD_DIR}" || die
+	emake check
+}
+
+src_install() {
+	default
+
+	readme.gentoo_create_doc
+}