1 |
floppym 12/08/28 20:49:34 |
2 |
|
3 |
Modified: chromium-9999-r1.ebuild ChangeLog |
4 |
Added: chromium-23.0.1246.0.ebuild |
5 |
Log: |
6 |
Version bump for dev channel release. |
7 |
|
8 |
(Portage version: 2.2.0_alpha123/cvs/Linux x86_64) |
9 |
|
10 |
Revision Changes Path |
11 |
1.132 www-client/chromium/chromium-9999-r1.ebuild |
12 |
|
13 |
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/chromium/chromium-9999-r1.ebuild?rev=1.132&view=markup |
14 |
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/chromium/chromium-9999-r1.ebuild?rev=1.132&content-type=text/plain |
15 |
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/chromium/chromium-9999-r1.ebuild?r1=1.131&r2=1.132 |
16 |
|
17 |
Index: chromium-9999-r1.ebuild |
18 |
=================================================================== |
19 |
RCS file: /var/cvsroot/gentoo-x86/www-client/chromium/chromium-9999-r1.ebuild,v |
20 |
retrieving revision 1.131 |
21 |
retrieving revision 1.132 |
22 |
diff -u -r1.131 -r1.132 |
23 |
--- chromium-9999-r1.ebuild 25 Aug 2012 17:23:29 -0000 1.131 |
24 |
+++ chromium-9999-r1.ebuild 28 Aug 2012 20:49:34 -0000 1.132 |
25 |
@@ -1,6 +1,6 @@ |
26 |
# Copyright 1999-2012 Gentoo Foundation |
27 |
# Distributed under the terms of the GNU General Public License v2 |
28 |
-# $Header: /var/cvsroot/gentoo-x86/www-client/chromium/chromium-9999-r1.ebuild,v 1.131 2012/08/25 17:23:29 floppym Exp $ |
29 |
+# $Header: /var/cvsroot/gentoo-x86/www-client/chromium/chromium-9999-r1.ebuild,v 1.132 2012/08/28 20:49:34 floppym Exp $ |
30 |
|
31 |
EAPI="4" |
32 |
PYTHON_DEPEND="2:2.6" |
33 |
@@ -201,6 +201,7 @@ |
34 |
\! -path 'third_party/mesa/*' \ |
35 |
\! -path 'third_party/modp_b64/*' \ |
36 |
\! -path 'third_party/mongoose/*' \ |
37 |
+ \! -path 'third_party/mt19937ar/*' \ |
38 |
\! -path 'third_party/npapi/*' \ |
39 |
\! -path 'third_party/openmax/*' \ |
40 |
\! -path 'third_party/ots/*' \ |
41 |
|
42 |
|
43 |
|
44 |
1.701 www-client/chromium/ChangeLog |
45 |
|
46 |
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/chromium/ChangeLog?rev=1.701&view=markup |
47 |
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/chromium/ChangeLog?rev=1.701&content-type=text/plain |
48 |
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/chromium/ChangeLog?r1=1.700&r2=1.701 |
49 |
|
50 |
Index: ChangeLog |
51 |
=================================================================== |
52 |
RCS file: /var/cvsroot/gentoo-x86/www-client/chromium/ChangeLog,v |
53 |
retrieving revision 1.700 |
54 |
retrieving revision 1.701 |
55 |
diff -u -r1.700 -r1.701 |
56 |
--- ChangeLog 25 Aug 2012 17:23:29 -0000 1.700 |
57 |
+++ ChangeLog 28 Aug 2012 20:49:34 -0000 1.701 |
58 |
@@ -1,6 +1,12 @@ |
59 |
# ChangeLog for www-client/chromium |
60 |
# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2 |
61 |
-# $Header: /var/cvsroot/gentoo-x86/www-client/chromium/ChangeLog,v 1.700 2012/08/25 17:23:29 floppym Exp $ |
62 |
+# $Header: /var/cvsroot/gentoo-x86/www-client/chromium/ChangeLog,v 1.701 2012/08/28 20:49:34 floppym Exp $ |
63 |
+ |
64 |
+*chromium-23.0.1246.0 (28 Aug 2012) |
65 |
+ |
66 |
+ 28 Aug 2012; Mike Gilbert <floppym@g.o> +chromium-23.0.1246.0.ebuild, |
67 |
+ chromium-9999-r1.ebuild: |
68 |
+ Version bump for dev channel release. |
69 |
|
70 |
*chromium-23.0.1243.2 (25 Aug 2012) |
71 |
|
72 |
|
73 |
|
74 |
|
75 |
1.1 www-client/chromium/chromium-23.0.1246.0.ebuild |
76 |
|
77 |
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/chromium/chromium-23.0.1246.0.ebuild?rev=1.1&view=markup |
78 |
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/chromium/chromium-23.0.1246.0.ebuild?rev=1.1&content-type=text/plain |
79 |
|
80 |
Index: chromium-23.0.1246.0.ebuild |
81 |
=================================================================== |
82 |
# Copyright 1999-2012 Gentoo Foundation |
83 |
# Distributed under the terms of the GNU General Public License v2 |
84 |
# $Header: /var/cvsroot/gentoo-x86/www-client/chromium/chromium-23.0.1246.0.ebuild,v 1.1 2012/08/28 20:49:34 floppym Exp $ |
85 |
|
86 |
EAPI="4" |
87 |
PYTHON_DEPEND="2:2.6" |
88 |
|
89 |
CHROMIUM_LANGS="am ar bg bn ca cs da de el en_GB es es_LA et fa fi fil fr gu he |
90 |
hi hr hu id it ja kn ko lt lv ml mr ms nb nl pl pt_BR pt_PT ro ru sk sl sr |
91 |
sv sw ta te th tr uk vi zh_CN zh_TW" |
92 |
|
93 |
inherit chromium eutils flag-o-matic multilib \ |
94 |
pax-utils portability python toolchain-funcs versionator virtualx |
95 |
|
96 |
DESCRIPTION="Open-source version of Google Chrome web browser" |
97 |
HOMEPAGE="http://chromium.org/" |
98 |
SRC_URI="http://commondatastorage.googleapis.com/chromium-browser-official/${P}.tar.bz2" |
99 |
|
100 |
LICENSE="BSD" |
101 |
SLOT="0" |
102 |
KEYWORDS="~amd64 ~x86" |
103 |
IUSE="bindist cups gnome gnome-keyring kerberos pulseaudio selinux" |
104 |
|
105 |
RDEPEND="app-arch/bzip2 |
106 |
cups? ( |
107 |
dev-libs/libgcrypt |
108 |
>=net-print/cups-1.3.11 |
109 |
) |
110 |
>=dev-lang/v8-3.11.10.6 |
111 |
dev-libs/dbus-glib |
112 |
>=dev-libs/elfutils-0.149 |
113 |
dev-libs/expat |
114 |
>=dev-libs/icu-49.1.1-r1 |
115 |
>=dev-libs/libevent-1.4.13 |
116 |
dev-libs/libxml2[icu] |
117 |
dev-libs/libxslt |
118 |
>=dev-libs/nss-3.12.3 |
119 |
gnome? ( >=gnome-base/gconf-2.24.0 ) |
120 |
gnome-keyring? ( >=gnome-base/gnome-keyring-2.28.2 ) |
121 |
>=media-libs/alsa-lib-1.0.19 |
122 |
media-libs/flac |
123 |
>=media-libs/libjpeg-turbo-1.2.0-r1 |
124 |
media-libs/libpng |
125 |
>=media-libs/libwebp-0.2.0_rc1 |
126 |
media-libs/speex |
127 |
pulseaudio? ( media-sound/pulseaudio ) |
128 |
sys-fs/udev |
129 |
sys-libs/zlib |
130 |
virtual/libusb:1 |
131 |
x11-libs/gtk+:2 |
132 |
x11-libs/libXinerama |
133 |
x11-libs/libXScrnSaver |
134 |
x11-libs/libXtst |
135 |
kerberos? ( virtual/krb5 ) |
136 |
selinux? ( sys-libs/libselinux )" |
137 |
DEPEND="${RDEPEND} |
138 |
>=dev-lang/nacl-toolchain-newlib-0_p9093 |
139 |
dev-lang/perl |
140 |
dev-lang/yasm |
141 |
dev-python/ply |
142 |
dev-python/simplejson |
143 |
>=dev-util/gperf-3.0.3 |
144 |
>=sys-devel/bison-2.4.3 |
145 |
sys-devel/flex |
146 |
>=sys-devel/make-3.81-r2 |
147 |
virtual/pkgconfig |
148 |
test? ( |
149 |
dev-python/pyftpdlib |
150 |
)" |
151 |
RDEPEND+=" |
152 |
!=www-client/chromium-9999 |
153 |
x11-misc/xdg-utils |
154 |
virtual/ttf-fonts" |
155 |
|
156 |
if ! has chromium_pkg_die ${EBUILD_DEATH_HOOKS}; then |
157 |
EBUILD_DEATH_HOOKS+=" chromium_pkg_die"; |
158 |
fi |
159 |
|
160 |
pkg_setup() { |
161 |
if [[ "${SLOT}" == "0" ]]; then |
162 |
CHROMIUM_SUFFIX="" |
163 |
else |
164 |
CHROMIUM_SUFFIX="-${SLOT}" |
165 |
fi |
166 |
CHROMIUM_HOME="/usr/$(get_libdir)/chromium-browser${CHROMIUM_SUFFIX}" |
167 |
|
168 |
# Make sure the build system will use the right tools, bug #340795. |
169 |
tc-export AR CC CXX RANLIB |
170 |
|
171 |
# Make sure the build system will use the right python, bug #344367. |
172 |
python_set_active_version 2 |
173 |
python_pkg_setup |
174 |
|
175 |
if ! use selinux; then |
176 |
chromium_suid_sandbox_check_kernel_config |
177 |
fi |
178 |
|
179 |
if use bindist; then |
180 |
elog "bindist enabled: H.264 video support will be disabled." |
181 |
else |
182 |
elog "bindist disabled: Resulting binaries may not be legal to re-distribute." |
183 |
fi |
184 |
} |
185 |
|
186 |
src_prepare() { |
187 |
ln -s /usr/$(get_libdir)/nacl-toolchain-newlib \ |
188 |
native_client/toolchain/linux_x86_newlib || die |
189 |
|
190 |
# zlib-1.2.5.1-r1 renames the OF macro in zconf.h, bug 383371. |
191 |
sed -i '1i#define OF(x) x' \ |
192 |
third_party/zlib/contrib/minizip/{ioapi,{,un}zip}.h || die |
193 |
|
194 |
# Fix build without NaCl glibc toolchain. |
195 |
epatch "${FILESDIR}/${PN}-ppapi-r0.patch" |
196 |
|
197 |
# Missing gyp files in tarball. |
198 |
# https://code.google.com/p/chromium/issues/detail?id=144823 |
199 |
if [[ -e chrome/test/data/nacl/nacl_test_data.gyp ]]; then |
200 |
die "tarball fixed, please remove workaround" |
201 |
fi |
202 |
|
203 |
mkdir -p chrome/test/data/nacl |
204 |
cat > chrome/test/data/nacl/nacl_test_data.gyp <<-EOF |
205 |
{ |
206 |
'targets': [ |
207 |
{ |
208 |
'target_name': 'nacl_tests', |
209 |
'type': 'none', |
210 |
}, |
211 |
], |
212 |
} |
213 |
EOF |
214 |
|
215 |
epatch_user |
216 |
|
217 |
# Remove most bundled libraries. Some are still needed. |
218 |
find third_party -type f \! -iname '*.gyp*' \ |
219 |
\! -path 'third_party/WebKit/*' \ |
220 |
\! -path 'third_party/angle/*' \ |
221 |
\! -path 'third_party/cacheinvalidation/*' \ |
222 |
\! -path 'third_party/cld/*' \ |
223 |
\! -path 'third_party/ffmpeg/*' \ |
224 |
\! -path 'third_party/flac/flac.h' \ |
225 |
\! -path 'third_party/flot/*' \ |
226 |
\! -path 'third_party/gpsd/*' \ |
227 |
\! -path 'third_party/harfbuzz/*' \ |
228 |
\! -path 'third_party/hunspell/*' \ |
229 |
\! -path 'third_party/hyphen/*' \ |
230 |
\! -path 'third_party/iccjpeg/*' \ |
231 |
\! -path 'third_party/jsoncpp/*' \ |
232 |
\! -path 'third_party/khronos/*' \ |
233 |
\! -path 'third_party/launchpad_translations/*' \ |
234 |
\! -path 'third_party/leveldatabase/*' \ |
235 |
\! -path 'third_party/libjingle/*' \ |
236 |
\! -path 'third_party/libphonenumber/*' \ |
237 |
\! -path 'third_party/libsrtp/*' \ |
238 |
\! -path 'third_party/libusb/libusb.h' \ |
239 |
\! -path 'third_party/libva/*' \ |
240 |
\! -path 'third_party/libvpx/*' \ |
241 |
\! -path 'third_party/libxml/chromium/*' \ |
242 |
\! -path 'third_party/libXNVCtrl/*' \ |
243 |
\! -path 'third_party/libyuv/*' \ |
244 |
\! -path 'third_party/lss/*' \ |
245 |
\! -path 'third_party/mesa/*' \ |
246 |
\! -path 'third_party/modp_b64/*' \ |
247 |
\! -path 'third_party/mongoose/*' \ |
248 |
\! -path 'third_party/mt19937ar/*' \ |
249 |
\! -path 'third_party/npapi/*' \ |
250 |
\! -path 'third_party/openmax/*' \ |
251 |
\! -path 'third_party/ots/*' \ |
252 |
\! -path 'third_party/protobuf/*' \ |
253 |
\! -path 'third_party/qcms/*' \ |
254 |
\! -path 'third_party/re2/*' \ |
255 |
\! -path 'third_party/scons-2.0.1/*' \ |
256 |
\! -path 'third_party/sfntly/*' \ |
257 |
\! -path 'third_party/skia/*' \ |
258 |
\! -path 'third_party/smhasher/*' \ |
259 |
\! -path 'third_party/speex/*' \ |
260 |
\! -path 'third_party/sqlite/*' \ |
261 |
\! -path 'third_party/tlslite/*' \ |
262 |
\! -path 'third_party/trace-viewer/*' \ |
263 |
\! -path 'third_party/undoview/*' \ |
264 |
\! -path 'third_party/v8-i18n/*' \ |
265 |
\! -path 'third_party/webdriver/*' \ |
266 |
\! -path 'third_party/webgl_conformance/*' \ |
267 |
\! -path 'third_party/webrtc/*' \ |
268 |
\! -path 'third_party/zlib/*' \ |
269 |
-delete || die |
270 |
|
271 |
local v8_bundled="$(chromium_bundled_v8_version)" |
272 |
local v8_installed="$(chromium_installed_v8_version)" |
273 |
einfo "V8 version: bundled - ${v8_bundled}; installed - ${v8_installed}" |
274 |
|
275 |
# Remove bundled v8. |
276 |
find v8 -type f \! -iname '*.gyp*' -delete || die |
277 |
|
278 |
# The implementation files include v8 headers with full path, |
279 |
# like #include "v8/include/v8.h". Make sure the system headers |
280 |
# will be used. |
281 |
# TODO: find a solution that can be upstreamed. |
282 |
rmdir v8/include || die |
283 |
ln -s /usr/include v8/include || die |
284 |
|
285 |
# Make sure the build system will use the right python, bug #344367. |
286 |
# Only convert directories that need it, to save time. |
287 |
python_convert_shebangs -q -r 2 build tools |
288 |
} |
289 |
|
290 |
src_configure() { |
291 |
local myconf="" |
292 |
|
293 |
# Never tell the build system to "enable" SSE2, it has a few unexpected |
294 |
# additions, bug #336871. |
295 |
myconf+=" -Ddisable_sse2=1" |
296 |
|
297 |
# Disable tcmalloc, it causes problems with e.g. NVIDIA |
298 |
# drivers, bug #413637. |
299 |
myconf+=" -Dlinux_use_tcmalloc=0" |
300 |
|
301 |
# Disable glibc Native Client toolchain, we don't need it (bug #417019). |
302 |
myconf+=" -Ddisable_glibc=1" |
303 |
|
304 |
# Make it possible to remove third_party/adobe. |
305 |
echo > "${T}/flapper_version.h" || die |
306 |
myconf+=" -Dflapper_version_h_file=${T}/flapper_version.h" |
307 |
|
308 |
# Use system-provided libraries. |
309 |
# TODO: use_system_ffmpeg |
310 |
# TODO: use_system_hunspell (upstream changes needed). |
311 |
# TODO: use_system_speex (needs additional shims, bug #432748). |
312 |
# TODO: use_system_ssl (http://crbug.com/58087). |
313 |
# TODO: use_system_sqlite (http://crbug.com/22208). |
314 |
# TODO: use_system_vpx |
315 |
# TODO: use_system_zlib (forked, bug #432746). |
316 |
myconf+=" |
317 |
-Duse_system_bzip2=1 |
318 |
-Duse_system_flac=1 |
319 |
-Duse_system_icu=1 |
320 |
-Duse_system_libevent=1 |
321 |
-Duse_system_libjpeg=1 |
322 |
-Duse_system_libpng=1 |
323 |
-Duse_system_libusb=1 |
324 |
-Duse_system_libwebp=1 |
325 |
-Duse_system_libxml=1 |
326 |
-Duse_system_speex=0 |
327 |
-Duse_system_v8=1 |
328 |
-Duse_system_xdg_utils=1 |
329 |
-Duse_system_yasm=1 |
330 |
-Duse_system_zlib=0" |
331 |
|
332 |
# Optional dependencies. |
333 |
# TODO: linux_link_kerberos, bug #381289. |
334 |
myconf+=" |
335 |
$(gyp_use cups) |
336 |
$(gyp_use gnome use_gconf) |
337 |
$(gyp_use gnome-keyring use_gnome_keyring) |
338 |
$(gyp_use gnome-keyring linux_link_gnome_keyring) |
339 |
$(gyp_use kerberos) |
340 |
$(gyp_use pulseaudio) |
341 |
$(gyp_use selinux selinux)" |
342 |
|
343 |
# Use explicit library dependencies instead of dlopen. |
344 |
# This makes breakages easier to detect by revdep-rebuild. |
345 |
myconf+=" |
346 |
-Dlinux_link_gsettings=1" |
347 |
|
348 |
if ! use selinux; then |
349 |
# Enable SUID sandbox. |
350 |
myconf+=" |
351 |
-Dlinux_sandbox_path=${CHROMIUM_HOME}/chrome_sandbox |
352 |
-Dlinux_sandbox_chrome_path=${CHROMIUM_HOME}/chrome" |
353 |
fi |
354 |
|
355 |
# Never use bundled gold binary. Disable gold linker flags for now. |
356 |
myconf+=" |
357 |
-Dlinux_use_gold_binary=0 |
358 |
-Dlinux_use_gold_flags=0" |
359 |
|
360 |
if ! use bindist; then |
361 |
# Enable H.624 support in bundled ffmpeg. |
362 |
myconf+=" -Dproprietary_codecs=1 -Dffmpeg_branding=Chrome" |
363 |
fi |
364 |
|
365 |
local myarch="$(tc-arch)" |
366 |
if [[ $myarch = amd64 ]] ; then |
367 |
myconf+=" -Dtarget_arch=x64" |
368 |
elif [[ $myarch = x86 ]] ; then |
369 |
myconf+=" -Dtarget_arch=ia32" |
370 |
else |
371 |
die "Failed to determine target arch, got '$myarch'." |
372 |
fi |
373 |
|
374 |
# Make sure that -Werror doesn't get added to CFLAGS by the build system. |
375 |
# Depending on GCC version the warnings are different and we don't want |
376 |
# the build to fail because of that. |
377 |
myconf+=" -Dwerror=" |
378 |
|
379 |
# Avoid CFLAGS problems, bug #352457, bug #390147. |
380 |
if ! use custom-cflags; then |
381 |
replace-flags "-Os" "-O2" |
382 |
strip-flags |
383 |
fi |
384 |
|
385 |
egyp_chromium ${myconf} || die |
386 |
} |
387 |
|
388 |
src_compile() { |
389 |
local test_targets |
390 |
for x in base cacheinvalidation crypto \ |
391 |
googleurl gpu media net printing sql; do |
392 |
test_targets+=" ${x}_unittests" |
393 |
done |
394 |
|
395 |
local make_targets="chrome chromedriver" |
396 |
if ! use selinux; then |
397 |
make_targets+=" chrome_sandbox" |
398 |
fi |
399 |
if use test; then |
400 |
make_targets+=$test_targets |
401 |
fi |
402 |
|
403 |
# See bug #410883 for more info about the .host mess. |
404 |
emake ${make_targets} BUILDTYPE=Release V=1 \ |
405 |
CC.host="$(tc-getCC)" CFLAGS.host="${CFLAGS}" \ |
406 |
CXX.host="$(tc-getCXX)" CXXFLAGS.host="${CXXFLAGS}" \ |
407 |
LINK.host="$(tc-getCXX)" LDFLAGS.host="${LDFLAGS}" \ |
408 |
AR.host="$(tc-getAR)" || die |
409 |
|
410 |
pax-mark m out/Release/chrome |
411 |
if use test; then |
412 |
for x in $test_targets; do |
413 |
pax-mark m out/Release/${x} |
414 |
done |
415 |
fi |
416 |
} |
417 |
|
418 |
src_test() { |
419 |
# For more info see bug #350349. |
420 |
local mylocale='en_US.utf8' |
421 |
if ! locale -a | grep -q "$mylocale"; then |
422 |
eerror "${PN} requires ${mylocale} locale for tests" |
423 |
eerror "Please read the following guides for more information:" |
424 |
eerror " http://www.gentoo.org/doc/en/guide-localization.xml" |
425 |
eerror " http://www.gentoo.org/doc/en/utf-8.xml" |
426 |
die "locale ${mylocale} is not supported" |
427 |
fi |
428 |
|
429 |
# For more info see bug #370957. |
430 |
if [[ $UID -eq 0 ]]; then |
431 |
die "Tests must be run as non-root. Please use FEATURES=userpriv." |
432 |
fi |
433 |
|
434 |
runtest() { |
435 |
local cmd=$1 |
436 |
shift |
437 |
local filter="--gtest_filter=$(IFS=:; echo "-${*}")" |
438 |
einfo "${cmd}" "${filter}" |
439 |
LC_ALL="${mylocale}" VIRTUALX_COMMAND="${cmd}" virtualmake "${filter}" |
440 |
} |
441 |
|
442 |
local excluded_base_unittests=( |
443 |
"ICUStringConversionsTest.*" # bug #350347 |
444 |
"MessagePumpLibeventTest.*" # bug #398591 |
445 |
) |
446 |
runtest out/Release/base_unittests "${excluded_base_unittests[@]}" |
447 |
|
448 |
runtest out/Release/cacheinvalidation_unittests |
449 |
runtest out/Release/crypto_unittests |
450 |
runtest out/Release/googleurl_unittests |
451 |
runtest out/Release/gpu_unittests |
452 |
runtest out/Release/media_unittests |
453 |
|
454 |
local excluded_net_unittests=( |
455 |
"NetUtilTest.IDNToUnicode*" # bug 361885 |
456 |
"NetUtilTest.FormatUrl*" # see above |
457 |
"DnsConfigServiceTest.GetSystemConfig" # bug #394883 |
458 |
"CertDatabaseNSSTest.ImportServerCert_SelfSigned" # bug #399269 |
459 |
"URLFetcher*" # bug #425764 |
460 |
) |
461 |
runtest out/Release/net_unittests "${excluded_net_unittests[@]}" |
462 |
|
463 |
runtest out/Release/printing_unittests |
464 |
runtest out/Release/sql_unittests |
465 |
} |
466 |
|
467 |
src_install() { |
468 |
exeinto "${CHROMIUM_HOME}" |
469 |
doexe out/Release/chrome || die |
470 |
|
471 |
if ! use selinux; then |
472 |
doexe out/Release/chrome_sandbox || die |
473 |
fperms 4755 "${CHROMIUM_HOME}/chrome_sandbox" |
474 |
fi |
475 |
|
476 |
doexe out/Release/chromedriver || die |
477 |
|
478 |
doexe out/Release/nacl_helper{,_bootstrap} || die |
479 |
insinto "${CHROMIUM_HOME}" |
480 |
doins out/Release/nacl_irt_*.nexe || die |
481 |
doins out/Release/libppGoogleNaClPluginChrome.so || die |
482 |
|
483 |
newexe "${FILESDIR}"/chromium-launcher-r2.sh chromium-launcher.sh || die |
484 |
if [[ "${CHROMIUM_SUFFIX}" != "" ]]; then |
485 |
sed "s:chromium-browser:chromium-browser${CHROMIUM_SUFFIX}:g" \ |
486 |
-i "${ED}"/"${CHROMIUM_HOME}"/chromium-launcher.sh || die |
487 |
sed "s:chromium.desktop:chromium${CHROMIUM_SUFFIX}.desktop:g" \ |
488 |
-i "${ED}"/"${CHROMIUM_HOME}"/chromium-launcher.sh || die |
489 |
sed "s:plugins:plugins --user-data-dir=\${HOME}/.config/chromium${CHROMIUM_SUFFIX}:" \ |
490 |
-i "${ED}"/"${CHROMIUM_HOME}"/chromium-launcher.sh || die |
491 |
fi |
492 |
|
493 |
# It is important that we name the target "chromium-browser", |
494 |
# xdg-utils expect it; bug #355517. |
495 |
dosym "${CHROMIUM_HOME}/chromium-launcher.sh" /usr/bin/chromium-browser${CHROMIUM_SUFFIX} || die |
496 |
# keep the old symlink around for consistency |
497 |
dosym "${CHROMIUM_HOME}/chromium-launcher.sh" /usr/bin/chromium${CHROMIUM_SUFFIX} || die |
498 |
|
499 |
# Allow users to override command-line options, bug #357629. |
500 |
dodir /etc/chromium || die |
501 |
insinto /etc/chromium |
502 |
newins "${FILESDIR}/chromium.default" "default" || die |
503 |
|
504 |
pushd out/Release/locales > /dev/null || die |
505 |
chromium_remove_language_paks |
506 |
popd |
507 |
|
508 |
insinto "${CHROMIUM_HOME}" |
509 |
doins out/Release/*.pak || die |
510 |
|
511 |
doins -r out/Release/locales || die |
512 |
doins -r out/Release/resources || die |
513 |
|
514 |
newman out/Release/chrome.1 chromium${CHROMIUM_SUFFIX}.1 || die |
515 |
newman out/Release/chrome.1 chromium-browser${CHROMIUM_SUFFIX}.1 || die |
516 |
|
517 |
doexe out/Release/libffmpegsumo.so || die |
518 |
|
519 |
# Install icons and desktop entry. |
520 |
local branding size |
521 |
for size in 16 22 24 32 48 64 128 256 ; do |
522 |
case ${size} in |
523 |
16|32) branding="chrome/app/theme/default_100_percent/chromium" ;; |
524 |
*) branding="chrome/app/theme/chromium" ;; |
525 |
esac |
526 |
newicon -s ${size} "${branding}/product_logo_${size}.png" \ |
527 |
chromium-browser${CHROMIUM_SUFFIX}.png |
528 |
done |
529 |
|
530 |
local mime_types="text/html;text/xml;application/xhtml+xml;" |
531 |
mime_types+="x-scheme-handler/http;x-scheme-handler/https;" # bug #360797 |
532 |
mime_types+="x-scheme-handler/ftp;" # bug #412185 |
533 |
mime_types+="x-scheme-handler/mailto;x-scheme-handler/webcal;" # bug #416393 |
534 |
make_desktop_entry \ |
535 |
chromium-browser${CHROMIUM_SUFFIX} \ |
536 |
"Chromium${CHROMIUM_SUFFIX}" \ |
537 |
chromium-browser${CHROMIUM_SUFFIX} \ |
538 |
"Network;WebBrowser" \ |
539 |
"MimeType=${mime_types}\nStartupWMClass=chromium-browser" |
540 |
sed -e "/^Exec/s/$/ %U/" -i "${ED}"/usr/share/applications/*.desktop || die |
541 |
|
542 |
# Install GNOME default application entry (bug #303100). |
543 |
if use gnome; then |
544 |
dodir /usr/share/gnome-control-center/default-apps || die |
545 |
insinto /usr/share/gnome-control-center/default-apps |
546 |
newins "${FILESDIR}"/chromium-browser.xml chromium-browser${CHROMIUM_SUFFIX}.xml || die |
547 |
if [[ "${CHROMIUM_SUFFIX}" != "" ]]; then |
548 |
sed "s:chromium-browser:chromium-browser${CHROMIUM_SUFFIX}:g" -i \ |
549 |
"${ED}"/usr/share/gnome-control-center/default-apps/chromium-browser${CHROMIUM_SUFFIX}.xml |
550 |
fi |
551 |
fi |
552 |
} |