[gentoo-commits] gentoo-x86 commit in app-misc/mc: ChangeLog mc-4.7.0.4.ebuild

[Alex Alexander (wired)]

wired       10/04/02 15:13:33

  Modified:             ChangeLog
  Added:                mc-4.7.0.4.ebuild
  Log:
  4.7.0.4 version bump
  (Portage version: 2.2_rc67/cvs/Linux x86_64)

Revision  Changes    Path
1.195                app-misc/mc/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-misc/mc/ChangeLog?rev=1.195&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-misc/mc/ChangeLog?rev=1.195&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-misc/mc/ChangeLog?r1=1.194&r2=1.195

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-misc/mc/ChangeLog,v
retrieving revision 1.194
retrieving revision 1.195
diff -u -r1.194 -r1.195
--- ChangeLog	14 Mar 2010 17:44:20 -0000	1.194
+++ ChangeLog	2 Apr 2010 15:13:33 -0000	1.195
@@ -1,6 +1,11 @@
 # ChangeLog for app-misc/mc
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-misc/mc/ChangeLog,v 1.194 2010/03/14 17:44:20 armin76 Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-misc/mc/ChangeLog,v 1.195 2010/04/02 15:13:33 wired Exp $
+
+*mc-4.7.0.4 (02 Apr 2010)
+
+  02 Apr 2010; Alex Alexander <wired@g.o> +mc-4.7.0.4.ebuild:
+  4.7.0.4 version bump
 
   14 Mar 2010; Raúl Porcel <armin76@g.o> mc-4.7.0.3.ebuild:
   alpha/arm/ia64/s390/sh/sparc stable wrt #308383



1.1                  app-misc/mc/mc-4.7.0.4.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-misc/mc/mc-4.7.0.4.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-misc/mc/mc-4.7.0.4.ebuild?rev=1.1&content-type=text/plain

Index: mc-4.7.0.4.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-misc/mc/mc-4.7.0.4.ebuild,v 1.1 2010/04/02 15:13:33 wired Exp $

EAPI=3

inherit base

MY_P=${P/_/-}

DESCRIPTION="GNU Midnight Commander is a text based file manager"
HOMEPAGE="http://www.midnight-commander.org"
SRC_URI="http://www.midnight-commander.org/downloads/${MY_P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd ~x86-interix ~amd64-linux ~ppc-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x86-solaris"
IUSE="+edit gpm nls samba slang X"

RDEPEND=">=dev-libs/glib-2.8:2
	gpm? ( sys-libs/gpm )
	kernel_linux? ( sys-fs/e2fsprogs )
	samba? ( net-fs/samba )
	slang? ( >=sys-libs/slang-2 )
	!slang? ( sys-libs/ncurses )
	X? ( x11-libs/libX11
		x11-libs/libICE
		x11-libs/libXau
		x11-libs/libXdmcp
		x11-libs/libSM )"
DEPEND="${RDEPEND}
	dev-util/pkgconfig
	nls? ( sys-devel/gettext )"

S=${WORKDIR}/${MY_P}

src_configure() {
	local myscreen=ncurses
	use slang && myscreen=slang

	econf \
		--disable-dependency-tracking \
		$(use_enable nls) \
		--enable-vfs \
		$(use_enable kernel_linux vfs-undelfs) \
		--enable-charset \
		$(use_with X x) \
		$(use_with samba) \
		--with-configdir="${EPREFIX}"/etc/samba \
		--with-codepagedir="${EPREFIX}"/var/lib/samba/codepages \
		$(use_with gpm gpm-mouse) \
		--with-screen=${myscreen} \
		$(use_with edit)
}

src_install() {
	emake DESTDIR="${D}" install || die
	dodoc AUTHORS README
}

pkg_postinst() {
	elog "To enable exiting to latest working directory,"
	elog "put this into your ~/.bashrc:"
	elog ". ${EPREFIX}/usr/libexec/mc/mc.sh"
}