Get Gentoo!
gentoo.org sites
gentoo.org Wiki Bugs Forums Packages
Planet Archives Sources
Infra Status

Gentoo Archives: gentoo-commits

From: "Julian Ospald (hasufell)" <hasufell@g.o>
To: gentoo-commits@l.g.o
Subject: [gentoo-commits] gentoo-x86 commit in net-irc/hexchat: ChangeLog hexchat-2.9.6.1-r1.ebuild
Date: Sat, 26 Oct 2013 22:18:56
Message-Id: 20131026221852.941BA20047@flycatcher.gentoo.org
1 hasufell 13/10/26 22:18:52
2
3 Modified: ChangeLog
4 Added: hexchat-2.9.6.1-r1.ebuild
5 Log:
6 revbump backport sasl fix for inspircd
7
8 (Portage version: 2.2.7/cvs/Linux x86_64, signed Manifest commit with key E73C35B3)
9
10 Revision Changes Path
11 1.83 net-irc/hexchat/ChangeLog
12
13 file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-irc/hexchat/ChangeLog?rev=1.83&view=markup
14 plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-irc/hexchat/ChangeLog?rev=1.83&content-type=text/plain
15 diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-irc/hexchat/ChangeLog?r1=1.82&r2=1.83
16
17 Index: ChangeLog
18 ===================================================================
19 RCS file: /var/cvsroot/gentoo-x86/net-irc/hexchat/ChangeLog,v
20 retrieving revision 1.82
21 retrieving revision 1.83
22 diff -u -r1.82 -r1.83
23 --- ChangeLog 5 Oct 2013 02:22:40 -0000 1.82
24 +++ ChangeLog 26 Oct 2013 22:18:52 -0000 1.83
25 @@ -1,6 +1,12 @@
26 # ChangeLog for net-irc/hexchat
27 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
28 -# $Header: /var/cvsroot/gentoo-x86/net-irc/hexchat/ChangeLog,v 1.82 2013/10/05 02:22:40 hasufell Exp $
29 +# $Header: /var/cvsroot/gentoo-x86/net-irc/hexchat/ChangeLog,v 1.83 2013/10/26 22:18:52 hasufell Exp $
30 +
31 +*hexchat-2.9.6.1-r1 (26 Oct 2013)
32 +
33 + 26 Oct 2013; Julian Ospald <hasufell@g.o> +hexchat-2.9.6.1-r1.ebuild,
34 + +files/hexchat-2.9.6.1-sasl.patch:
35 + revbump backport sasl fix for inspircd
36
37 05 Oct 2013; Julian Ospald <hasufell@g.o> hexchat-9999.ebuild:
38 update live ebuild
39
40
41
42 1.1 net-irc/hexchat/hexchat-2.9.6.1-r1.ebuild
43
44 file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-irc/hexchat/hexchat-2.9.6.1-r1.ebuild?rev=1.1&view=markup
45 plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-irc/hexchat/hexchat-2.9.6.1-r1.ebuild?rev=1.1&content-type=text/plain
46
47 Index: hexchat-2.9.6.1-r1.ebuild
48 ===================================================================
49 # Copyright 1999-2013 Gentoo Foundation
50 # Distributed under the terms of the GNU General Public License v2
51 # $Header: /var/cvsroot/gentoo-x86/net-irc/hexchat/hexchat-2.9.6.1-r1.ebuild,v 1.1 2013/10/26 22:18:52 hasufell Exp $
52
53 EAPI=5
54
55 PYTHON_COMPAT=( python2_7 python3_3 )
56 inherit eutils fdo-mime gnome2-utils mono-env multilib python-single-r1
57
58 DESCRIPTION="Graphical IRC client based on XChat"
59 HOMEPAGE="http://hexchat.github.io/"
60 SRC_URI="http://dl.hexchat.org/hexchat/${P}.tar.xz"
61
62 LICENSE="GPL-2"
63 SLOT="0"
64 KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux"
65 IUSE="dbus fastscroll +gtk gtkspell ipv6 libcanberra libnotify libproxy nls ntlm perl +plugins plugin-checksum plugin-doat plugin-fishlim plugin-sysinfo python sexy spell ssl theme-manager"
66 REQUIRED_USE="gtkspell? ( spell )
67 plugin-checksum? ( plugins )
68 plugin-doat? ( plugins )
69 plugin-fishlim? ( plugins )
70 plugin-sysinfo? ( plugins )
71 python? ( ${PYTHON_REQUIRED_USE} )
72 sexy? ( spell )
73 ?? ( gtkspell sexy )"
74
75 RDEPEND="dev-libs/glib:2
76 dbus? ( >=dev-libs/dbus-glib-0.98 )
77 fastscroll? ( x11-libs/libXft )
78 gtk? ( x11-libs/gtk+:2 )
79 libcanberra? ( media-libs/libcanberra )
80 libproxy? ( net-libs/libproxy )
81 libnotify? ( x11-libs/libnotify )
82 nls? ( virtual/libintl )
83 ntlm? ( net-libs/libntlm )
84 perl? ( >=dev-lang/perl-5.8.0 )
85 plugin-sysinfo? ( sys-apps/pciutils )
86 python? ( ${PYTHON_DEPS} )
87 spell? (
88 app-text/enchant
89 gtkspell? ( app-text/gtkspell:2 )
90 sexy? ( x11-libs/libsexy )
91 !gtkspell? ( !sexy? ( dev-libs/libxml2 ) )
92 )
93 ssl? ( dev-libs/openssl:0 )
94 theme-manager? ( dev-lang/mono )"
95 DEPEND="${RDEPEND}
96 app-arch/xz-utils
97 virtual/pkgconfig
98 nls? ( sys-devel/gettext )
99 theme-manager? ( dev-util/monodevelop )"
100
101 pkg_setup() {
102 use python && python-single-r1_pkg_setup
103 if use theme-manager ; then
104 mono-env_pkg_setup
105 export XDG_CACHE_HOME="${T}/.cache"
106 fi
107 }
108
109 src_prepare() {
110 epatch "${FILESDIR}"/${P}-sasl.patch
111 epatch_user
112 }
113
114 src_configure() {
115 local myspellconf
116 if use spell ; then
117 if use gtkspell ; then
118 myspellconf="--enable-spell=gtkspell"
119 elif use sexy ; then
120 myspellconf="--enable-spell=libsexy"
121 else
122 myspellconf="--enable-spell=static"
123 fi
124 else
125 myspellconf="--disable-spell"
126 fi
127
128 econf \
129 $(use_enable nls) \
130 $(use_enable libproxy socks) \
131 $(use_enable ipv6) \
132 $(use_enable fastscroll xft) \
133 $(use_enable ssl openssl) \
134 $(use_enable gtk gtkfe) \
135 $(use_enable !gtk textfe) \
136 $(usex python "--enable-python=${EPYTHON}" "--disable-python") \
137 $(use_enable perl) \
138 $(use_enable plugins plugin) \
139 $(use_enable plugin-checksum checksum) \
140 $(use_enable plugin-doat doat) \
141 $(use_enable plugin-fishlim fishlim) \
142 $(use_enable plugin-sysinfo sysinfo) \
143 $(use_enable dbus) \
144 $(use_enable libnotify) \
145 $(use_enable libcanberra) \
146 --enable-shm \
147 ${myspellconf} \
148 $(use_enable ntlm) \
149 $(use_enable libproxy) \
150 --enable-minimal-flags \
151 $(use_with theme-manager)
152 }
153
154 src_install() {
155 emake DESTDIR="${D}" \
156 UPDATE_ICON_CACHE=true \
157 UPDATE_MIME_DATABASE=true \
158 UPDATE_DESKTOP_DATABASE=true \
159 install
160 dodoc share/doc/{readme,hacking}.md
161 use plugin-fishlim && dodoc share/doc/fishlim.md
162 prune_libtool_files --all
163 }
164
165 pkg_preinst() {
166 if use gtk ; then
167 gnome2_icon_savelist
168 fi
169 }
170
171 pkg_postinst() {
172 if use gtk ; then
173 gnome2_icon_cache_update
174 einfo
175 else
176 einfo
177 elog "You have disabled the gtk USE flag. This means you don't have"
178 elog "the GTK-GUI for HexChat but only a text interface called \"hexchat-text\"."
179 elog
180 fi
181
182 if use theme-manager ; then
183 fdo-mime_desktop_database_update
184 fdo-mime_mime_database_update
185 elog "Themes are available at:"
186 elog " http://hexchat.org/themes.html"
187 elog
188 fi
189
190 elog "If you're upgrading from hexchat <=2.9.3 remember to rename"
191 elog "the xchat.conf file found in ~/.config/hexchat/ to hexchat.conf"
192 elog
193 elog "If you're upgrading from hexchat <=2.9.5 you will have to fix"
194 elog "your auto-join channel settings, see:"
195 elog " https://bugs.gentoo.org/show_bug.cgi?id=473514#c1"
196 elog "Also, some internal hotkeys such as \"Ctrl+l\" (clear screen)"
197 elog "have been removed, but you can add them yourself via:"
198 elog " Settings -> Keyboard Shortcuts"
199 einfo
200 elog "optional dependencies:"
201 elog " media-sound/sox (sound playback if you don't have libcanberra"
202 elog " enabled)"
203 elog " x11-plugins/hexchat-javascript (javascript support)"
204 elog " x11-themes/sound-theme-freedesktop (default BEEP sound,"
205 elog " needs libcanberra enabled)"
206 einfo
207 }
208
209 pkg_postrm() {
210 if use gtk ; then
211 gnome2_icon_cache_update
212 fi
213
214 if use theme-manager ; then
215 fdo-mime_desktop_database_update
216 fdo-mime_mime_database_update
217 fi
218 }
Report Message
Find on MARC Find on Google Groups