[gentoo-commits] repo/gentoo:master commit in: sci-libs/cblas-reference/

[Justin Lecher]

commit:     ddf18a6eab2fddd04157d552461acd37daca1e17
Author:     Justin Lecher <jlec <AT> gentoo <DOT> org>
AuthorDate: Mon Dec 28 16:46:58 2015 +0000
Commit:     Justin Lecher <jlec <AT> gentoo <DOT> org>
CommitDate: Mon Dec 28 19:19:59 2015 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=ddf18a6e

sci-libs/cblas-reference: Bump to EAPI=5

Package-Manager: portage-2.2.26
Signed-off-by: Justin Lecher <jlec <AT> gentoo.org>

 .../cblas-reference-20030223-r6.ebuild             | 67 ++++++++++++++++++++++
 1 file changed, 67 insertions(+)

diff --git a/sci-libs/cblas-reference/cblas-reference-20030223-r6.ebuild b/sci-libs/cblas-reference/cblas-reference-20030223-r6.ebuild
new file mode 100644
index 0000000..33fa881
--- /dev/null
+++ b/sci-libs/cblas-reference/cblas-reference-20030223-r6.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+inherit autotools eutils fortran-2 multilib toolchain-funcs
+
+MyPN="${PN/-reference/}"
+
+DESCRIPTION="C wrapper interface to the F77 reference BLAS implementation"
+HOMEPAGE="http://www.netlib.org/blas/"
+SRC_URI="http://www.netlib.org/blas/blast-forum/${MyPN}.tgz"
+
+SLOT="0"
+LICENSE="public-domain"
+IUSE=""
+KEYWORDS="~alpha ~amd64 ~hppa ~ppc ~ppc64 ~s390 ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~x64-macos"
+
+RDEPEND="
+	virtual/blas
+	app-eselect/eselect-cblas"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig"
+
+ESELECT_PROF=reference
+S="${WORKDIR}/CBLAS"
+
+src_prepare() {
+	epatch "${FILESDIR}"/${P}-autotool.patch
+	eautoreconf
+
+	cp "${FILESDIR}"/eselect.cblas.reference "${T}"/ || die
+	sed -i -e "s:/usr:${EPREFIX}/usr:" "${T}"/eselect.cblas.reference || die
+	if [[ ${CHOST} == *-darwin* ]] ; then
+		sed -i -e 's/\.so\([\.0-9]\+\)\?/\1.dylib/g' \
+			"${T}"/eselect.cblas.reference || die
+	fi
+}
+
+src_configure() {
+	econf \
+		--libdir="${EPREFIX}"/usr/$(get_libdir)/blas/reference \
+		--with-blas="$($(tc-getPKG_CONFIG) --libs blas)"
+}
+
+src_install() {
+	default
+	dodoc cblas_example*c
+	eselect cblas add $(get_libdir) "${T}"/eselect.cblas.reference ${ESELECT_PROF}
+}
+
+pkg_postinst() {
+	local p=cblas
+	local current_lib=$(eselect ${p} show | cut -d' ' -f2)
+	if [[ ${current_lib} == ${ESELECT_PROF} || -z ${current_lib} ]]; then
+		# work around eselect bug #189942
+		local configfile="${EROOT}"/etc/env.d/${p}/$(get_libdir)/config
+		[[ -e ${configfile} ]] && rm -f ${configfile}
+		eselect ${p} set ${ESELECT_PROF}
+		elog "${p} has been eselected to ${ESELECT_PROF}"
+	else
+		elog "Current eselected ${p} is ${current_lib}"
+		elog "To use ${p} ${ESELECT_PROF} implementation, you have to issue (as root):"
+		elog "\t eselect ${p} set ${ESELECT_PROF}"
+	fi
+}