[gentoo-commits] gentoo-x86 commit in dev-libs/wayland: wayland-1.6.1.ebuild wayland-1.3.0.ebuild ChangeLog

[Chi-Thanh Christopher Nguyen (chithanh)]

chithanh    15/02/09 01:19:26

  Modified:             wayland-1.3.0.ebuild ChangeLog
  Added:                wayland-1.6.1.ebuild
  Log:
  Version bump. Shut up repoman warning.
  
  (Portage version: 2.2.14/cvs/Linux x86_64, signed Manifest commit with key 0x2324E7B566DF2611!)

Revision  Changes    Path
1.4                  dev-libs/wayland/wayland-1.3.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/wayland/wayland-1.3.0.ebuild?rev=1.4&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/wayland/wayland-1.3.0.ebuild?rev=1.4&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/wayland/wayland-1.3.0.ebuild?r1=1.3&r2=1.4

Index: wayland-1.3.0.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-libs/wayland/wayland-1.3.0.ebuild,v
retrieving revision 1.3
retrieving revision 1.4
diff -u -r1.3 -r1.4
--- wayland-1.3.0.ebuild	18 Jun 2014 19:18:47 -0000	1.3
+++ wayland-1.3.0.ebuild	9 Feb 2015 01:19:26 -0000	1.4
@@ -1,6 +1,6 @@
-# Copyright 1999-2014 Gentoo Foundation
+# Copyright 1999-2015 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/wayland/wayland-1.3.0.ebuild,v 1.3 2014/06/18 19:18:47 mgorny Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/wayland/wayland-1.3.0.ebuild,v 1.4 2015/02/09 01:19:26 chithanh Exp $
 
 EAPI=5
 
@@ -36,7 +36,7 @@
 
 src_prepare() {
 	# Remove resources-test from TESTS as it has failed since it was added.
-	sed -i -e 's/	resources-test$(EXEEXT)/	$(NULL)/' ${S}/tests/Makefile.in || die
+	sed -i -e 's/	resources-test$(EXEEXT)/	$(NULL)/' "${S}"/tests/Makefile.in || die
 
 	autotools-multilib_src_prepare
 }



1.49                 dev-libs/wayland/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/wayland/ChangeLog?rev=1.49&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/wayland/ChangeLog?rev=1.49&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/wayland/ChangeLog?r1=1.48&r2=1.49

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-libs/wayland/ChangeLog,v
retrieving revision 1.48
retrieving revision 1.49
diff -u -r1.48 -r1.49
--- ChangeLog	26 Sep 2014 20:39:31 -0000	1.48
+++ ChangeLog	9 Feb 2015 01:19:26 -0000	1.49
@@ -1,6 +1,12 @@
 # ChangeLog for dev-libs/wayland
-# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/wayland/ChangeLog,v 1.48 2014/09/26 20:39:31 mattst88 Exp $
+# Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/wayland/ChangeLog,v 1.49 2015/02/09 01:19:26 chithanh Exp $
+
+*wayland-1.6.1 (09 Feb 2015)
+
+  09 Feb 2015; Chí-Thanh Christopher Nguyễn <chithanh@g.o>
+  +wayland-1.6.1.ebuild, wayland-1.3.0.ebuild:
+  Version bump. Shut up repoman warning.
 
 *wayland-1.6.0 (26 Sep 2014)
 



1.1                  dev-libs/wayland/wayland-1.6.1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/wayland/wayland-1.6.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/wayland/wayland-1.6.1.ebuild?rev=1.1&content-type=text/plain

Index: wayland-1.6.1.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-libs/wayland/wayland-1.6.1.ebuild,v 1.1 2015/02/09 01:19:26 chithanh Exp $

EAPI=5

if [[ ${PV} = 9999* ]]; then
	EGIT_REPO_URI="git://anongit.freedesktop.org/git/${PN}/${PN}"
	GIT_ECLASS="git-r3"
	EXPERIMENTAL="true"
	AUTOTOOLS_AUTORECONF=1
fi

inherit autotools-multilib toolchain-funcs $GIT_ECLASS

DESCRIPTION="Wayland protocol libraries"
HOMEPAGE="http://wayland.freedesktop.org/"

if [[ $PV = 9999* ]]; then
	SRC_URI="${SRC_PATCHES}"
else
	SRC_URI="http://wayland.freedesktop.org/releases/${P}.tar.xz"
fi

LICENSE="MIT"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86"
IUSE="doc static-libs"

RDEPEND=">=dev-libs/expat-2.1.0-r3:=[${MULTILIB_USEDEP}]
	>=virtual/libffi-3.0.13-r1:=[${MULTILIB_USEDEP}]"
DEPEND="${RDEPEND}
	doc? ( app-doc/doxygen )
	virtual/pkgconfig"

src_configure() {
	local myeconfargs=(
		$(use_enable static-libs static)
		$(use_enable doc documentation)
	)
	if tc-is-cross-compiler ; then
		myeconfargs+=( --disable-scanner )
	fi
	if ! multilib_is_native_abi; then
		myeconfargs+=( --disable-documentation )
	fi

	autotools-multilib_src_configure
}

src_test() {
	export XDG_RUNTIME_DIR="${T}/runtime-dir"
	mkdir "${XDG_RUNTIME_DIR}" || die
	chmod 0700 "${XDG_RUNTIME_DIR}" || die

	autotools-multilib_src_test
}