[gentoo-commits] repo/gentoo:master commit in: app-admin/keepassxc/

[Lars Wendler]

commit:     63f24afd03d1d57d60231717b4fcde28fa00a32e
Author:     Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
AuthorDate: Fri Jan 28 14:47:05 2022 +0000
Commit:     Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
CommitDate: Fri Jan 28 14:56:50 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=63f24afd

app-admin/keepassxc: Add 2.6.x live ebuild

Signed-off-by: Lars Wendler <polynomial-c <AT> gentoo.org>

 app-admin/keepassxc/keepassxc-2.6.9999.ebuild | 99 +++++++++++++++++++++++++++
 1 file changed, 99 insertions(+)

diff --git a/app-admin/keepassxc/keepassxc-2.6.9999.ebuild b/app-admin/keepassxc/keepassxc-2.6.9999.ebuild
new file mode 100644
index 000000000000..e2016b26a2c8
--- /dev/null
+++ b/app-admin/keepassxc/keepassxc-2.6.9999.ebuild
@@ -0,0 +1,99 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake flag-o-matic xdg
+
+DESCRIPTION="KeePassXC - KeePass Cross-platform Community Edition"
+HOMEPAGE="https://keepassxc.org"
+
+if [[ "${PV}" != *9999 ]] ; then
+	if [[ "${PV}" == *_beta* ]] ; then
+		SRC_URI="https://github.com/keepassxreboot/keepassxc/archive/${PV/_/-}.tar.gz -> ${P}.tar.gz"
+		S="${WORKDIR}/${P/_/-}"
+	else
+		#SRC_URI="https://github.com/keepassxreboot/keepassxc/archive/${PV}.tar.gz -> ${P}.tar.gz"
+		SRC_URI="https://github.com/keepassxreboot/keepassxc/releases/download/${PV}/${P}-src.tar.xz"
+		KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+	fi
+else
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/keepassxreboot/${PN}"
+	[[ "${PV}" != 9999 ]] && EGIT_BRANCH="master"
+fi
+
+LICENSE="LGPL-2.1 GPL-2 GPL-3"
+SLOT="0"
+IUSE="autotype browser ccache doc keeshare +network test yubikey"
+
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	app-crypt/argon2:=
+	dev-libs/libgcrypt:=
+	>=dev-libs/libsodium-1.0.12:=
+	dev-qt/qtconcurrent:5
+	dev-qt/qtcore:5
+	dev-qt/qtdbus:5
+	dev-qt/qtgui:5
+	dev-qt/qtnetwork:5
+	dev-qt/qtsvg:5
+	dev-qt/qtwidgets:5
+	media-gfx/qrencode:=
+	sys-libs/readline:0=
+	sys-libs/zlib:=
+	autotype? (
+		dev-qt/qtx11extras:5
+		x11-libs/libX11
+		x11-libs/libXi
+		x11-libs/libXtst
+	)
+	keeshare? ( sys-libs/zlib:=[minizip] )
+	yubikey? ( sys-auth/ykpers )
+"
+
+DEPEND="
+	${RDEPEND}
+	dev-qt/linguist-tools:5
+	dev-qt/qttest:5
+"
+BDEPEND="
+	ccache? ( dev-util/ccache )
+	doc? ( dev-ruby/asciidoctor )
+"
+
+src_prepare() {
+	if [[ "${PV}" != *_beta* ]] && [[ "${PV}" != *9999 ]] && [[ ! -f .version ]] ; then
+		printf '%s' "${PV}" > .version || die
+	fi
+
+	 cmake_src_prepare
+}
+
+src_configure() {
+	# https://github.com/keepassxreboot/keepassxc/issues/5801
+	filter-flags -flto*
+
+	local mycmakeargs=(
+		-DWITH_CCACHE="$(usex ccache)"
+		-DWITH_GUI_TESTS=OFF
+		-DWITH_TESTS="$(usex test)"
+		-DWITH_XC_AUTOTYPE="$(usex autotype)"
+		-DWITH_XC_DOCS="$(usex doc)"
+		-DWITH_XC_BROWSER="$(usex browser)"
+		-DWITH_XC_FDOSECRETS=ON
+		-DWITH_XC_KEESHARE="$(usex keeshare)"
+		-DWITH_XC_NETWORKING="$(usex network)"
+		-DWITH_XC_SSHAGENT=ON
+		-DWITH_XC_UPDATECHECK=OFF
+		-DWITH_XC_YUBIKEY="$(usex yubikey)"
+	)
+	if [[ "${PV}" == *_beta* ]] ; then
+		mycmakeargs+=( -DOVERRIDE_VERSION="${PV/_/-}" )
+	fi
+	if [[ "${PV}" != 9999 ]] ; then
+		mycmakeargs+=( -DWITH_XC_KEESHARE_SECURE="$(usex keeshare)" )
+	fi
+	cmake_src_configure
+}