[gentoo-commits] repo/gentoo:master commit in: sys-kernel/gentoo-kernel-bin/

[Sam James]

commit:     6c90449db78b487f33b9a671a51dc7d664273356
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Fri Jul  9 11:52:04 2021 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Fri Jul  9 11:52:04 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=6c90449d

sys-kernel/gentoo-kernel-bin: bump to 5.4.130-r1 for arm64

Signed-off-by: Sam James <sam <AT> gentoo.org>

 sys-kernel/gentoo-kernel-bin/Manifest              |   1 +
 .../gentoo-kernel-bin-5.4.130-r1.ebuild            | 114 +++++++++++++++++++++
 2 files changed, 115 insertions(+)

diff --git a/sys-kernel/gentoo-kernel-bin/Manifest b/sys-kernel/gentoo-kernel-bin/Manifest
index bd466223cc0..a7b24216ed0 100644
--- a/sys-kernel/gentoo-kernel-bin/Manifest
+++ b/sys-kernel/gentoo-kernel-bin/Manifest
@@ -102,6 +102,7 @@ DIST gentoo-kernel-5.4.129-1.amd64.xpak 61346649 BLAKE2B 37d29b604a69fd8bc84c41b
 DIST gentoo-kernel-5.4.129-1.arm64.xpak 56131771 BLAKE2B 5567df5a41ccd99aca489b8b35718eefdfc9ddb0d9bbe6158abb32c59490278c6e1456ed021f9a08f7bb9b0c206fe503ab31cedadf0276a01f7fbe56e8ea8270 SHA512 8be57abcb7533b8f47a3bc11302e3f9b0ff8c33f67e6830210030a2caf3215b708856c899ecb7dddf9af707e39594f035a21e503c98a909ca1ddfb156d121554
 DIST gentoo-kernel-5.4.129-1.x86.xpak 53134201 BLAKE2B c7d76168ceb139ff7e206e5005d6cad2c7c54320967ca9e9c8dcf493677527fa3712d43c9b6dba96a54ad8b1d68cce937dd3643b0ac2d1e8a32c1d27361f578a SHA512 edf3c3f744738bbc06f13307259ef6315cb5bda60d9ca165853b7ea4b2f983ba72efa3bb1b4db1a0b21deb5060b7636a5c41840b36cd1ee224bce69358db6e4d
 DIST gentoo-kernel-5.4.130-1.amd64.xpak 61373618 BLAKE2B 4431a12633d68d87e95826fa71e45fc61a7a6c53f3d8879583ac74802c00460048400386da61b625ebcb7eb192302cf5ca0d63a95597d51ccf144ece5c168ba5 SHA512 c84fda865821ca57b77ee2f93dd7986688a115d2a90b99ee4154bcb2f1fc6c7ad96c729a0f484ee25e70318f30935aba0eb4b228631a90d9ec6d936c3c076b00
+DIST gentoo-kernel-5.4.130-1.arm64.xpak 56048219 BLAKE2B 72e54faf0ed99e570e71504afe5b721875fc4d491d73cff91c6534abd612962d9360c1efb01c0757ba9764211b3030b5c6032d63106b7eee9d8fb9d55683da36 SHA512 4b7cab1a6fd68b9c46cf4f4d5d78eb6d66bff424af9c3d2a844a072ee2578f679d636c2f185b033a55ae12ee3d7cfec5aeb2accb87a3a5e6ae1e19601c620374
 DIST gentoo-kernel-5.4.130-1.x86.xpak 53128397 BLAKE2B a4183f65fe7bc2b869b3556342434b90f577c88266a4462cfe4fd080584c333b7c934649894d9c570f1949b018614b96e17cd6b118aad08fd22e48d3a44515ea SHA512 2ec7337c2ca20eb43c0423318199e36b8d64454d0594910d84d965d725ac416509f8be2b60d70f76f8a8d40a8c17b0d928f6cf8e20b8271d3f7008921d4ca10d
 DIST linux-5.10.tar.xz 116606704 BLAKE2B b923d7b66309224f42f35f8a5fa219421b0a9362d2adacdadd8d96251f61f7230878ea297a269a7f3b3c56830f0b177e068691e1d7f88501a05653b0a13274d1 SHA512 95bc137d0cf9148da6a9d1f1a878698dc27b40f68e22c597544010a6c591ce1b256f083489d3ff45ff77753289b535135590194d88ef9f007d0ddab3d74de70e
 DIST linux-5.12.tar.xz 118112412 BLAKE2B 842d921b9a73d2aaade763dbd2ec67bdfe0275baa6d628b775f5c87574ad7dc86f0419afcd48c10c1235f4bffa16084243f2cf4556e6afcd391e975fe8ba530b SHA512 be03b6fee1d1ea8087b09874d27c0a602c0b04fd90ad38b975bd2c8455a07e83c29b56814aaf1389e82305fae0e4c2d1701075a7f0a7295dd28149f967ec5b3d

diff --git a/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.4.130-r1.ebuild b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.4.130-r1.ebuild
new file mode 100644
index 00000000000..b63276300c5
--- /dev/null
+++ b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.4.130-r1.ebuild
@@ -0,0 +1,114 @@
+# Copyright 2020-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit kernel-install toolchain-funcs
+
+MY_P=linux-${PV%.*}
+GENPATCHES_P=genpatches-${PV%.*}-$(( ${PV##*.} + 3 ))
+BINPKG=${P/-bin/}-1
+
+DESCRIPTION="Pre-built Linux kernel with genpatches"
+HOMEPAGE="https://www.kernel.org/"
+SRC_URI+="
+	https://cdn.kernel.org/pub/linux/kernel/v$(ver_cut 1).x/${MY_P}.tar.xz
+	https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.base.tar.xz
+	https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.extras.tar.xz
+	arm64? (
+		https://dev.gentoo.org/~sam/binpkg/arm64/kernel/sys-kernel/gentoo-kernel/${BINPKG}.xpak
+			-> ${BINPKG}.arm64.xpak
+	)
+"
+S=${WORKDIR}
+
+LICENSE="GPL-2"
+KEYWORDS="~arm64"
+
+RDEPEND="
+	!sys-kernel/gentoo-kernel:${SLOT}"
+PDEPEND="
+	>=virtual/dist-kernel-${PV}"
+BDEPEND="
+	sys-devel/bc
+	sys-devel/flex
+	virtual/libelf
+	virtual/yacc"
+
+QA_PREBUILT='*'
+
+KV_LOCALVERSION='-gentoo-dist'
+KPV=${PV}${KV_LOCALVERSION}
+
+src_unpack() {
+	default
+	ebegin "Unpacking ${BINPKG}.${ARCH}.xpak"
+	tar -x < <(xz -c -d --single-stream "${DISTDIR}/${BINPKG}.${ARCH}.xpak")
+	eend ${?} || die "Unpacking ${BINPKG} failed"
+}
+
+src_prepare() {
+	local PATCHES=(
+		# meh, genpatches have no directory
+		"${WORKDIR}"/*.patch
+	)
+	cd "${MY_P}" || die
+	default
+}
+
+src_configure() {
+	# force ld.bfd if we can find it easily
+	local LD="$(tc-getLD)"
+	if type -P "${LD}.bfd" &>/dev/null; then
+		LD+=.bfd
+	fi
+
+	tc-export_build_env
+	local makeargs=(
+		V=1
+
+		HOSTCC="$(tc-getBUILD_CC)"
+		HOSTCXX="$(tc-getBUILD_CXX)"
+		HOSTCFLAGS="${BUILD_CFLAGS}"
+		HOSTLDFLAGS="${BUILD_LDFLAGS}"
+
+		CROSS_COMPILE=${CHOST}-
+		AS="$(tc-getAS)"
+		CC="$(tc-getCC)"
+		LD="${LD}"
+		AR="$(tc-getAR)"
+		NM="$(tc-getNM)"
+		STRIP=":"
+		OBJCOPY="$(tc-getOBJCOPY)"
+		OBJDUMP="$(tc-getOBJDUMP)"
+
+		# we need to pass it to override colliding Gentoo envvar
+		ARCH=$(tc-arch-kernel)
+
+		O="${WORKDIR}"/modprep
+	)
+
+	mkdir modprep || die
+	cp "usr/src/linux-${KPV}/.config" modprep/ || die
+	emake -C "${MY_P}" "${makeargs[@]}" modules_prepare
+}
+
+src_test() {
+	kernel-install_test "${KPV}" \
+		"${WORKDIR}/usr/src/linux-${KPV}/$(dist-kernel_get_image_path)" \
+		"lib/modules/${KPV}"
+}
+
+src_install() {
+	mv lib usr "${ED}"/ || die
+
+	# strip out-of-source build stuffs from modprep
+	# and then copy built files
+	find modprep -type f '(' \
+			-name Makefile -o \
+			-name '*.[ao]' -o \
+			'(' -name '.*' -a -not -name '.config' ')' \
+		')' -delete || die
+	rm modprep/source || die
+	cp -p -R modprep/. "${ED}/usr/src/linux-${KPV}"/ || die
+}