[gentoo-commits] gentoo-x86 commit in x11-libs/goocanvas: ChangeLog goocanvas-1.0.0.ebuild

[Gilles Dartiguelongue (eva)]

eva         11/02/22 22:33:38

  Modified:             ChangeLog
  Added:                goocanvas-1.0.0.ebuild
  Log:
  Version bump, bug #342273.
  
  (Portage version: 2.2.0_alpha24/cvs/Linux x86_64, RepoMan options: --force)

Revision  Changes    Path
1.21                 x11-libs/goocanvas/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-libs/goocanvas/ChangeLog?rev=1.21&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-libs/goocanvas/ChangeLog?rev=1.21&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-libs/goocanvas/ChangeLog?r1=1.20&r2=1.21

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/x11-libs/goocanvas/ChangeLog,v
retrieving revision 1.20
retrieving revision 1.21
diff -u -r1.20 -r1.21
--- ChangeLog	19 Nov 2010 09:01:14 -0000	1.20
+++ ChangeLog	22 Feb 2011 22:33:38 -0000	1.21
@@ -1,6 +1,11 @@
 # ChangeLog for x11-libs/goocanvas
-# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-libs/goocanvas/ChangeLog,v 1.20 2010/11/19 09:01:14 jlec Exp $
+# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/x11-libs/goocanvas/ChangeLog,v 1.21 2011/02/22 22:33:38 eva Exp $
+
+*goocanvas-1.0.0 (22 Feb 2011)
+
+  22 Feb 2011; Gilles Dartiguelongue <eva@g.o> +goocanvas-1.0.0.ebuild:
+  Version bump, bug #342273.
 
   19 Nov 2010; Justin Lecher <jlec@g.o> goocanvas-0.14.ebuild:
   Cleaned DESCRIPTION to fit ebuild writing guide lines



1.1                  x11-libs/goocanvas/goocanvas-1.0.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-libs/goocanvas/goocanvas-1.0.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-libs/goocanvas/goocanvas-1.0.0.ebuild?rev=1.1&content-type=text/plain

Index: goocanvas-1.0.0.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-libs/goocanvas/goocanvas-1.0.0.ebuild,v 1.1 2011/02/22 22:33:38 eva Exp $

EAPI="3"

GCONF_DEBUG="no"

inherit gnome2 libtool

DESCRIPTION="Canvas widget for GTK+ using the cairo 2D library for drawing"
HOMEPAGE="http://live.gnome.org/GooCanvas"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
IUSE="doc examples"

RDEPEND=">=x11-libs/gtk+-2.12:2
	>=dev-libs/glib-2.10:2
	>=x11-libs/cairo-1.4"
DEPEND="${RDEPEND}
	dev-util/pkgconfig
	doc? ( >=dev-util/gtk-doc-1.8 )"

pkg_setup() {
	DOCS="AUTHORS ChangeLog NEWS README TODO"
	G2CONF="${G2CONF} --disable-rebuilds --disable-static"
}

src_prepare() {
	# Fails to build with recent GTK+
	sed -e "s/-D.*_DISABLE_DEPRECATED//g" \
		-i src/Makefile.am src/Makefile.in demo/Makefile.am demo/Makefile.in \
		|| die "sed 1 failed"

	sed -e 's/^\(SUBDIRS =.*\)demo\(.*\)$/\1\2/' \
		-i Makefile.am Makefile.in || die "sed 2 failed"

	# Needed for FreeBSD - Please do not remove
	elibtoolize
}

src_install() {
	gnome2_src_install

	if use examples; then
		insinto /usr/share/doc/${P}/examples/
		doins demo/*.c demo/flower.png demo/toroid.png
	fi
}