[gentoo-commits] repo/gentoo:master commit in: net-libs/mbedtls/

[Anthony G. Basile]

commit:     0a6891be3f023f7d8c8125e56ca2e48e2f1ad9c5
Author:     Anthony G. Basile <blueness <AT> gentoo <DOT> org>
AuthorDate: Mon Mar 26 12:23:43 2018 +0000
Commit:     Anthony G. Basile <blueness <AT> gentoo <DOT> org>
CommitDate: Mon Mar 26 12:24:00 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=0a6891be

net-libs/mbedtls: version bumps to 2.7.2 and 2.8.0

Package-Manager: Portage-2.3.24, Repoman-2.3.6

 net-libs/mbedtls/Manifest             |  2 +
 net-libs/mbedtls/mbedtls-2.7.2.ebuild | 93 +++++++++++++++++++++++++++++++++++
 net-libs/mbedtls/mbedtls-2.8.0.ebuild | 93 +++++++++++++++++++++++++++++++++++
 3 files changed, 188 insertions(+)

diff --git a/net-libs/mbedtls/Manifest b/net-libs/mbedtls/Manifest
index 846d81f8197..81128ac85b5 100644
--- a/net-libs/mbedtls/Manifest
+++ b/net-libs/mbedtls/Manifest
@@ -2,3 +2,5 @@ DIST mbedtls-2.6.0.tar.gz 1912899 BLAKE2B 6477cfabc8f86e4ac9cfd3539c3645ebb1446d
 DIST mbedtls-2.6.1.tar.gz 1912980 BLAKE2B 8ac29233edcd61fc2c440db86dd8359daa5fd6cf268f41748eb7d71d228739132ab22018ee636ac83e8bdb89917650103d9cea2b62ce28bf59a3a6d0cbe87f7e SHA512 06f8ba2a453164bac01d20ca6f5c80e691857977ef501d56685e81a0e90dddae1bedeab46c18c22f9a3b72894d45d7466f76a5c404417b6613ddae0ee4a881c8
 DIST mbedtls-2.7.0.tar.gz 2038485 BLAKE2B 66f853eb3832b3b8e531fc31ab826d9d4a19dc78cebb64d6893ed6adfce8816f65d43dee28ce34212e507e08c9fcb5918819996e3f819c0d048a5916857348df SHA512 411ec25d2cd51abbbfa2312195c4e65aa578855f6f909b8668375e6f5ce5401a00153cb4790328daaf85cd2d0ce647dbcc9fa556331e2d14709ba64aff883867
 DIST mbedtls-2.7.1.tar.gz 2040225 BLAKE2B 5743f1bdc9af8dd4425c36907d4cfa4a07ab6dd0a092d0b7e4ecdd775e19396ae409a7f5438bbe9d87a9e8fec28e45ef9472baea752bd2b3c06b4c62487bec49 SHA512 ba4b7dfafc02a949ffa91fb73ee574b320fe64731c3880abe4dd9730384c28ee67c9788375cbd654d385e90aee1bb9265a873ddda5c21ee8385f02ff784db3fc
+DIST mbedtls-2.7.2.tar.gz 2127772 BLAKE2B d66c65f0d974baf97ae361e64db5028af6c402ea248a785009b422d993deaa4facee98dd338ee4b5d36087fd07e679069fc4fb57cce548097d1f788cedb825fa SHA512 52455b68744a3c220aed7346d19c7b9bebd3a065406242b446816a3b02325d72005b5c381b158bfff90e2fe5854064629b297fbec95fea3ad203bfae51a15cab
+DIST mbedtls-2.8.0.tar.gz 2132562 BLAKE2B ac0a67c51e4aeb59e947d16039b20de680ccd7daf372652c0a7d1a6694ce8fe213f959b47a4335cda236575d8f491c84a413ae2f408e86600519ac66a31f8c1a SHA512 baa2024e26cb1d772a525348cdcc84e2b5eabf58642d8c792fe88cf6c539b36f14e80d592e85bc474f6be036513ed4b8bc86f5808ad4f5b08f25ca7e43dc3921

diff --git a/net-libs/mbedtls/mbedtls-2.7.2.ebuild b/net-libs/mbedtls/mbedtls-2.7.2.ebuild
new file mode 100644
index 00000000000..a992986693d
--- /dev/null
+++ b/net-libs/mbedtls/mbedtls-2.7.2.ebuild
@@ -0,0 +1,93 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit cmake-utils multilib-minimal
+
+DESCRIPTION="Cryptographic library for embedded systems"
+HOMEPAGE="https://tls.mbed.org/"
+SRC_URI="https://github.com/ARMmbed/mbedtls/archive/${P}.tar.gz"
+S=${WORKDIR}/${PN}-${P}
+
+LICENSE="Apache-2.0"
+SLOT="0/10" # slot for libmbedtls.so
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd"
+IUSE="cpu_flags_x86_sse2 doc havege libressl programs test threads zlib"
+
+RDEPEND="
+	programs? (
+		!libressl? ( dev-libs/openssl:0= )
+		libressl? ( dev-libs/libressl:0= )
+	)
+	zlib? ( >=sys-libs/zlib-1.2.8-r1[${MULTILIB_USEDEP}] )"
+DEPEND="${RDEPEND}
+	doc? ( app-doc/doxygen media-gfx/graphviz )
+	test? ( dev-lang/perl )"
+
+enable_mbedtls_option() {
+	local myopt="$@"
+	# check that config.h syntax is the same at version bump
+	sed -i \
+		-e "s://#define ${myopt}:#define ${myopt}:" \
+		include/mbedtls/config.h || die
+}
+
+src_prepare() {
+	use cpu_flags_x86_sse2 && enable_mbedtls_option MBEDTLS_HAVE_SSE2
+	use zlib && enable_mbedtls_option MBEDTLS_ZLIB_SUPPORT
+	use havege && enable_mbedtls_option MBEDTLS_HAVEGE_C
+	use threads && enable_mbedtls_option MBEDTLS_THREADING_C
+	use threads && enable_mbedtls_option MBEDTLS_THREADING_PTHREAD
+
+	cmake-utils_src_prepare
+}
+
+multilib_src_configure() {
+	local mycmakeargs=(
+		-DENABLE_PROGRAMS=$(multilib_native_usex programs)
+		-DENABLE_ZLIB_SUPPORT=$(usex zlib)
+		-DUSE_STATIC_MBEDTLS_LIBRARY=OFF
+		-DENABLE_TESTING=$(usex test)
+		-DUSE_SHARED_MBEDTLS_LIBRARY=ON
+		-DINSTALL_MBEDTLS_HEADERS=ON
+		-DLIB_INSTALL_DIR="/usr/$(get_libdir)"
+	)
+
+	cmake-utils_src_configure
+}
+
+multilib_src_compile() {
+	cmake-utils_src_compile
+	use doc && multilib_is_native_abi && emake apidoc
+}
+
+multilib_src_test() {
+	LD_LIBRARY_PATH="${LD_LIBRARY_PATH}:${BUILD_DIR}/library" \
+		cmake-utils_src_test
+}
+
+multilib_src_install() {
+	cmake-utils_src_install
+}
+
+multilib_src_install_all() {
+	use doc && HTML_DOCS=( apidoc )
+
+	einstalldocs
+
+	if use programs ; then
+		# avoid file collisions with sys-apps/coreutils
+		local p e
+		for p in "${ED%/}"/usr/bin/* ; do
+			if [[ -x "${p}" && ! -d "${p}" ]] ; then
+				mv "${p}" "${ED%/}"/usr/bin/mbedtls_${p##*/} || die
+			fi
+		done
+		for e in aes hash pkey ssl test ; do
+			docinto "${e}"
+			dodoc programs/"${e}"/*.c
+			dodoc programs/"${e}"/*.txt
+		done
+	fi
+}

diff --git a/net-libs/mbedtls/mbedtls-2.8.0.ebuild b/net-libs/mbedtls/mbedtls-2.8.0.ebuild
new file mode 100644
index 00000000000..a992986693d
--- /dev/null
+++ b/net-libs/mbedtls/mbedtls-2.8.0.ebuild
@@ -0,0 +1,93 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit cmake-utils multilib-minimal
+
+DESCRIPTION="Cryptographic library for embedded systems"
+HOMEPAGE="https://tls.mbed.org/"
+SRC_URI="https://github.com/ARMmbed/mbedtls/archive/${P}.tar.gz"
+S=${WORKDIR}/${PN}-${P}
+
+LICENSE="Apache-2.0"
+SLOT="0/10" # slot for libmbedtls.so
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd"
+IUSE="cpu_flags_x86_sse2 doc havege libressl programs test threads zlib"
+
+RDEPEND="
+	programs? (
+		!libressl? ( dev-libs/openssl:0= )
+		libressl? ( dev-libs/libressl:0= )
+	)
+	zlib? ( >=sys-libs/zlib-1.2.8-r1[${MULTILIB_USEDEP}] )"
+DEPEND="${RDEPEND}
+	doc? ( app-doc/doxygen media-gfx/graphviz )
+	test? ( dev-lang/perl )"
+
+enable_mbedtls_option() {
+	local myopt="$@"
+	# check that config.h syntax is the same at version bump
+	sed -i \
+		-e "s://#define ${myopt}:#define ${myopt}:" \
+		include/mbedtls/config.h || die
+}
+
+src_prepare() {
+	use cpu_flags_x86_sse2 && enable_mbedtls_option MBEDTLS_HAVE_SSE2
+	use zlib && enable_mbedtls_option MBEDTLS_ZLIB_SUPPORT
+	use havege && enable_mbedtls_option MBEDTLS_HAVEGE_C
+	use threads && enable_mbedtls_option MBEDTLS_THREADING_C
+	use threads && enable_mbedtls_option MBEDTLS_THREADING_PTHREAD
+
+	cmake-utils_src_prepare
+}
+
+multilib_src_configure() {
+	local mycmakeargs=(
+		-DENABLE_PROGRAMS=$(multilib_native_usex programs)
+		-DENABLE_ZLIB_SUPPORT=$(usex zlib)
+		-DUSE_STATIC_MBEDTLS_LIBRARY=OFF
+		-DENABLE_TESTING=$(usex test)
+		-DUSE_SHARED_MBEDTLS_LIBRARY=ON
+		-DINSTALL_MBEDTLS_HEADERS=ON
+		-DLIB_INSTALL_DIR="/usr/$(get_libdir)"
+	)
+
+	cmake-utils_src_configure
+}
+
+multilib_src_compile() {
+	cmake-utils_src_compile
+	use doc && multilib_is_native_abi && emake apidoc
+}
+
+multilib_src_test() {
+	LD_LIBRARY_PATH="${LD_LIBRARY_PATH}:${BUILD_DIR}/library" \
+		cmake-utils_src_test
+}
+
+multilib_src_install() {
+	cmake-utils_src_install
+}
+
+multilib_src_install_all() {
+	use doc && HTML_DOCS=( apidoc )
+
+	einstalldocs
+
+	if use programs ; then
+		# avoid file collisions with sys-apps/coreutils
+		local p e
+		for p in "${ED%/}"/usr/bin/* ; do
+			if [[ -x "${p}" && ! -d "${p}" ]] ; then
+				mv "${p}" "${ED%/}"/usr/bin/mbedtls_${p##*/} || die
+			fi
+		done
+		for e in aes hash pkey ssl test ; do
+			docinto "${e}"
+			dodoc programs/"${e}"/*.c
+			dodoc programs/"${e}"/*.txt
+		done
+	fi
+}