[gentoo-commits] gentoo-x86 commit in www-apps/egroupware: ChangeLog egroupware-1.4.004.ebuild

[Benedikt Boehm (hollow)]

hollow      08/04/25 11:44:10

  Modified:             ChangeLog
  Added:                egroupware-1.4.004.ebuild
  Log:
  version bump wrt security #218625
  (Portage version: 2.1.5_rc6)

Revision  Changes    Path
1.92                 www-apps/egroupware/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/www-apps/egroupware/ChangeLog?rev=1.92&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/www-apps/egroupware/ChangeLog?rev=1.92&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/www-apps/egroupware/ChangeLog?r1=1.91&r2=1.92

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/www-apps/egroupware/ChangeLog,v
retrieving revision 1.91
retrieving revision 1.92
diff -u -r1.91 -r1.92
--- ChangeLog	7 Apr 2008 20:22:25 -0000	1.91
+++ ChangeLog	25 Apr 2008 11:44:10 -0000	1.92
@@ -1,6 +1,12 @@
 # ChangeLog for www-apps/egroupware
 # Copyright 2002-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/www-apps/egroupware/ChangeLog,v 1.91 2008/04/07 20:22:25 armin76 Exp $
+# $Header: /var/cvsroot/gentoo-x86/www-apps/egroupware/ChangeLog,v 1.92 2008/04/25 11:44:10 hollow Exp $
+
+*egroupware-1.4.004 (25 Apr 2008)
+
+  25 Apr 2008; Benedikt Böhm <hollow@g.o>
+  +egroupware-1.4.004.ebuild:
+  version bump wrt security #218625
 
   07 Apr 2008; Raúl Porcel <armin76@g.o> egroupware-1.4.003.ebuild:
   alpha stable wrt security #214212



1.1                  www-apps/egroupware/egroupware-1.4.004.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/www-apps/egroupware/egroupware-1.4.004.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/www-apps/egroupware/egroupware-1.4.004.ebuild?rev=1.1&content-type=text/plain

Index: egroupware-1.4.004.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/www-apps/egroupware/egroupware-1.4.004.ebuild,v 1.1 2008/04/25 11:44:10 hollow Exp $

inherit eutils webapp depend.php

MY_PN=eGroupWare

DESCRIPTION="Web-based GroupWare suite"
HOMEPAGE="http://www.egroupware.org/"
SRC_URI="mirror://sourceforge/${PN}/${MY_PN}-${PV}-2.tar.bz2
	mirror://sourceforge/${PN}/${MY_PN}-egw-pear-${PV}-2.tar.bz2"

LICENSE="GPL-2"
KEYWORDS="~alpha ~amd64 ~hppa ~ppc ~sparc ~x86"
IUSE="jpgraph ldap mssql mysql postgres"

RDEPEND="jpgraph? ( || ( dev-php5/jpgraph dev-php4/jpgraph ) )
	dev-php/PEAR-PEAR
	virtual/cron"

need_httpd_cgi
need_php_httpd

S="${WORKDIR}"/${PN}

pkg_setup () {
	webapp_pkg_setup
	has_php

	local php_flags="imap session unicode"

	for f in ldap mssql mysql postgres; do
		use ${f} && php_flags="${php_flags} ${f}"
	done

	if ! PHPCHECKNODIE="yes" require_php_with_use ${php_flags} || \
		! PHPCHECKNODIE="yes" require_php_with_any_use gd gd-external ; then
			die "Re-install ${PHP_PKG} with ${php_flags} and either gd or gd-external."
	fi
}

src_unpack() {
	unpack ${A}
	cd "${S}"
	esvn_clean

	if use jpgraph; then
		einfo "Fixing jpgraph location"
		sed -i "s|EGW_SERVER_ROOT . '/../jpgraph/src/jpgraph.php'|'/usr/share/php${PHP_VERSION}/jpgraph/jpgraph.php'|" \
			projectmanager/inc/class.ganttchart.inc.php || die
		sed -i "s|EGW_SERVER_ROOT . '/../jpgraph/src/jpgraph_gantt.php'|'/usr/share/php${PHP_VERSION}/jpgraph/jpgraph_gantt.php'|" \
			projectmanager/inc/class.ganttchart.inc.php || die
	fi
}

src_install() {
	webapp_src_preinst

	insinto "${MY_HTDOCSDIR}"
	doins -r .

	webapp_serverowned "${MY_HTDOCSDIR}"/phpgwapi/images

	webapp_postinst_txt en "${FILESDIR}"/postinstall-en-1.2.txt
	webapp_src_install
}

pkg_postinst() {
	if use ldap; then
		elog "If you are using LDAP contacts/addressbook, please read the upgrade instructions at"
		elog "http://www.egroupware.org/index.php?page_name=wiki&wikipage=ManualSetupUpdate"
		elog "before running the egroupware setup"
	fi
	webapp_pkg_postinst
}



-- 
gentoo-commits@l.g.o mailing list