[gentoo-commits] repo/gentoo:master commit in: sci-libs/coinor-dip/

[Sam James]

commit:     8d5eb6f356da4df3b7b4b7f0fd13a40874fffa12
Author:     Ionen Wolkens <sudinave <AT> gmail <DOT> com>
AuthorDate: Fri Feb 26 09:28:12 2021 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Sat Feb 27 03:06:29 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=8d5eb6f3

sci-libs/coinor-dip: bump to 0.95.0, ported to EAPI 7

Has reworked old workarounds and reviewed deps.

USE=examples removed, now installed unconditionally (small files).
USE=doc now installs html docs.
USE=static-libs removed.

Package-Manager: Portage-3.0.15, Repoman-3.0.2
Signed-off-by: Ionen Wolkens <sudinave <AT> gmail.com>
Signed-off-by: Sam James <sam <AT> gentoo.org>

 sci-libs/coinor-dip/Manifest                 |  1 +
 sci-libs/coinor-dip/coinor-dip-0.95.0.ebuild | 57 ++++++++++++++++++++++++++++
 2 files changed, 58 insertions(+)

diff --git a/sci-libs/coinor-dip/Manifest b/sci-libs/coinor-dip/Manifest
index 6f56dedea8c..311cd87df33 100644
--- a/sci-libs/coinor-dip/Manifest
+++ b/sci-libs/coinor-dip/Manifest
@@ -1 +1,2 @@
 DIST Dip-0.9.8.tgz 10557241 BLAKE2B 1fcddbe4b7e8ae0450fcf97473428c0a36b751bbf5b91ab45c362ca0590d390d8c0b5b4b273ed41f7e9432423c59b9a4f8536ff34b0c9c0f1c11ced779ddb38c SHA512 7dfb51f63aab36fe7e894be5f17f8b614bfdf9be1a14b8f8b2ee555dcb8392f82b13d20481d60423d3d375a2e52eebe0439e696e3b3a7dfdd18223829835d361
+DIST coinor-dip-0.95.0.tar.gz 5213061 BLAKE2B 6f40e5d20832b0463e302519da168a30bdeea011a45047acb9dbe904763fc94ccaffbee3599b6f959e0eea5e40a0456771012707b9daafc50875194a1ff9967e SHA512 a9ea2bc23d625fa19e11943f46b3bf2db49aa894fe336c8de4a9a0c735e1569bd8bef015fd671eb856ee39a334adf06c95e2708bd69c4735d5f6bf994c9e41a2

diff --git a/sci-libs/coinor-dip/coinor-dip-0.95.0.ebuild b/sci-libs/coinor-dip/coinor-dip-0.95.0.ebuild
new file mode 100644
index 00000000000..d13707458c4
--- /dev/null
+++ b/sci-libs/coinor-dip/coinor-dip-0.95.0.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DESCRIPTION="COIN-OR Decomposition in Integer Programming library"
+HOMEPAGE="https://projects.coin-or.org/Dip/"
+SRC_URI="https://github.com/coin-or/Dip/archive/releases/${PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/Dip-releases-${PV}/Dip"
+
+LICENSE="EPL-1.0"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="doc test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	sci-libs/coinor-alps:=
+	sci-libs/coinor-cbc:=
+	sci-libs/coinor-cgl:=
+	sci-libs/coinor-clp:=
+	sci-libs/coinor-osi:=
+	sci-libs/coinor-utils:="
+DEPEND="${RDEPEND}"
+BDEPEND="
+	virtual/pkgconfig
+	doc? ( app-doc/doxygen[dot] )
+	test? ( sci-libs/coinor-sample )"
+
+src_prepare() {
+	default
+	# Prevent unneeded call to pkg-config that needs ${ED}'s in path.
+	sed -i '/--libs.*addlibs.txt/d' Makefile.in || die
+}
+
+src_configure() {
+	econf $(use_with doc dot)
+}
+
+src_compile() {
+	emake all $(usex doc doxydoc '')
+}
+
+src_test() {
+	# Needed given "make check" is a noop and it skips the working one.
+	emake test
+}
+
+src_install() {
+	default
+	dodoc -r examples
+	use doc && dodoc -r doxydoc/html
+
+	# Duplicate or irrelevant files.
+	rm -r "${ED}"/usr/share/coin/doc || die
+	find "${ED}" -name '*.la' -delete || die
+}