[gentoo-commits] repo/gentoo:master commit in: dev-ruby/pdf-reader/

[Hans de Graaff]

commit:     7b24e96b19e13de3d7281eec325bfd1cb1a88212
Author:     Hans de Graaff <graaff <AT> gentoo <DOT> org>
AuthorDate: Tue Jul  3 05:14:32 2018 +0000
Commit:     Hans de Graaff <graaff <AT> gentoo <DOT> org>
CommitDate: Tue Jul  3 05:14:32 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=7b24e96b

dev-ruby/pdf-reader: fix gemspec and parallel slot install

Closes: https://bugs.gentoo.org/659910
Closes: https://bugs.gentoo.org/610922
Package-Manager: Portage-2.3.40, Repoman-2.3.9

 dev-ruby/pdf-reader/pdf-reader-1.4.1-r2.ebuild | 49 ++++++++++++++++++++++++++
 dev-ruby/pdf-reader/pdf-reader-2.1.0-r1.ebuild | 49 ++++++++++++++++++++++++++
 2 files changed, 98 insertions(+)

diff --git a/dev-ruby/pdf-reader/pdf-reader-1.4.1-r2.ebuild b/dev-ruby/pdf-reader/pdf-reader-1.4.1-r2.ebuild
new file mode 100644
index 00000000000..6d0fc36b2a9
--- /dev/null
+++ b/dev-ruby/pdf-reader/pdf-reader-1.4.1-r2.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=5
+
+GITHUB_USER=yob
+
+USE_RUBY="ruby23 ruby24 ruby25"
+
+RUBY_FAKEGEM_RECIPE_TEST="rspec3"
+
+RUBY_FAKEGEM_RECIPE_DOC="rdoc"
+RUBY_FAKEGEM_EXTRADOC="CHANGELOG README.rdoc TODO"
+
+RUBY_FAKEGEM_GEMSPEC="pdf-reader.gemspec"
+
+RUBY_FAKEGEM_BINWRAP=""
+
+inherit ruby-fakegem
+
+DESCRIPTION="PDF parser conforming as much as possible to the PDF specification from Adobe"
+HOMEPAGE="https://github.com/yob/pdf-reader/"
+
+# We cannot use the gem distributions because they don't contain the
+# tests' data, we have to rely on the git tags.
+SRC_URI="https://github.com/${GITHUB_USER}/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE=""
+
+ruby_add_rdepend ">=dev-ruby/afm-0.2.1
+	=dev-ruby/ascii85-1*
+	=dev-ruby/hashery-2*
+	dev-ruby/ttfunk:*
+	dev-ruby/ruby-rc4"
+
+all_ruby_prepare() {
+	# Remove bundler support
+	sed -i -e '/[Bb]undler/d' spec/spec_helper.rb || die
+}
+
+all_ruby_install() {
+	all_fakegem_install
+
+	docinto examples
+	dodoc examples/* || die
+}

diff --git a/dev-ruby/pdf-reader/pdf-reader-2.1.0-r1.ebuild b/dev-ruby/pdf-reader/pdf-reader-2.1.0-r1.ebuild
new file mode 100644
index 00000000000..d03629ca327
--- /dev/null
+++ b/dev-ruby/pdf-reader/pdf-reader-2.1.0-r1.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+GITHUB_USER=yob
+
+USE_RUBY="ruby23 ruby24 ruby25"
+
+RUBY_FAKEGEM_RECIPE_TEST="rspec3"
+
+RUBY_FAKEGEM_RECIPE_DOC="rdoc"
+RUBY_FAKEGEM_EXTRADOC="CHANGELOG README.md TODO"
+
+RUBY_FAKEGEM_GEMSPEC="pdf-reader.gemspec"
+
+inherit ruby-fakegem
+
+DESCRIPTION="PDF parser conforming as much as possible to the PDF specification from Adobe"
+HOMEPAGE="https://github.com/yob/pdf-reader/"
+
+# We cannot use the gem distributions because they don't contain the
+# tests' data, we have to rely on the git tags.
+SRC_URI="https://github.com/${GITHUB_USER}/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="2"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE=""
+
+RDEPEND+=" !!<dev-ruby/pdf-reader-1.4.1-r2"
+
+ruby_add_rdepend ">=dev-ruby/afm-0.2.1 =dev-ruby/afm-0.2*
+	=dev-ruby/ascii85-1*
+	=dev-ruby/hashery-2*
+	dev-ruby/ttfunk:*
+	dev-ruby/ruby-rc4"
+
+all_ruby_prepare() {
+	# Remove bundler support
+	sed -i -e '/[Bb]undler/d' spec/spec_helper.rb || die
+}
+
+all_ruby_install() {
+	all_fakegem_install
+
+	docinto examples
+	dodoc examples/* || die
+}