[gentoo-commits] gentoo-x86 commit in media-sound/jack-audio-connection-kit: ChangeLog jack-audio-connection-kit-0.121.3-r1.ebuild

[Alexis Ballier (aballier)]

aballier    13/07/29 23:39:25

  Modified:             ChangeLog
  Added:                jack-audio-connection-kit-0.121.3-r1.ebuild
  Log:
  Migrate to multilib and fix the ncurses dep when readline gets picked up by default.
  
  (Portage version: 2.2.0_alpha190/cvs/Linux x86_64, signed Manifest commit with key 160F534A)

Revision  Changes    Path
1.151                media-sound/jack-audio-connection-kit/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/jack-audio-connection-kit/ChangeLog?rev=1.151&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/jack-audio-connection-kit/ChangeLog?rev=1.151&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/jack-audio-connection-kit/ChangeLog?r1=1.150&r2=1.151

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-sound/jack-audio-connection-kit/ChangeLog,v
retrieving revision 1.150
retrieving revision 1.151
diff -u -r1.150 -r1.151
--- ChangeLog	13 May 2013 03:40:20 -0000	1.150
+++ ChangeLog	29 Jul 2013 23:39:25 -0000	1.151
@@ -1,6 +1,13 @@
 # ChangeLog for media-sound/jack-audio-connection-kit
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/jack-audio-connection-kit/ChangeLog,v 1.150 2013/05/13 03:40:20 blueness Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/jack-audio-connection-kit/ChangeLog,v 1.151 2013/07/29 23:39:25 aballier Exp $
+
+*jack-audio-connection-kit-0.121.3-r1 (29 Jul 2013)
+
+  29 Jul 2013; Alexis Ballier <aballier@g.o>
+  +jack-audio-connection-kit-0.121.3-r1.ebuild:
+  Migrate to multilib and fix the ncurses dep when readline gets picked up by
+  default.
 
   13 May 2013; Anthony G. Basile <blueness@g.o>
   jack-audio-connection-kit-0.121.3.ebuild:



1.1                  media-sound/jack-audio-connection-kit/jack-audio-connection-kit-0.121.3-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/jack-audio-connection-kit/jack-audio-connection-kit-0.121.3-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/jack-audio-connection-kit/jack-audio-connection-kit-0.121.3-r1.ebuild?rev=1.1&content-type=text/plain

Index: jack-audio-connection-kit-0.121.3-r1.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-sound/jack-audio-connection-kit/jack-audio-connection-kit-0.121.3-r1.ebuild,v 1.1 2013/07/29 23:39:25 aballier Exp $

EAPI=5

inherit flag-o-matic eutils multilib multilib-minimal

DESCRIPTION="A low-latency audio server"
HOMEPAGE="http://www.jackaudio.org"
SRC_URI="http://www.jackaudio.org/downloads/${P}.tar.gz"

LICENSE="GPL-2 LGPL-2.1"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sh ~sparc ~x86 ~amd64-fbsd"
IUSE="3dnow altivec alsa coreaudio doc debug examples mmx oss sse cpudetection pam"

# readline: only used for jack_transport -> useless for non native ABIs
# libsndfile: ditto for jackrec
RDEPEND="
	sys-libs/readline
	>=media-libs/libsndfile-1.0.0
	alsa? ( >=media-libs/alsa-lib-1.0.18[${MULTILIB_USEDEP}] )
	media-libs/libsamplerate[${MULTILIB_USEDEP}]
	!media-sound/jack-cvs
	abi_x86_32? ( !<=app-emulation/emul-linux-x86-soundlibs-20130224-r7
					!app-emulation/emul-linux-x86-soundlibs[-abi_x86_32(-)] )"
DEPEND="${RDEPEND}
	virtual/pkgconfig
	doc? ( app-doc/doxygen )"
RDEPEND="${RDEPEND}
	alsa? ( sys-process/lsof )
	pam? ( sys-auth/realtime-base )"

src_prepare() {
	epatch "${FILESDIR}/${PN}-sparc-cpuinfo.patch"
	epatch "${FILESDIR}/${PN}-freebsd.patch"
}

DOCS=( AUTHORS TODO README )

multilib_src_configure() {
	local myconf=""

	# CPU Detection (dynsimd) uses asm routines which requires 3dnow, mmx and sse.
	if use cpudetection && use 3dnow && use mmx && use sse ; then
		einfo "Enabling cpudetection (dynsimd). Adding -mmmx, -msse, -m3dnow and -O2 to CFLAGS."
		myconf="${myconf} --enable-dynsimd"
		append-flags -mmmx -msse -m3dnow -O2
	fi

	use doc || export ac_cv_prog_HAVE_DOXYGEN=false

	ECONF_SOURCE="${S}" econf \
		$(use_enable altivec) \
		$(use_enable alsa) \
		$(use_enable coreaudio) \
		$(use_enable debug) \
		$(use_enable mmx) \
		$(use_enable oss) \
		--disable-portaudio \
		$(use_enable sse) \
		--with-html-dir=/usr/share/doc/${PF} \
		--disable-dependency-tracking \
		--libdir=/usr/$(get_libdir) \
		${myconf}

	if [ "${ABI}" != "${DEFAULT_ABI}" ] ; then
		for i in tools man ; do
			sed -i -e "s/ ${i}//" Makefile || die
		done
	fi
}

multilib_src_install_all() {
	if use examples; then
		insinto /usr/share/doc/${PF}
		doins -r "${S}/example-clients"
		docompress -x /usr/share/doc/${PF}/example-clients
	fi
}