[gentoo-commits] gentoo-x86 commit in media-sound/picard: ChangeLog picard-0.9.0_beta1.ebuild

[Santiago M. Mola (coldwind)]

coldwind    07/10/28 17:24:35

  Modified:             ChangeLog
  Added:                picard-0.9.0_beta1.ebuild
  Log:
  Bump to 0.9.0_beta1, thanks to Marti Raudsepp <marti@×××××.org>.
  (Portage version: 2.1.3.9)

Revision  Changes    Path
1.4                  media-sound/picard/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/picard/ChangeLog?rev=1.4&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/picard/ChangeLog?rev=1.4&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/picard/ChangeLog?r1=1.3&r2=1.4

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-sound/picard/ChangeLog,v
retrieving revision 1.3
retrieving revision 1.4
diff -u -r1.3 -r1.4
--- ChangeLog	16 Sep 2007 21:43:33 -0000	1.3
+++ ChangeLog	28 Oct 2007 17:24:35 -0000	1.4
@@ -1,6 +1,12 @@
 # ChangeLog for media-sound/picard
 # Copyright 1999-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/picard/ChangeLog,v 1.3 2007/09/16 21:43:33 coldwind Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/picard/ChangeLog,v 1.4 2007/10/28 17:24:35 coldwind Exp $
+
+*picard-0.9.0_beta1 (28 Oct 2007)
+
+  28 Oct 2007; Santiago M. Mola <coldwind@g.o>
+  +picard-0.9.0_beta1.ebuild:
+  Bump to 0.9.0_beta1, thanks to Marti Raudsepp <marti@×××××.org>.
 
   16 Sep 2007; Santiago M. Mola <coldwind@g.o>
   picard-0.9.0_alpha14.ebuild:



1.1                  media-sound/picard/picard-0.9.0_beta1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/picard/picard-0.9.0_beta1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/picard/picard-0.9.0_beta1.ebuild?rev=1.1&content-type=text/plain

Index: picard-0.9.0_beta1.ebuild
===================================================================
# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-sound/picard/picard-0.9.0_beta1.ebuild,v 1.1 2007/10/28 17:24:35 coldwind Exp $

inherit eutils distutils

MY_P="${P/_beta/beta}"

DESCRIPTION="An improved rewrite/port of the Picard Tagger using Qt"
HOMEPAGE="http://musicbrainz.org/doc/PicardQt"
SRC_URI="http://ftp.musicbrainz.org/pub/musicbrainz/users/luks/picard-qt/${MY_P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86 ~amd64"
IUSE="cdaudio ffmpeg nls"

RDEPEND=">=dev-lang/python-2.4
	|| ( >=dev-lang/python-2.5 >=dev-python/ctypes-0.9 )
	>=dev-python/PyQt4-4.2
	>=x11-libs/qt-4.2
	>=media-libs/mutagen-1.9
	cdaudio? ( >=media-libs/libdiscid-0.1.1 )
	ffmpeg? ( >=media-video/ffmpeg-0.4.9
		>=media-libs/libofa-0.9.2 )"

DEPEND="${RDEPEND}"

DOCS="AUTHORS.txt INSTALL.txt NEWS.txt"
S=${WORKDIR}/${MY_P}

src_compile() {
	${python} setup.py config || die "setup.py config failed"
	if ! use ffmpeg; then
		sed -i -e "s:\(^with-avcodec\ =\ \).*:\1False:" \
			-e "s:\(^with-libofa\ =\ \).*:\1False:" \
			build.cfg || die "sed failed"
	fi
	${python} setup.py build $(use nls || echo "--disable-locales") \
		|| die "setup.py build failed"
}

src_install() {
	distutils_src_install --disable-autoupdate --skip-build \
		$(use nls || echo "--disable-locales")
}

pkg_postinst() {
	distutils_pkg_postinst
	echo
	elog "You should set the environment variable BROWSER to something like"
	elog "\"firefox '%s' &\" to let python know which browser to use."
	echo
	if ! use ffmpeg; then
		ewarn "The 'ffmpeg' USE flag is disabled. Acoustic fingerprinting and"
		ewarn "recognition will not be available."
		echo
	fi
	if ! use cdaudio; then
		ewarn "The 'cdaudio' USE flag is disabled. CD index lookup and"
		ewarn "identification will not be available. You can get audio CD support"
		ewarn "by installing media-libs/libdiscid."
	fi
}



-- 
gentoo-commits@g.o mailing list