[gentoo-commits] gentoo-x86 commit in app-office/gnucash: gnucash-2.3.5.ebuild ChangeLog

[Torsten Veller (tove)]

tove        09/08/30 16:57:47

  Modified:             ChangeLog
  Added:                gnucash-2.3.5.ebuild
  Log:
  Version bump
  (Portage version: 2.2_rc40/cvs/Linux x86_64)

Revision  Changes    Path
1.197                app-office/gnucash/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-office/gnucash/ChangeLog?rev=1.197&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-office/gnucash/ChangeLog?rev=1.197&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-office/gnucash/ChangeLog?r1=1.196&r2=1.197

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-office/gnucash/ChangeLog,v
retrieving revision 1.196
retrieving revision 1.197
diff -u -r1.196 -r1.197
--- ChangeLog	2 Aug 2009 15:30:08 -0000	1.196
+++ ChangeLog	30 Aug 2009 16:57:47 -0000	1.197
@@ -1,6 +1,11 @@
 # ChangeLog for app-office/gnucash
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-office/gnucash/ChangeLog,v 1.196 2009/08/02 15:30:08 maekke Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-office/gnucash/ChangeLog,v 1.197 2009/08/30 16:57:47 tove Exp $
+
+*gnucash-2.3.5 (30 Aug 2009)
+
+  30 Aug 2009; Torsten Veller <tove@g.o> +gnucash-2.3.5.ebuild:
+  Version bump
 
   02 Aug 2009; Markus Meier <maekke@g.o> gnucash-2.2.9-r1.ebuild:
   amd64 stable, bug #275705



1.1                  app-office/gnucash/gnucash-2.3.5.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-office/gnucash/gnucash-2.3.5.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-office/gnucash/gnucash-2.3.5.ebuild?rev=1.1&content-type=text/plain

Index: gnucash-2.3.5.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-office/gnucash/gnucash-2.3.5.ebuild,v 1.1 2009/08/30 16:57:47 tove Exp $

EAPI=2

inherit eutils gnome2

DOC_VER="2.2.0"

DESCRIPTION="A personal finance manager"
HOMEPAGE="http://www.gnucash.org/"
#SRC_URI="mirror://sourceforge/${PN}/${P}.tar.bz2"
SRC_URI="http://www.gnucash.org/pub/gnucash/sources/unstable/2.3.x/${P}.tar.bz2"

SLOT="0"
LICENSE="GPL-2"
KEYWORDS="~alpha ~amd64 ~ppc ~sparc ~x86"

IUSE="+doc ofx hbci chipcard debug quotes sqlite postgres mysql webkit"

# FIXME: rdepend on dev-libs/qof when upstream fix their mess (see configure.in)

RDEPEND=">=dev-libs/glib-2.6.3
	>=dev-scheme/guile-1.8.3[deprecated,regex]
	dev-scheme/guile-www
	>=dev-scheme/slib-3.1.4
	>=sys-libs/zlib-1.1.4
	>=dev-libs/popt-1.5
	>=x11-libs/gtk+-2.10
	>=gnome-base/libgnomeui-2.4
	>=gnome-base/libglade-2.4
	>=dev-libs/libxml2-2.5.10
	>=gnome-base/gconf-2
	>=x11-libs/goffice-0.6[gnome]
	ofx? ( >=dev-libs/libofx-0.7.0 )
	hbci? ( net-libs/aqbanking[qt3]
		chipcard? ( sys-libs/libchipcard )
	)
	quotes? ( dev-perl/DateManip
		>=dev-perl/Finance-Quote-1.11
		dev-perl/HTML-TableExtract )
	webkit? ( net-libs/webkit-gtk )
	>=gnome-extra/gtkhtml-3.14
	sqlite? ( dev-db/libdbi dev-db/libdbi-drivers[sqlite] )
	postgres? ( dev-db/libdbi dev-db/libdbi-drivers[postgres] )
	mysql? ( dev-db/libdbi dev-db/libdbi-drivers[mysql] )
	media-libs/libart_lgpl
	x11-libs/pango"

DEPEND="${RDEPEND}
	dev-util/pkgconfig
	dev-util/intltool
	sys-devel/libtool
	>=app-text/scrollkeeper-0.3"

PDEPEND="doc? ( >=app-doc/gnucash-docs-${DOC_VER} )"
ELTCONF="--patch-only"
DOCS="doc/README.OFX doc/README.HBCI"

# FIXME: no the best thing to do but it'd be even better to fix autofoo
#MAKEOPTS="${MAKEOPTS} -j1"

pkg_setup() {
	ewarn "This is one of several unstable 2.3.x releases of the GnuCash Free"
	ewarn "Accounting Software which will eventually lead to the stable version"
	ewarn "2.4.0."
	ewarn "This release is intended for developers and testers who want to help"
	ewarn "tracking down all those bugs that are still in there."
	ewarn ""
	ewarn "WARNING WARNING WARNING"
	ewarn "Make sure you make backups of any files used in testing versions of"
	ewarn "GnuCash in the 2.3.x series."

	if use webkit ; then
		G2CONF="${G2CONF} --with-html-engine=webkit"
	else
		G2CONF="${G2CONF} --with-html-engine=gtkhtml"
	fi

	if use sqlite || use mysql || use postgres ; then
		G2CONF="${G2CONF}
			--enable-dbi"
	fi
	G2CONF="${G2CONF}
		$(use_enable debug)
		$(use_enable ofx)
		$(use_enable hbci aqbanking)
		--disable-doxygen
		--enable-locale-specific-tax
		--disable-error-on-warning"
}

src_test() {
	GUILE_WARN_DEPRECATED=no \
	GNC_DOT_DIR="${T}"/.gnucash \
	emake check \
	|| die "Make check failed. See above for details."
}

src_install() {
	gnome2_src_install GNC_DOC_INSTALL_DIR=/usr/share/doc/${PF}

	rm -rf "${D}"/usr/share/doc/${PF}/{examples/,COPYING,INSTALL,*win32-bin.txt,projects.html}
#	prepalldocs
	mv "${D}"/usr/share/doc/${PF} "${T}"/cantuseprepalldocs || die
	dodoc "${T}"/cantuseprepalldocs/* || die
}