[gentoo-commits] repo/gentoo:master commit in: kde-apps/okular/

[Andreas Sturmlechner]

commit:     f711c79a5dde63b78bec1bebc1cce1fe539f4f85
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Fri Jul 16 13:59:38 2021 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Fri Jul 16 15:20:50 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=f711c79a

kde-apps/okular: Drop 21.04.3 (r0)

Package-Manager: Portage-3.0.20, Repoman-3.0.3
Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 kde-apps/okular/okular-21.04.3.ebuild | 107 ----------------------------------
 1 file changed, 107 deletions(-)

diff --git a/kde-apps/okular/okular-21.04.3.ebuild b/kde-apps/okular/okular-21.04.3.ebuild
deleted file mode 100644
index 9c072d62591..00000000000
--- a/kde-apps/okular/okular-21.04.3.ebuild
+++ /dev/null
@@ -1,107 +0,0 @@
-# Copyright 1999-2021 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-ECM_HANDBOOK="forceoptional"
-ECM_TEST="forceoptional"
-PVCUT=$(ver_cut 1-3)
-KFMIN=5.80.0
-QTMIN=5.15.2
-VIRTUALX_REQUIRED="test"
-inherit ecm kde.org
-
-DESCRIPTION="Universal document viewer based on KDE Frameworks"
-HOMEPAGE="https://okular.kde.org https://apps.kde.org/okular/"
-
-LICENSE="GPL-2" # TODO: CHECK
-SLOT="5"
-KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
-IUSE="chm djvu epub +image-backend markdown mobi +pdf +plucker +postscript qml share speech +tiff"
-
-DEPEND="
-	>=dev-qt/qtdbus-${QTMIN}:5
-	>=dev-qt/qtgui-${QTMIN}:5
-	>=dev-qt/qtprintsupport-${QTMIN}:5
-	>=dev-qt/qtsvg-${QTMIN}:5
-	>=dev-qt/qtwidgets-${QTMIN}:5
-	>=kde-frameworks/kactivities-${KFMIN}:5
-	>=kde-frameworks/karchive-${KFMIN}:5
-	>=kde-frameworks/kbookmarks-${KFMIN}:5
-	>=kde-frameworks/kcompletion-${KFMIN}:5
-	>=kde-frameworks/kconfig-${KFMIN}:5
-	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
-	>=kde-frameworks/kcoreaddons-${KFMIN}:5
-	>=kde-frameworks/kcrash-${KFMIN}:5
-	>=kde-frameworks/kio-${KFMIN}:5
-	>=kde-frameworks/kjs-${KFMIN}:5
-	>=kde-frameworks/kparts-${KFMIN}:5
-	>=kde-frameworks/kpty-${KFMIN}:5
-	>=kde-frameworks/kwallet-${KFMIN}:5
-	>=kde-frameworks/threadweaver-${KFMIN}:5
-	media-libs/freetype
-	>=media-libs/phonon-4.11.0
-	sys-libs/zlib
-	chm? (
-		dev-libs/chmlib
-		dev-libs/libzip:=
-		>=kde-frameworks/khtml-${KFMIN}:5
-	)
-	djvu? ( app-text/djvu )
-	epub? ( app-text/ebook-tools )
-	image-backend? (
-		>=dev-qt/qtgui-${QTMIN}:5[gif,jpeg,png]
-		>=kde-apps/libkexiv2-${PVCUT}:5
-	)
-	markdown? ( app-text/discount )
-	mobi? ( >=kde-apps/kdegraphics-mobipocket-${PVCUT}:5 )
-	pdf? ( app-text/poppler[nss,qt5] )
-	plucker? ( virtual/jpeg:0 )
-	postscript? ( app-text/libspectre )
-	share? ( >=kde-frameworks/purpose-${KFMIN}:5 )
-	speech? ( >=dev-qt/qtspeech-${QTMIN}:5 )
-	tiff? ( media-libs/tiff:0 )
-"
-RDEPEND="${DEPEND}
-	image-backend? ( >=kde-frameworks/kimageformats-${KFMIN}:5 )
-	qml? (
-		>=dev-qt/qtquickcontrols2-${QTMIN}:5
-		>=kde-frameworks/kirigami-${KFMIN}:5
-	)
-"
-
-PATCHES=(
-	"${FILESDIR}/${PN}-20.11.90-tests.patch" # bug 734138
-	"${FILESDIR}/${PN}-20.08.2-hide-mobile-app.patch" # avoid same-name entry
-)
-
-src_configure() {
-	local mycmakeargs=(
-		-DOKULAR_UI=$(usex qml "both" "desktop")
-		$(cmake_use_find_package chm CHM)
-		$(cmake_use_find_package chm KF5KHtml)
-		$(cmake_use_find_package chm LibZip)
-		$(cmake_use_find_package djvu DjVuLibre)
-		$(cmake_use_find_package epub EPub)
-		$(cmake_use_find_package image-backend KF5KExiv2)
-		$(cmake_use_find_package markdown Discount)
-		$(cmake_use_find_package mobi QMobipocket)
-		$(cmake_use_find_package pdf Poppler)
-		$(cmake_use_find_package plucker JPEG)
-		$(cmake_use_find_package postscript LibSpectre)
-		$(cmake_use_find_package share KF5Purpose)
-		$(cmake_use_find_package speech Qt5TextToSpeech)
-		$(cmake_use_find_package tiff TIFF)
-	)
-	ecm_src_configure
-}
-
-src_test() {
-	# mainshelltest hangs, chmgeneratortest fails, bug #603116
-	# parttest hangs, bug #641728, annotationtoolbartest fails, KDE-Bug #429640
-	local myctestargs=(
-		-E "(mainshelltest|chmgeneratortest|parttest|annotationtoolbartest)"
-	)
-
-	ecm_src_test
-}