[gentoo-commits] repo/gentoo:master commit in: dev-python/pivy/

[Sam James]

commit:     9ca76b61e63037637892f18a0d7f6e11d273d7e1
Author:     Bernd Waibel <waebbl-gentoo <AT> posteo <DOT> net>
AuthorDate: Thu Sep  1 05:23:54 2022 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Sun Nov  6 20:12:52 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=9ca76b61

dev-python/pivy: add 0.6.8

Closes: https://bugs.gentoo.org/880083
Closes: https://bugs.gentoo.org/867763
Closes: https://github.com/gentoo/gentoo/pull/27101
Signed-off-by: Bernd Waibel <waebbl-gentoo <AT> posteo.net>
Signed-off-by: Sam James <sam <AT> gentoo.org>

 dev-python/pivy/Manifest          |  1 +
 dev-python/pivy/pivy-0.6.8.ebuild | 59 +++++++++++++++++++++++++++++++++++++++
 2 files changed, 60 insertions(+)

diff --git a/dev-python/pivy/Manifest b/dev-python/pivy/Manifest
index ac45149907b0..1b8c15c0ff99 100644
--- a/dev-python/pivy/Manifest
+++ b/dev-python/pivy/Manifest
@@ -1 +1,2 @@
 DIST pivy-0.6.7.tar.gz 6618410 BLAKE2B 22ebe63a75fa624b772cb3d3ff6f03336258f6c8b638613413c19fcea072f83f73396bc91d35f0e06bc27ec57471ae67965ee492e62a7e73919f7827de645175 SHA512 606eac3527b5906ad6884c25775b5625bfd2a1b1c78f75017b05e662d622c75d30e70fd5785ec2145902f5a02d99098b52cc776aee12fab02f0319762ee104b0
+DIST pivy-0.6.8.tar.gz 6618458 BLAKE2B 08c57f0d7bff15a7f9d49b56b75b44c587416eb0feb2b237db48d7e2edd478f9212d7e898f4dd102b9d5dd10046dd652f37a9974861598c7ba91d7fdb1145c91 SHA512 723b09028f2e3075056b9588cebad0ddccbc98d0c15552b9565c177b0de764b9645f88ea2bc534ccf606f2e0b59f91e1d03551b55ece66c0654ce9cdf09a1a7c

diff --git a/dev-python/pivy/pivy-0.6.8.ebuild b/dev-python/pivy/pivy-0.6.8.ebuild
new file mode 100644
index 000000000000..617534188b57
--- /dev/null
+++ b/dev-python/pivy/pivy-0.6.8.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..11} )
+
+inherit distutils-r1
+
+DESCRIPTION="Coin3D bindings for Python"
+HOMEPAGE="https://github.com/coin3d/pivy"
+
+if [[ ${PV} == *9999 ]]; then
+	inherit git-r3
+	PIVY_REPO_URI="https://github.com/coin3d/pivy.git"
+else
+	SRC_URI="https://github.com/coin3d/pivy/archive/refs/tags/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="amd64 x86"
+fi
+
+LICENSE="ISC"
+SLOT="0"
+IUSE="+quarter soqt test"
+RESTRICT="!test? ( test )"
+
+REQUIRED_USE="
+	${PYTHON_REQUIRED_USE}
+	|| ( quarter soqt )
+"
+
+RDEPEND="
+	>=media-libs/coin-4.0.0
+	quarter? ( media-libs/quarter )
+	soqt? ( >=media-libs/SoQt-1.6.0 )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	dev-lang/swig
+	dev-util/cmake
+	test? ( ${RDEPEND} )
+"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-0.6.6-0001-fix-CMakeLists.txt-for-distutils_cmake.patch
+	"${FILESDIR}"/${PN}-0.6.6-0002-Gentoo-specific-clear-swig-deprecation-warning.patch
+	"${FILESDIR}"/${PN}-0.6.7-find-qmake.patch
+)
+
+DOCS=( AUTHORS HACKING NEWS README.md THANKS )
+
+python_test() {
+	# visual_test.py is interactive
+	# pyside_test.py currently fails
+	# quarter_tests.py needs pyside2, which currently lacks py3_11 support
+	for f in tests/coin_tests.py; do
+		"${EPYTHON}" "${f}" || die "Test ${f} failed with ${EPYTHON}"
+	done
+}