[gentoo-commits] gentoo-x86 commit in dev-python/pycdio: pycdio-0.17.ebuild ChangeLog

[Arfrever Frehtes Taifersar Arahesis (arfrever)]

arfrever    10/11/01 00:43:45

  Modified:             ChangeLog
  Added:                pycdio-0.17.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.0_alpha3/cvs/Linux x86_64)

Revision  Changes    Path
1.7                  dev-python/pycdio/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/pycdio/ChangeLog?rev=1.7&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/pycdio/ChangeLog?rev=1.7&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/pycdio/ChangeLog?r1=1.6&r2=1.7

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-python/pycdio/ChangeLog,v
retrieving revision 1.6
retrieving revision 1.7
diff -u -r1.6 -r1.7
--- ChangeLog	24 Dec 2009 23:23:49 -0000	1.6
+++ ChangeLog	1 Nov 2010 00:43:45 -0000	1.7
@@ -1,6 +1,12 @@
 # ChangeLog for dev-python/pycdio
-# Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/pycdio/ChangeLog,v 1.6 2009/12/24 23:23:49 arfrever Exp $
+# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/pycdio/ChangeLog,v 1.7 2010/11/01 00:43:45 arfrever Exp $
+
+*pycdio-0.17 (01 Nov 2010)
+
+  01 Nov 2010; Arfrever Frehtes Taifersar Arahesis <arfrever@g.o>
+  -pycdio-0.16.ebuild, +pycdio-0.17.ebuild:
+  Version bump.
 
 *pycdio-0.16 (25 Dec 2009)
 



1.1                  dev-python/pycdio/pycdio-0.17.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/pycdio/pycdio-0.17.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/pycdio/pycdio-0.17.ebuild?rev=1.1&content-type=text/plain

Index: pycdio-0.17.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-python/pycdio/pycdio-0.17.ebuild,v 1.1 2010/11/01 00:43:45 arfrever Exp $

EAPI="3"
PYTHON_DEPEND="2"
SUPPORT_PYTHON_ABIS="1"
RESTRICT_PYTHON_ABIS="3.*"
DISTUTILS_SRC_TEST="nosetests"

inherit distutils

DESCRIPTION="Python OO interface to libcdio (CD Input and Control library)"
HOMEPAGE="http://savannah.gnu.org/projects/libcdio/ http://pypi.python.org/pypi/pycdio"
SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="examples"

RDEPEND="dev-libs/libcdio"
DEPEND="${RDEPEND}
	dev-lang/swig
	dev-python/setuptools"

PYTHON_CFLAGS=("2.* + -fno-strict-aliasing")

DOCS="README.txt"
PYTHON_MODNAME="cdio.py iso9660.py pycdio.py pyiso9660.py"

src_prepare() {
	distutils_src_prepare

	# Remove obsolete sys.path and adjust 'data' paths in examples.
	sed \
		-e "s:^sys.path.insert.*::" \
		-e "s:\.\./data:./data:g" \
		-i example/*.py || die "sed failed"

	# Disable failing tests.
	sed -e "s/test_get_set/_&/" -i test/test-cdtext.py || die "sed failed"
	sed -e "s/test_fs/_&/" -i test/test-isocopy.py || die "sed failed"
}

src_install(){
	distutils_src_install

	if use examples; then
		insinto /usr/share/doc/${PF}/examples
		doins example/{README,*.py} || die "doins failed"
		doins -r data || die "doins failed"
	fi
}