[gentoo-commits] gentoo-x86 commit in media-sound/mpg123: ChangeLog mpg123-1.0.1.ebuild

[Samuli Suominen (drac)]

drac        07/12/30 14:32:53

  Modified:             ChangeLog
  Added:                mpg123-1.0.1.ebuild
  Log:
  Version bump wrt #203760, thanks to Tobias Jakobi.
  (Portage version: 2.1.4_rc11)

Revision  Changes    Path
1.131                media-sound/mpg123/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/mpg123/ChangeLog?rev=1.131&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/mpg123/ChangeLog?rev=1.131&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/mpg123/ChangeLog?r1=1.130&r2=1.131

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-sound/mpg123/ChangeLog,v
retrieving revision 1.130
retrieving revision 1.131
diff -u -r1.130 -r1.131
--- ChangeLog	10 Dec 2007 21:34:00 -0000	1.130
+++ ChangeLog	30 Dec 2007 14:32:53 -0000	1.131
@@ -1,6 +1,12 @@
 # ChangeLog for media-sound/mpg123
 # Copyright 2002-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/mpg123/ChangeLog,v 1.130 2007/12/10 21:34:00 drac Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/mpg123/ChangeLog,v 1.131 2007/12/30 14:32:53 drac Exp $
+
+*mpg123-1.0.1 (30 Dec 2007)
+
+  30 Dec 2007; Samuli Suominen <drac@g.o>
+  +files/mpg123-1.0.1-no-faltivec.patch, +mpg123-1.0.1.ebuild:
+  Version bump wrt #203760, thanks to Tobias Jakobi.
 
   10 Dec 2007; Samuli Suominen <drac@g.o> mpg123-1.0_rc2.ebuild:
   Force automake-1.9 since 1.10 breaks LTCCASCOMPILE, building mmx code on



1.1                  media-sound/mpg123/mpg123-1.0.1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/mpg123/mpg123-1.0.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/mpg123/mpg123-1.0.1.ebuild?rev=1.1&content-type=text/plain

Index: mpg123-1.0.1.ebuild
===================================================================
# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-sound/mpg123/mpg123-1.0.1.ebuild,v 1.1 2007/12/30 14:32:53 drac Exp $

WANT_AUTOMAKE=1.9

inherit autotools eutils

DESCRIPTION="Real Time mp3 player"
HOMEPAGE="http://www.mpg123.de"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.bz2"

LICENSE="GPL-2 LGPL-2.1"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86"
IUSE="3dnow 3dnowext alsa altivec esd jack mmx nas oss portaudio pulseaudio sdl sse"

RDEPEND="alsa? ( media-libs/alsa-lib )
	sdl? ( media-libs/libsdl )
	esd? ( media-sound/esound )
	nas? ( media-libs/nas )
	jack? ( media-sound/jack-audio-connection-kit )
	portaudio? ( media-libs/portaudio )
	pulseaudio? ( media-sound/pulseaudio )"
DEPEND="${RDEPEND}
	dev-util/pkgconfig"

PROVIDE="virtual/mpg123"

src_unpack() {
	unpack ${A}
	cd "${S}"
	epatch "${FILESDIR}"/${P}-no-faltivec.patch
	eautoreconf
}

src_compile() {
	local myaudio

	use alsa && myaudio="${myaudio} alsa"
	use esd && myaudio="${myaudio} esd"
	use jack && myaudio="${myaudio} jack"
	use nas && myaudio="${myaudio} nas"
	use oss && myaudio="${myaudio} oss"
	use pulseaudio && myaudio="${myaudio} pulse"
	use sdl && myaudio="${myaudio} sdl"

	local mycpu

	if use altivec; then
		mycpu="--with-cpu=altivec"
	elif use 3dnowext; then
		mycpu="--with-cpu=3dnowext"
	elif use 3dnow; then
		mycpu="--with-cpu=3dnow"
	elif use sse; then
		mycpu="--with-cpu=sse"
	elif use mmx; then
		mycpu="--with-cpu=mmx"
	fi

	econf --with-optimization=0 \
		--with-audio="${myaudio}" \
		${mycpu} || die "econf failed."

	emake || die "emake failed."
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed."
	dodoc AUTHORS ChangeLog NEWS README
}



-- 
gentoo-commits@g.o mailing list