[gentoo-commits] gentoo-x86 commit in app-admin/testdisk: ChangeLog testdisk-6.12.ebuild

[Robin H. Johnson (robbat2)]

robbat2     11/07/03 23:58:06

  Modified:             ChangeLog
  Added:                testdisk-6.12.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.0_alpha43/cvs/Linux x86_64)

Revision  Changes    Path
1.41                 app-admin/testdisk/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/testdisk/ChangeLog?rev=1.41&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/testdisk/ChangeLog?rev=1.41&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/testdisk/ChangeLog?r1=1.40&r2=1.41

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-admin/testdisk/ChangeLog,v
retrieving revision 1.40
retrieving revision 1.41
diff -p -w -b -B -u -u -r1.40 -r1.41
--- ChangeLog	25 Feb 2011 18:13:56 -0000	1.40
+++ ChangeLog	3 Jul 2011 23:58:06 -0000	1.41
@@ -1,6 +1,11 @@
 # ChangeLog for app-admin/testdisk
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-admin/testdisk/ChangeLog,v 1.40 2011/02/25 18:13:56 signals Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-admin/testdisk/ChangeLog,v 1.41 2011/07/03 23:58:06 robbat2 Exp $
+
+*testdisk-6.12 (03 Jul 2011)
+
+  03 Jul 2011; Robin H. Johnson <robbat2@g.o> +testdisk-6.12.ebuild:
+  Version bump.
 
   25 Feb 2011; Kevin McCarthy <signals@g.o> testdisk-6.5.ebuild,
   testdisk-6.8-r1.ebuild, testdisk-6.10.ebuild, testdisk-6.11-r1.ebuild,



1.1                  app-admin/testdisk/testdisk-6.12.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/testdisk/testdisk-6.12.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/testdisk/testdisk-6.12.ebuild?rev=1.1&content-type=text/plain

Index: testdisk-6.12.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-admin/testdisk/testdisk-6.12.ebuild,v 1.1 2011/07/03 23:58:06 robbat2 Exp $

EAPI=2
inherit eutils flag-o-matic

DESCRIPTION="Checks and undeletes partitions + PhotoRec, signature based recovery tool"
HOMEPAGE="http://www.cgsecurity.org/wiki/TestDisk"
SRC_URI="http://www.cgsecurity.org/${P}.tar.bz2"
#SRC_URI="http://www.cgsecurity.org/${P}-WIP.tar.bz2"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE="static reiserfs ntfs jpeg"
# WARNING: reiserfs support does NOT work with reiserfsprogs
# you MUST use progsreiserfs-0.3.1_rc8 (the last version ever released).
DEPEND=">=sys-libs/ncurses-5.2
		jpeg? ( virtual/jpeg )
	  	ntfs? ( || ( >=sys-fs/ntfsprogs-2.0.0 sys-fs/ntfs3g ) )
	  	reiserfs? ( >=sys-fs/progsreiserfs-0.3.1_rc8 )
	  	>=sys-fs/e2fsprogs-1.35
		sys-libs/zlib"
RDEPEND="!static? ( ${DEPEND} )"

#S=${WORKDIR}/${P}-WIP

# merged upstream
#src_prepare() {
#	epatch "${FILESDIR}"/${P}-exif_bound_checking-v2.patch
#}

src_configure() {
	local myconf="--without-ewf --enable-sudo"
	# --with-foo are broken, any use of --with/--without disable the
	# functionality.
	# The following variation must be used.
	use reiserfs || myconf="${myconf} --without-reiserfs"
	use ntfs || myconf="${myconf} --without-ntfs"
	use jpeg || myconf="${myconf} --without-jpeg"

	# this is static method is the same used by upstream for their 'static' make
	# target, but better, as it doesn't break.
	use static && append-ldflags -static

	econf ${myconf} || die

	# perform safety checks for NTFS and REISERFS
	if useq ntfs && egrep -q 'undef HAVE_LIBNTFS\>' "${S}"/config.h ; then
		die "Failed to find NTFS library."
	fi
	if useq reiserfs && egrep -q 'undef HAVE_LIBREISERFS\>' "${S}"/config.h ; then
		die "Failed to find reiserfs library."
	fi
	if useq jpeg && egrep -q 'undef HAVE_LIBJPEG\>' "${S}"/config.h ; then
		die "Failed to find jpeg library."
	fi
}

src_install() {
	emake DESTDIR="${D}" install || die
	[ "$PF" != "$P" ] && mv "${D}"/usr/share/doc/${P} "${D}"/usr/share/doc/${PF}
}