[gentoo-commits] repo/proj/guru:dev commit in: net-nntp/inn/

[Anna Vyalkova]

commit:     cec17f7cc708b65953a65da434f7da8c48a131c4
Author:     Anna (cybertailor) Vyalkova <cyber+gentoo <AT> sysrq <DOT> in>
AuthorDate: Mon Jan  3 21:29:01 2022 +0000
Commit:     Anna Vyalkova <cyber+gentoo <AT> sysrq <DOT> in>
CommitDate: Mon Jan  3 21:35:56 2022 +0000
URL:        https://gitweb.gentoo.org/repo/proj/guru.git/commit/?id=cec17f7c

net-nntp/inn: initial import

Signed-off-by: Anna (cybertailor) Vyalkova <cyber+gentoo <AT> sysrq.in>

 net-nntp/inn/Manifest         |   2 +
 net-nntp/inn/inn-2.6.4.ebuild | 113 ++++++++++++++++++++++++++++++++++++++++++
 net-nntp/inn/metadata.xml     |  30 +++++++++++
 3 files changed, 145 insertions(+)

diff --git a/net-nntp/inn/Manifest b/net-nntp/inn/Manifest
new file mode 100644
index 000000000..86209df86
--- /dev/null
+++ b/net-nntp/inn/Manifest
@@ -0,0 +1,2 @@
+DIST inn-2.6.4.tar.gz 2610659 BLAKE2B 0cabe90b941f47d759179f71de10212ffb71c1955452ab1b04018a3f7dbb2f8fa0f2f3c534bda9fc08768b4ffa1034fcf2d59077fa1a5bb77801c74d11a6cab5 SHA512 0b1e4add9fe1f2a423f372adbce9622ffe943c75865427f30b18f5a5b8c2dae158d5bfa4d611631cb993757523bc858ca6ad907463bd5f91c60a851359a70c57
+DIST inn-2.6.4.tar.gz.sha256.asc 620 BLAKE2B e21d72effaf090a7a8bbc6f1b6fc8f2b6a604dfbc594ae1bba5f559e93e0b352bd255a2b12880dabbd038f6204003064b9744def43ea6cfc0cd52aec0779f279 SHA512 17ab70d3df9500f3fbe0ee2e359bbaf8d54fcd4337000b44ab7e74f87c65617740b052d942f9e0adcb901e017ed64367f55e4dbb07075ae734fd05fcd5d21396

diff --git a/net-nntp/inn/inn-2.6.4.ebuild b/net-nntp/inn/inn-2.6.4.ebuild
new file mode 100644
index 000000000..5b0671696
--- /dev/null
+++ b/net-nntp/inn/inn-2.6.4.ebuild
@@ -0,0 +1,113 @@
+# Copyright 2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..10} )
+
+inherit optfeature python-single-r1 verify-sig
+
+DESCRIPTION="InterNetNews -- the Internet meets Netnews"
+HOMEPAGE="https://www.eyrie.org/~eagle/software/inn/"
+SRC_URI="https://archives.eyrie.org/software/${PN}/${P}.tar.gz
+	verify-sig? ( https://archives.eyrie.org/software/${PN}/${P}.tar.gz.sha256.asc )"
+
+LICENSE="ISC"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="berkdb gzip kerberos keywords largefile low-memory +perl +python sasl ssl systemd zlib"
+REQUIRED_USE="
+	python? ( ${PYTHON_REQUIRED_USE} )
+	?? ( low-memory largefile )
+" # ?? ( bzip2 gzip )
+
+DEPEND="
+	app-crypt/gnupg
+	sys-libs/pam
+	virtual/libcrypt:=
+	virtual/sendmail
+	!berkdb? ( sys-libs/gdbm:= )
+	berkdb? ( sys-libs/db:* )
+	kerberos? ( app-crypt/mit-krb5 )
+	perl? ( dev-lang/perl:= )
+	python? ( ${PYTHON_DEPS} )
+	sasl? ( dev-libs/cyrus-sasl:2 )
+	ssl? ( dev-libs/openssl:= )
+	systemd? ( sys-apps/systemd:= )
+	zlib? ( sys-libs/zlib:= )
+"
+RDEPEND="${DEPEND}"
+BDEPEND="
+	sys-devel/flex
+	virtual/yacc
+	verify-sig? ( sec-keys/openpgp-keys-russallbery )
+"
+
+DOCS=(
+	ChangeLog CONTRIBUTORS HACKING INSTALL NEWS README TODO
+	doc/{checklist,external-auth,FAQ} doc/history{,-innfeed}
+	doc/hook-{perl,python} doc/{IPv6-info,sample-control}
+	doc/config-{design,semantics,syntax}
+)
+
+VERIFY_SIG_OPENPGP_KEY_PATH="${BROOT}/usr/share/openpgp-keys/russallbery.asc"
+
+src_unpack() {
+	if use verify-sig; then
+		pushd "${DISTDIR}" || die
+		verify-sig_verify_signed_checksums \
+			${P}.tar.gz.sha256.asc sha256 ${P}.tar.gz
+		popd || die
+	fi
+
+	unpack ${P}.tar.gz
+}
+
+src_configure() {
+	econf_args=(
+		--prefix=/opt/${PN}
+		$(use_enable keywords)
+		$(use_enable largefile largefiles)
+		$(use_enable low-memory tagged-hash)
+		$(use_with berkdb bdb)
+		$(use_with kerberos krb5)
+		$(use_with perl)
+		$(use_with python)
+		$(use_with sasl)
+		$(use_with ssl openssl)
+		$(use_with zlib)
+	)
+
+	if use gzip; then
+		econf_args+=( --with-log-compress=gzip )
+	else
+		econf_args+=( --with-log-compress=cat )
+	fi
+
+	econf "${econf_args[@]}"
+}
+
+src_compile() {
+	emake -j1
+}
+
+src_test() {
+	emake -j1 check
+}
+
+src_install() {
+	default
+
+	# collision with sys-apps/man-pages
+	mv "${ED}"/usr/share/man/man3/{list,inn-list}.3 || die
+
+	rm -r "${ED}"/opt/${PN}/{db,doc} || die
+}
+
+pkg_postinst() {
+	if use perl; then
+		optfeature "controlchan program" dev-perl/MIME-tools
+		optfeature "innreport script" dev-perl/GD
+		optfeature "send-uucp backend" net-misc/taylor-uucp
+	fi
+}

diff --git a/net-nntp/inn/metadata.xml b/net-nntp/inn/metadata.xml
new file mode 100644
index 000000000..3fa0a8245
--- /dev/null
+++ b/net-nntp/inn/metadata.xml
@@ -0,0 +1,30 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+<maintainer type="person">
+	<email>cyber+gentoo@×××××.in</email>
+	<name>Anna</name>
+</maintainer>
+<upstream>
+	<remote-id type="github">InterNetNews/inn</remote-id>
+	<bugs-to>https://github.com/InterNetNews/inn/issues</bugs-to>
+	<doc>https://www.eyrie.org/~eagle/software/inn/docs/</doc>
+	<maintainer>
+		<email>eagle@×××××.org</email>
+		<name>Russ Allbery</name>
+	</maintainer>
+</upstream>
+<longdescription>
+InterNetNews is a complete Usenet system. The cornerstone of the package is
+innd, an NNTP server that multiplexes all I/O. Newsreading is handled by a
+separate server, nnrpd, that is spawned for each client. Both innd and nnrpd
+have some slight variances from the NNTP protocol.
+</longdescription>
+<use>
+	<!--flag name="bzip2">Compress logs using bzip2</flag-->
+	<flag name="gzip">Compress logs using gzip</flag>
+	<flag name="keywords">Enable automatic innd keyword generation</flag>
+	<flag name="low-memory">Use tagged hash table for history to reduce memory footprint</flag>
+	<flag name="largefile">Support files larger than 2GB</flag>
+</use>
+</pkgmetadata>