[gentoo-commits] gentoo-x86 commit in dev-util/schroot: ChangeLog metadata.xml schroot-1.2.3.ebuild

[Jonathan Callen (abcd)]

abcd        09/09/11 07:16:30

  Added:                ChangeLog metadata.xml schroot-1.2.3.ebuild
  Log:
  New ebuild. Thanks to Nick Fortino <nfortino@×××××.com> for initial ebuild and patches (bug #257334).
  (Portage version: -svn/cvs/Linux i686)

Revision  Changes    Path
1.1                  dev-util/schroot/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-util/schroot/ChangeLog?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-util/schroot/ChangeLog?rev=1.1&content-type=text/plain

Index: ChangeLog
===================================================================
# ChangeLog for dev-util/schroot
# Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
# $Header: /var/cvsroot/gentoo-x86/dev-util/schroot/ChangeLog,v 1.1 2009/09/11 07:16:29 abcd Exp $

*schroot-1.2.3 (11 Sep 2009)

  11 Sep 2009; Jonathan Callen <abcd@g.o> +schroot-1.2.3.ebuild,
  +files/schroot-1.2.3-autotools.patch, +files/schroot-1.2.3-pam.patch,
  +files/schroot-1.2.3-tests.patch, +files/schroot.confd,
  +files/schroot.initd, +metadata.xml:
  New ebuild. Thanks to Nick Fortino <nfortino@×××××.com> for initial ebuild
  and patches (bug #257334).




1.1                  dev-util/schroot/metadata.xml

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-util/schroot/metadata.xml?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-util/schroot/metadata.xml?rev=1.1&content-type=text/plain

Index: metadata.xml
===================================================================
<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
<pkgmetadata>
<herd>no-herd</herd>
<maintainer>
  <email>abcd@g.o</email>
  <name>Jonathan Callen</name>
</maintainer>
<use>
  <flag name="dchroot">Enables the building of a wrapper named "dchroot", replacing <pkg>dev-util/dchroot</pkg>.</flag>
</use>
</pkgmetadata>



1.1                  dev-util/schroot/schroot-1.2.3.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-util/schroot/schroot-1.2.3.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-util/schroot/schroot-1.2.3.ebuild?rev=1.1&content-type=text/plain

Index: schroot-1.2.3.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-util/schroot/schroot-1.2.3.ebuild,v 1.1 2009/09/11 07:16:29 abcd Exp $

EAPI="2"

inherit autotools base

DESCRIPTION="Utility to execute commands in a chroot environment"
HOMEPAGE="http://packages.debian.org/source/sid/schroot"
SRC_URI="mirror://debian/pool/main/${PN:0:1}/${PN}/${PN}_${PV}.orig.tar.gz"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~x86"
IUSE="+dchroot debug doc nls test"

COMMON_DEPEND="
	>=dev-libs/boost-1.34.0
	dev-libs/lockdev
	sys-libs/pam
"

DEPEND="${COMMON_DEPEND}
	nls? ( sys-devel/gettext )
	test? ( >=dev-util/cppunit-1.10.0 )
"
RDEPEND="${COMMON_DEPEND}
	dchroot? ( !dev-util/dchroot )
	nls? ( virtual/libintl )
"

PATCHES=(
	"${FILESDIR}/${P}-autotools.patch"
	"${FILESDIR}/${P}-tests.patch"
)

src_prepare() {
	base_src_prepare

	if use test; then
		# Fix bug where aclocal doesn't find cppunit.m4 from the system...
		ln -s /usr/share/aclocal/cppunit.m4 m4/
		export AT_M4DIR=m4
	else
		# Don't depend on cppunit unless we are testing
		sed -i '/AM_PATH_CPPUNIT/d' configure.ac
	fi

	eautoreconf
}

src_configure() {
	econf \
		$(use_enable dchroot) \
		$(use_enable dchroot dchroot-dsa) \
		$(use_enable debug) \
		$(use_enable nls) \
		--enable-shared \
		--disable-static \
		--localstatedir=/var
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"

	newinitd "${FILESDIR}"/schroot.initd schroot || die "installation of init.d script failed"
	newconfd "${FILESDIR}"/schroot.confd schroot || die "installation of conf.d file failed"

	dodoc AUTHORS ChangeLog NEWS README THANKS TODO || die "installation of docs failed"
	if use doc; then
		insinto /usr/share/doc/${PF}/html/sbuild
		doins doc/sbuild/html/* || die "installation of html docs failed"
		insinto /usr/share/doc/${PF}/html/schroot
		doins doc/schroot/html/* || die "installation of html docs failed"
	fi
}