[gentoo-commits] gentoo-x86 commit in sys-apps/pciutils: ChangeLog pciutils-3.1.4.ebuild

[Mike Frysinger (vapier)]

vapier      09/08/23 09:35:36

  Modified:             ChangeLog
  Added:                pciutils-3.1.4.ebuild
  Log:
  Version bump #276540 by Lars Wendler.
  (Portage version: 2.2_rc38/cvs/Linux x86_64)

Revision  Changes    Path
1.165                sys-apps/pciutils/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-apps/pciutils/ChangeLog?rev=1.165&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-apps/pciutils/ChangeLog?rev=1.165&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-apps/pciutils/ChangeLog?r1=1.164&r2=1.165

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-apps/pciutils/ChangeLog,v
retrieving revision 1.164
retrieving revision 1.165
diff -u -r1.164 -r1.165
--- ChangeLog	5 Apr 2009 03:21:42 -0000	1.164
+++ ChangeLog	23 Aug 2009 09:35:36 -0000	1.165
@@ -1,6 +1,11 @@
 # ChangeLog for sys-apps/pciutils
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/pciutils/ChangeLog,v 1.164 2009/04/05 03:21:42 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/pciutils/ChangeLog,v 1.165 2009/08/23 09:35:36 vapier Exp $
+
+*pciutils-3.1.4 (23 Aug 2009)
+
+  23 Aug 2009; Mike Frysinger <vapier@g.o> +pciutils-3.1.4.ebuild:
+  Version bump #276540 by Lars Wendler.
 
   05 Apr 2009; Mike Frysinger <vapier@g.o>
   files/pciutils-2.2.7-update-pciids-both-forms.patch:



1.1                  sys-apps/pciutils/pciutils-3.1.4.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-apps/pciutils/pciutils-3.1.4.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-apps/pciutils/pciutils-3.1.4.ebuild?rev=1.1&content-type=text/plain

Index: pciutils-3.1.4.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-apps/pciutils/pciutils-3.1.4.ebuild,v 1.1 2009/08/23 09:35:36 vapier Exp $

inherit eutils multilib

DESCRIPTION="Various utilities dealing with the PCI bus"
HOMEPAGE="http://atrey.karlin.mff.cuni.cz/~mj/pciutils.html"
SRC_URI="ftp://atrey.karlin.mff.cuni.cz/pub/linux/pci/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd"
IUSE="network-cron zlib"

DEPEND="zlib? ( sys-libs/zlib )"

src_unpack() {
	unpack ${A}
	cd "${S}"
	epatch "${FILESDIR}"/${PN}-2.2.7-update-pciids-both-forms.patch
	sed -i -e "/^LIBDIR=/s:/lib:/$(get_libdir):" Makefile
}

uyesno() { use $1 && echo yes || echo no ; }
pemake() {
	emake \
		HOST="${CHOST}" \
		CROSS_COMPILE="${CHOST}-" \
		DNS="yes" \
		IDSDIR="/usr/share/misc" \
		MANDIR="/usr/share/man" \
		PREFIX="/usr" \
		SHARED="yes" \
		STRIP="" \
		ZLIB=$(uyesno zlib) \
		"$@"
}

src_compile() {
	pemake OPT="${CFLAGS}" all || die
}

src_install() {
	pemake DESTDIR="${D}" install || die
	dodoc ChangeLog README TODO

	if use network-cron ; then
		exeinto /etc/cron.monthly
		newexe "${FILESDIR}"/pciutils.cron update-pciids \
			|| die "Failed to install update cronjob"
	fi

	# Install both forms until HAL has migrated
	if use zlib ; then
		local sharedir="${D}/usr/share/misc"
		elog "Providing a backwards compatibility non-compressed pci.ids"
		gzip -d <"${sharedir}"/pci.ids.gz >"${sharedir}"/pci.ids
	fi

	newinitd "${FILESDIR}"/init.d-pciparm pciparm
	newconfd "${FILESDIR}"/conf.d-pciparm pciparm
}

pkg_postinst() {
	elog "The 'pcimodules' program has been replaced by 'lspci -k'"
}