[gentoo-commits] repo/gentoo:master commit in: dev-python/oslo-utils/

[Matt Thode]

commit:     5f5c5a28455ddfcb53de7dfd721e8c17916d9504
Author:     Matthew Thode <prometheanfire <AT> gentoo <DOT> org>
AuthorDate: Fri Feb 16 05:47:16 2018 +0000
Commit:     Matt Thode <prometheanfire <AT> gentoo <DOT> org>
CommitDate: Fri Feb 16 05:47:16 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=5f5c5a28

dev-python/oslo-utils: 3.35.0 bup

Package-Manager: Portage-2.3.19, Repoman-2.3.6

 dev-python/oslo-utils/Manifest                 |  1 +
 dev-python/oslo-utils/oslo-utils-3.35.0.ebuild | 95 ++++++++++++++++++++++++++
 2 files changed, 96 insertions(+)

diff --git a/dev-python/oslo-utils/Manifest b/dev-python/oslo-utils/Manifest
index 77350c09ca0..6f0f84d4049 100644
--- a/dev-python/oslo-utils/Manifest
+++ b/dev-python/oslo-utils/Manifest
@@ -1 +1,2 @@
 DIST oslo-utils-3.28.1.tar.gz 85889 BLAKE2B b789bcee79f30a59a178c51997b42bc63bc67b998aedf2972b7f01c098992236eb2535a4e7fc43cbde5888340b0b14930093b49142fc9434fa7ea0069733b7d7 SHA512 f46c097378af27b8b1e7c9ff0908e3077c19c819ca02a9c181a54fd77a62506668ca22b42d5127a9e49f62244d034b5cef0b7c8c751b55a651a6f46fff0b4c02
+DIST oslo-utils-3.35.0.tar.gz 86107 BLAKE2B 2b4e00af5993799e43b40d63c667fb582984f8abbdd768203e0c95d2ecaf0f8ea10ba70ed520c116ed0da841dcac479d81881b4061ffe3529d8fe26917bb264f SHA512 dee75fd36b1c3fbccbb432408769c15d17b7dfdeef3b6f7056218670ca2c7e97a1e98acae3e06810f842a8e20fab1cf419b23153cde94c93e6b60e498ae2f527

diff --git a/dev-python/oslo-utils/oslo-utils-3.35.0.ebuild b/dev-python/oslo-utils/oslo-utils-3.35.0.ebuild
new file mode 100644
index 00000000000..90b8d63dc81
--- /dev/null
+++ b/dev-python/oslo-utils/oslo-utils-3.35.0.ebuild
@@ -0,0 +1,95 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 python3_{4,5,6} )
+
+inherit distutils-r1 vcs-snapshot
+
+MY_PN=${PN/-/.}
+
+DESCRIPTION="Oslo Utility library"
+HOMEPAGE="https://launchpad.net/oslo"
+SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_PN}-${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="doc test"
+
+CDEPEND=">=dev-python/pbr-2.0.0[${PYTHON_USEDEP}]
+	!~dev-python/pbr-2.1.0[${PYTHON_USEDEP}]"
+DEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	${CDEPEND}
+	test? (
+		>=dev-python/fixtures-3.0.0[${PYTHON_USEDEP}]
+		>=dev-python/testrepository-0.0.18[${PYTHON_USEDEP}]
+		>=dev-python/testscenarios-0.4[${PYTHON_USEDEP}]
+		>=dev-python/testtools-2.2.0[${PYTHON_USEDEP}]
+		>=dev-python/oslotest-1.10.0[${PYTHON_USEDEP}]
+		>=dev-python/ddt-1.0.1[${PYTHON_USEDEP}]
+		>=dev-python/coverage-4.0.0[${PYTHON_USEDEP}]
+		!~dev-python/coverage-4.4.0[${PYTHON_USEDEP}]
+		>=dev-python/mock-2.0.0[${PYTHON_USEDEP}]
+		>=dev-python/oslo-config-5.1.0[${PYTHON_USEDEP}]
+		>=dev-python/bandit-1.1.0[${PYTHON_USEDEP}]
+	)
+	doc? (
+		>=dev-python/sphinx-1.6.2[${PYTHON_USEDEP}]
+		!~dev-python/sphinx-1.6.6[${PYTHON_USEDEP}]
+		>=dev-python/openstackdocstheme-1.18.1[${PYTHON_USEDEP}]
+		>=dev-python/reno-2.5.0[${PYTHON_USEDEP}]
+		>=dev-python/fixtures-3.0.0[${PYTHON_USEDEP}]
+	)
+"
+RDEPEND="
+	${CDEPEND}
+	>=dev-python/six-1.10.0[${PYTHON_USEDEP}]
+	virtual/python-funcsigs[${PYTHON_USEDEP}]
+	>=dev-python/iso8601-0.1.11[${PYTHON_USEDEP}]
+	>=dev-python/oslo-i18n-3.15.3[${PYTHON_USEDEP}]
+	>=dev-python/monotonic-0.6[${PYTHON_USEDEP}]
+	>=dev-python/pytz-2013.6[${PYTHON_USEDEP}]
+	>=dev-python/netaddr-0.7.18[${PYTHON_USEDEP}]
+	>=dev-python/netifaces-0.10.4[${PYTHON_USEDEP}]
+	>=dev-python/debtcollector-1.2.0[${PYTHON_USEDEP}]
+	>=dev-python/pyparsing-2.1.0[${PYTHON_USEDEP}]
+"
+
+python_prepare_all() {
+	sed -i '/^hacking/d' test-requirements.txt || die
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	use doc && esetup.py build_sphinx
+}
+
+# Note: Tests fail due to requiring installation
+#
+# Installation appears to fail due to the use of namespace packages but root
+# cause was never truly established.
+#
+# Tests fail with:
+# ImportError: No module named 'oslo.utils
+
+#RESTRICT="test"
+
+python_test() {
+	distutils_install_for_testing
+
+	cd "${TEST_DIR}"/lib || die
+
+	rm -rf .testrepository || die "couldn't remove '.testrepository' under ${EPTYHON}"
+
+	testr init || die "testr init failed under ${EPYTHON}"
+	testr run || die "testr run failed under ${EPYTHON}"
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( doc/build/html/. )
+
+	distutils-r1_python_install_all
+}