[gentoo-commits] repo/gentoo:master commit in: sys-apps/usbutils/

[Mike Gilbert]

commit:     5e8affc7dca726a84fd5764058e09392c6dfbebf
Author:     Mike Gilbert <floppym <AT> gentoo <DOT> org>
AuthorDate: Thu Nov 25 00:49:51 2021 +0000
Commit:     Mike Gilbert <floppym <AT> gentoo <DOT> org>
CommitDate: Sun Nov 28 19:54:03 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=5e8affc7

sys-apps/usbutils: migrate to hwdata

Signed-off-by: Mike Gilbert <floppym <AT> gentoo.org>

 sys-apps/usbutils/usbutils-014-r1.ebuild | 59 ++++++++++++++++++++++++++++++++
 1 file changed, 59 insertions(+)

diff --git a/sys-apps/usbutils/usbutils-014-r1.ebuild b/sys-apps/usbutils/usbutils-014-r1.ebuild
new file mode 100644
index 000000000000..cee126405f8d
--- /dev/null
+++ b/sys-apps/usbutils/usbutils-014-r1.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{8,9} )
+
+inherit autotools python-single-r1
+
+DESCRIPTION="USB enumeration utilities"
+HOMEPAGE="https://www.kernel.org/pub/linux/utils/usb/usbutils/
+	https://git.kernel.org/pub/scm/linux/kernel/git/gregkh/usbutils.git/"
+SRC_URI="https://www.kernel.org/pub/linux/utils/usb/${PN}/${P}.tar.xz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux"
+IUSE="python"
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+DEPEND="virtual/libusb:1=
+	virtual/libudev:="
+BDEPEND="
+	app-arch/xz-utils
+	virtual/pkgconfig
+	python? ( ${PYTHON_DEPS} )"
+RDEPEND="${DEPEND}
+	python? (
+		${PYTHON_DEPS}
+		sys-apps/hwdata
+	)
+"
+
+pkg_setup() {
+	use python && python-single-r1_pkg_setup
+}
+
+src_prepare() {
+	default
+	eautoreconf
+	use python && python_fix_shebang lsusb.py.in
+}
+
+src_configure() {
+	local myeconfargs=(
+		--datarootdir="${EPREFIX}/usr/share"
+		--datadir="${EPREFIX}/usr/share/hwdata"
+	)
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	default
+	newdoc usbhid-dump/NEWS NEWS.usbhid-dump
+	dobin usbreset # noinst_PROGRAMS, but installed by other distros
+
+	if ! use python ; then
+		rm -f "${ED}"/usr/bin/lsusb.py || die
+	fi
+}