[gentoo-commits] gentoo-x86 commit in media-libs/flac: ChangeLog flac-1.3.1.ebuild

[Tim Harder (radhermit)]

radhermit    14/11/27 13:45:34

  Modified:             ChangeLog
  Added:                flac-1.3.1.ebuild
  Log:
  Version bump (bug #530848) and fix prefix support (bug #529566).
  
  (Portage version: 2.2.14/cvs/Linux x86_64, signed Manifest commit with key 4AB3E85B4F064CA3)

Revision  Changes    Path
1.180                media-libs/flac/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/flac/ChangeLog?rev=1.180&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/flac/ChangeLog?rev=1.180&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/flac/ChangeLog?r1=1.179&r2=1.180

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-libs/flac/ChangeLog,v
retrieving revision 1.179
retrieving revision 1.180
diff -u -r1.179 -r1.180
--- ChangeLog	27 Sep 2014 22:16:21 -0000	1.179
+++ ChangeLog	27 Nov 2014 13:45:34 -0000	1.180
@@ -1,6 +1,11 @@
 # ChangeLog for media-libs/flac
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/flac/ChangeLog,v 1.179 2014/09/27 22:16:21 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-libs/flac/ChangeLog,v 1.180 2014/11/27 13:45:34 radhermit Exp $
+
+*flac-1.3.1 (27 Nov 2014)
+
+  27 Nov 2014; Tim Harder <radhermit@g.o> +flac-1.3.1.ebuild:
+  Version bump (bug #530848) and fix prefix support (bug #529566).
 
 *flac-1.3.0-r1 (27 Sep 2014)
 



1.1                  media-libs/flac/flac-1.3.1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/flac/flac-1.3.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/flac/flac-1.3.1.ebuild?rev=1.1&content-type=text/plain

Index: flac-1.3.1.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-libs/flac/flac-1.3.1.ebuild,v 1.1 2014/11/27 13:45:34 radhermit Exp $

EAPI=5
AUTOTOOLS_AUTORECONF=1
AUTOTOOLS_PRUNE_LIBTOOL_FILES=all

inherit autotools-multilib

DESCRIPTION="free lossless audio encoder and decoder"
HOMEPAGE="http://flac.sourceforge.net"
SRC_URI="http://downloads.xiph.org/releases/${PN}/${P}.tar.xz"

LICENSE="BSD FDL-1.2 GPL-2 LGPL-2.1"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd"
IUSE="3dnow altivec +cxx debug ogg sse static-libs"

RDEPEND="ogg? ( >=media-libs/libogg-1.3.0[${MULTILIB_USEDEP}] )
	abi_x86_32? (
		!<=app-emulation/emul-linux-x86-soundlibs-20130224-r1
		!app-emulation/emul-linux-x86-soundlibs[-abi_x86_32(-)]
	)"
DEPEND="${RDEPEND}
	app-arch/xz-utils
	abi_x86_32? ( dev-lang/nasm )
	!elibc_uclibc? ( sys-devel/gettext )
	virtual/pkgconfig"

src_prepare() {
	local PATCHES=(
		"${FILESDIR}"/${PN}-1.3.0-asneeded.patch
		"${FILESDIR}"/${PN}-1.3.0-dontbuild-tests.patch
		"${FILESDIR}"/${PN}-1.3.0-dontbuild-examples.patch
	)

	AT_M4DIR="m4" autotools-multilib_src_prepare
}

src_configure() {
	local myeconfargs=(
		$(use_enable debug)
		$(use_enable sse)
		$(use_enable 3dnow)
		$(use_enable altivec)
		--disable-doxygen-docs
		--disable-xmms-plugin
		$(use_enable cxx cpplibs)
		$(use_enable ogg)
		--disable-examples
		$([[ ${CHOST} == *-darwin* ]] && echo "--disable-asm-optimizations")
	)
	autotools-multilib_src_configure
}

src_test() {
	if [[ ${UID} != 0 ]]; then
		autotools-multilib_src_test -j1
	else
		ewarn "Tests will fail if ran as root, skipping."
	fi
}

src_install() {
	autotools-multilib_src_install \
		docdir="${EPREFIX}"/usr/share/doc/${PF}/html
}