[gentoo-commits] repo/gentoo:master commit in: media-libs/gegl/

[Sebastian Pipping]

commit:     b6e1da66c9d91081748a4d8c5ef02c16319fb8d5
Author:     Sebastian Pipping <sping <AT> gentoo <DOT> org>
AuthorDate: Sat Dec  5 00:39:03 2015 +0000
Commit:     Sebastian Pipping <sping <AT> gentoo <DOT> org>
CommitDate: Sat Dec  5 01:42:16 2015 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=b6e1da66

media-libs/gegl: 0.3.4 (bug #567366)

Package-Manager: portage-2.2.24

 media-libs/gegl/Manifest          |   1 +
 media-libs/gegl/gegl-0.3.4.ebuild | 183 ++++++++++++++++++++++++++++++++++++++
 2 files changed, 184 insertions(+)

diff --git a/media-libs/gegl/Manifest b/media-libs/gegl/Manifest
index 85500bb..1ff8e83 100644
--- a/media-libs/gegl/Manifest
+++ b/media-libs/gegl/Manifest
@@ -1,3 +1,4 @@
 DIST gegl-0.2.0.tar.bz2 7502040 SHA256 df2e6a0d9499afcbc4f9029c18d9d1e0dd5e8710a75e17c9b1d9a6480dd8d426 SHA512 16ef3f6852fd8efef2b6468a754342a2d003f2c2bef468d9465a448e6c89dedb8e791570f073a9faed05218a7c94c6c418eaa0f3abeadfb3e6b88d766ab792c8 WHIRLPOOL 74e9c18b095526b1d053f0700b3c3776197a5c1066cb77adb7c83f154aae9087319f7b7f0379fb9e895a5ef3ac62ebf05e2158c1d18180bafcef41dff096c01d
 DIST gegl-0.3.0.tar.bz2 5463571 SHA256 f0fec8f2e7b8835979d3cf4e38b05d41bb79f68dc80cf899a846484da693bbf7 SHA512 ff758df4689b0fa8f5e16ebcea32a7fe77bccfef70efc20d10669ce5139a70ec3533e78227fd4798812b31ac1ca5081b9d1d701a7449bf75356f879ece5fadd6 WHIRLPOOL 4827d6e40025c36d4ef869b5856f4def1e93cc195757f430cfd2980742ce6b37c79833283d17ec51e93b569a144548aaf7021854b9bcdb241b90049b1321a99b
 DIST gegl-0.3.2.tar.bz2 5325146 SHA256 b82f6e07e977dd7c2b6e671e9e029614840a66f0ca58defb22c0b05ed3ea485c SHA512 207d23a62cc447b0f6837e1901410114a63fe1a1b92a08d3c92941bfb461d04e320e02332e013ce26383641fdf1011fb4d3f4b6ce0370030c3fe770a49634a51 WHIRLPOOL 74105180350a621e9f445bcc0040f712f8129792199c4e9be086008854866d0bf4b369dd7f5c96acb2ac4454d34cff7ed4edf4460bc5e632109d1ed294e330eb
+DIST gegl-0.3.4.tar.bz2 5328192 SHA256 846290a790854d1e6b7c17a2d6f82ad7cb14c72e240bd3b81b98cc0ceddbc3ec SHA512 7fe14c1534d61cfc253bce54cc707f93882ad96302068fe672e6cdcb613430e835ee5d39a5398537f845a6d101eed6fd3d1ff7e4204d51bc9ab5a59c9e09d2ec WHIRLPOOL 046af673b5a21a050555fabf5e52532b5de7af289922991f0c15cc39a09d32302a6a98483bd4ff2cee3a37356d0cf0e267c87f524f3b6678eb61fcaab6d6735c

diff --git a/media-libs/gegl/gegl-0.3.4.ebuild b/media-libs/gegl/gegl-0.3.4.ebuild
new file mode 100644
index 0000000..4fca26c
--- /dev/null
+++ b/media-libs/gegl/gegl-0.3.4.ebuild
@@ -0,0 +1,183 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+PYTHON_COMPAT=( python2_7 )
+
+# vala and introspection support is broken, bug #468208
+VALA_MIN_API_VERSION=0.20
+VALA_USE_DEPEND=vapigen
+
+inherit versionator gnome2-utils eutils autotools python-any-r1 vala
+
+if [[ ${PV} == *9999* ]]; then
+	inherit autotools git-r3
+	EGIT_REPO_URI="git://git.gnome.org/gegl"
+	SRC_URI=""
+else
+	SRC_URI="http://download.gimp.org/pub/${PN}/${PV:0:3}/${P}.tar.bz2"
+	KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~amd64-fbsd ~amd64-linux ~arm-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~x64-solaris ~x86-solaris"
+fi
+
+DESCRIPTION="A graph based image processing framework"
+HOMEPAGE="http://www.gegl.org/"
+
+LICENSE="|| ( GPL-3 LGPL-3 )"
+SLOT="0.3"
+
+IUSE="cairo cpu_flags_x86_mmx cpu_flags_x86_sse debug ffmpeg +introspection jpeg jpeg2k lcms lensfun libav openexr png raw sdl svg test tiff umfpack vala v4l webp"
+REQUIRED_IUSE="
+	svg? ( cairo )
+	vala? ( introspection )
+"
+
+RDEPEND="
+	>=dev-libs/glib-2.36:2
+	dev-libs/json-glib
+	>=media-libs/babl-0.1.14
+	sys-libs/zlib
+	>=x11-libs/gdk-pixbuf-2.18:2
+	x11-libs/pango
+
+	cairo? ( x11-libs/cairo )
+	ffmpeg? (
+		libav? ( media-video/libav:0= )
+		!libav? ( media-video/ffmpeg:0= )
+	)
+	introspection? ( >=dev-libs/gobject-introspection-1.32 )
+	jpeg? ( virtual/jpeg:0= )
+	jpeg2k? ( >=media-libs/jasper-1.900.1 )
+	lcms? ( >=media-libs/lcms-2.2:2 )
+	lensfun? ( >=media-libs/lensfun-0.2.5 )
+	openexr? ( media-libs/openexr )
+	png? ( media-libs/libpng:0= )
+	raw? ( >=media-libs/libraw-0.15.4 )
+	sdl? ( media-libs/libsdl )
+	svg? ( >=gnome-base/librsvg-2.14:2 )
+	tiff? ( >=media-libs/tiff-4:0 )
+	umfpack? ( sci-libs/umfpack )
+	v4l? ( >=media-libs/libv4l-1.0.1 )
+	webp? ( media-libs/libwebp )
+"
+DEPEND="${RDEPEND}
+	>=dev-util/gtk-doc-am-1
+	>=dev-util/intltool-0.40.1
+	dev-lang/perl
+	virtual/pkgconfig
+	>=sys-devel/libtool-2.2
+	test? ( introspection? (
+		$(python_gen_any_dep '>=dev-python/pygobject-3.2[${PYTHON_USEDEP}]') ) )
+	vala? ( $(vala_depend) )
+"
+
+pkg_setup() {
+	use test && use introspection && python-any-r1_pkg_setup
+}
+
+src_prepare() {
+	# FIXME: the following should be proper patch sent to upstream
+	# fix OSX loadable module filename extension
+	sed -i -e 's/\.dylib/.bundle/' configure.ac || die
+	# don't require Apple's OpenCL on versions of OSX that don't have it
+	if [[ ${CHOST} == *-darwin* && ${CHOST#*-darwin} -le 9 ]] ; then
+		sed -i -e 's/#ifdef __APPLE__/#if 0/' gegl/opencl/* || die
+	fi
+
+	#epatch "${FILESDIR}"/${P}-g_log_domain.patch
+
+	# commit 7c78497b : tests that use gegl.png are broken on non-amd64
+	sed -e '/clones.xml/d' \
+		-e '/composite-transform.xml/d' \
+		-i tests/compositions/Makefile.am || die
+
+	epatch_user
+	eautoreconf
+
+	use vala && vala_src_prepare
+}
+
+src_configure() {
+	# never enable altering of CFLAGS via profile option
+	# libspiro: not in portage main tree
+	# disable documentation as the generating is bit automagic
+	#    if anyone wants to work on it just create bug with patch
+
+	# Also please note that:
+	#
+	#  - Some auto-detections are not patched away since the docs are
+	#    not built (--disable-docs, lack of --enable-gtk-doc) and these
+	#    tools affect re-generation of docs, only
+	#    (e.g. ruby, asciidoc, dot (of graphviz), enscript)
+	#
+	#  - Parameter --with-exiv2 compiles a noinst-app only, no use
+	#
+	#  - Parameter --disable-workshop disables any use of Lua, effectivly
+	#
+	#  - v4l support does not work with our media-libs/libv4l-0.8.9,
+	#    upstream bug at https://bugzilla.gnome.org/show_bug.cgi?id=654675
+	#
+	#  - There are two checks for dot, one controllable by --with(out)-graphviz
+	#    which toggles HAVE_GRAPHVIZ that is not used anywhere.  Yes.
+	#
+	#  - mrg is not in tree and gexiv2 support only has effect when mrg support
+	#    is enabled
+	#
+	# So that's why USE="exif graphviz lua v4l" got resolved.  More at:
+	# https://bugs.gentoo.org/show_bug.cgi?id=451136
+	#
+	econf \
+		--disable-docs \
+		--disable-profile \
+		--disable-silent-rules \
+		--disable-workshop \
+		--program-suffix=-${SLOT} \
+		--with-gdk-pixbuf \
+		--with-pango \
+		--without-libspiro \
+		$(use_enable cpu_flags_x86_mmx mmx) \
+		$(use_enable cpu_flags_x86_sse sse) \
+		$(use_enable debug) \
+		$(use_with cairo) \
+		$(use_with cairo pangocairo) \
+		--without-exiv2 \
+		$(use_with ffmpeg libavformat) \
+		--without-gexiv2 \
+		--without-graphviz \
+		$(use_with jpeg libjpeg) \
+		$(use_with jpeg2k jasper) \
+		$(use_with lcms) \
+		$(use_with lensfun) \
+		--without-lua \
+		--without-mrg \
+		$(use_with openexr) \
+		$(use_with png libpng) \
+		$(use_with raw libraw) \
+		$(use_with sdl) \
+		$(use_with svg librsvg) \
+		$(use_with tiff libtiff) \
+		$(use_with umfpack) \
+		$(use_with v4l libv4l) \
+		$(use_with v4l libv4l2) \
+		$(use_enable introspection) \
+		$(use_with vala) \
+		$(use_with webp)
+}
+
+src_test() {
+	gnome2_environment_reset  # sandbox issues
+	default
+}
+
+src_compile() {
+	gnome2_environment_reset  # sandbox issues (bug #396687)
+	default
+
+	[[ ${PV} == *9999* ]] && emake ./ChangeLog  # "./" prevents "Circular ChangeLog <- ChangeLog dependency dropped."
+}
+
+src_install() {
+	default
+	prune_libtool_files --all
+}