[gentoo-commits] repo/gentoo:master commit in: dev-libs/efl/

[Joonas Niilola]

commit:     f3a39471d43e936d8d47cc203aa056c8f1032ec8
Author:     Joonas Niilola <juippis <AT> gentoo <DOT> org>
AuthorDate: Wed Apr 29 17:00:09 2020 +0000
Commit:     Joonas Niilola <juippis <AT> gentoo <DOT> org>
CommitDate: Wed Apr 29 17:04:46 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=f3a39471

dev-libs/efl: bump to 1.24.0

Signed-off-by: Joonas Niilola <juippis <AT> gentoo.org>

 dev-libs/efl/Manifest          |   1 +
 dev-libs/efl/efl-1.24.0.ebuild | 277 +++++++++++++++++++++++++++++++++++++++++
 2 files changed, 278 insertions(+)

diff --git a/dev-libs/efl/Manifest b/dev-libs/efl/Manifest
index ce9f61ed5b1..7e1ea58e219 100644
--- a/dev-libs/efl/Manifest
+++ b/dev-libs/efl/Manifest
@@ -1 +1,2 @@
 DIST efl-1.23.3.tar.xz 77485032 BLAKE2B e5f65080aec1d11a43f1e1786b8ac4e7be70ddd9614b53db822177c28ee73f9590f63d032df5ddf00db6224730b45b045d9f91da2287a4dec7589e902cbcde28 SHA512 47ad067c43d39b534834195f89a745c4a47d867f33aaa68c28c6dccd147379e9bc2416bd68878cc16585f8cb60e926a7df62102658b205756c01985f37f0d297
+DIST efl-1.24.0.tar.xz 72274848 BLAKE2B f1652f334de618778eb1c70d05f101554b57676bd6bce462c21169969d3c005b52c35c4d95dcd015641e202fc3dc1034387f6d7d41b47521ca890fb62543b0fb SHA512 a3415e79eb0d13c1393f80728527d2b663b35e1b9ec815fadd0b43d754320ee8461aeade781b0264853e7935e920df7a5cc0b438c6b8a15a5744380a32f55080

diff --git a/dev-libs/efl/efl-1.24.0.ebuild b/dev-libs/efl/efl-1.24.0.ebuild
new file mode 100644
index 00000000000..15c656409f9
--- /dev/null
+++ b/dev-libs/efl/efl-1.24.0.ebuild
@@ -0,0 +1,277 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit meson xdg-utils
+
+DESCRIPTION="Enlightenment Foundation Libraries all-in-one package"
+HOMEPAGE="https://www.enlightenment.org"
+SRC_URI="https://download.enlightenment.org/rel/libs/${PN}/${P}.tar.xz"
+
+LICENSE="BSD-2 GPL-2 LGPL-2.1 ZLIB"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~hppa ~ppc ~ppc64 ~x86"
+IUSE="+X bmp connman dds debug doc drm +eet elogind examples fbcon fontconfig
+	fribidi gif gles2 gnutls glib +gstreamer harfbuzz hyphen ibus ico libressl
+	lua +luajit jpeg2k json nls mono opengl +pdf physics pmaps postscript psd
+	pulseaudio raw scim sdl +sound +ssl +svg +system-lz4 systemd tga tgv tiff
+	tslib unwind v4l vnc wayland webp xcf xim xpm xpresent zeroconf"
+
+REQUIRED_USE="
+	?? ( elogind systemd )
+	?? ( gles2 opengl )
+	^^ ( lua luajit )
+	ssl
+	drm? ( gles2 )
+	examples? ( eet svg )
+	gles2? ( || ( wayland X ) )
+	pulseaudio? ( sound )
+	wayland? ( gles2 !opengl )
+	xim? ( X )
+	xpresent? ( X )
+"
+
+# Requires everything to be enabled unconditionally.
+RESTRICT="test"
+
+RDEPEND="
+	dev-libs/check
+	net-misc/curl
+	media-libs/giflib:=
+	media-libs/libpng:0=
+	sys-apps/dbus
+	sys-libs/zlib
+	virtual/jpeg:0=
+	X? (
+		media-libs/freetype
+		x11-libs/libX11
+		x11-libs/libXcomposite
+		x11-libs/libXcursor
+		x11-libs/libXdamage
+		x11-libs/libXdmcp
+		x11-libs/libXext
+		x11-libs/libXfixes
+		x11-libs/libXi
+		x11-libs/libXinerama
+		x11-libs/libXrandr
+		x11-libs/libXrender
+		x11-libs/libXtst
+		x11-libs/libXScrnSaver
+		wayland? ( x11-libs/libxkbcommon[X] )
+	)
+	connman? ( net-misc/connman )
+	drm? (
+		dev-libs/libinput
+		dev-libs/wayland
+		media-libs/mesa[gbm]
+		x11-libs/libdrm
+		x11-libs/libxkbcommon
+	)
+	elogind? (
+		sys-auth/elogind
+		virtual/libudev
+	)
+	fontconfig? ( media-libs/fontconfig )
+	fribidi? ( dev-libs/fribidi )
+	gles2? (
+		media-libs/mesa[egl,gles2]
+		virtual/opengl
+	)
+	glib? ( dev-libs/glib:2 )
+	gstreamer? (
+		media-libs/gstreamer:1.0
+		media-libs/gst-plugins-base:1.0
+	)
+	hyphen? ( dev-libs/hyphen )
+	ibus? ( app-i18n/ibus )
+	jpeg2k? ( media-libs/openjpeg:= )
+	json? ( >=media-libs/rlottie-0.0.1_pre20191101 )
+	lua? ( dev-lang/lua:* )
+	luajit? ( dev-lang/luajit:* )
+	mono? ( dev-lang/mono )
+	opengl? ( virtual/opengl )
+	pdf? ( app-text/poppler:=[cxx] )
+	physics? ( sci-physics/bullet:= )
+	postscript? ( app-text/libspectre )
+	pulseaudio? ( media-sound/pulseaudio )
+	raw? ( media-libs/libraw:= )
+	scim? ( app-i18n/scim )
+	sdl? ( media-libs/libsdl2 )
+	sound? ( media-libs/libsndfile )
+	ssl? (
+		gnutls? ( net-libs/gnutls:= )
+		!gnutls? (
+			!libressl? ( dev-libs/openssl:0= )
+			libressl? ( dev-libs/libressl:= )
+		)
+	)
+	svg? ( gnome-base/librsvg )
+	system-lz4? ( app-arch/lz4 )
+	systemd? ( sys-apps/systemd:= )
+	tiff? ( media-libs/tiff:0= )
+	tslib? ( x11-libs/tslib:= )
+	unwind? ( sys-libs/libunwind )
+	v4l? ( media-libs/libv4l )
+	vnc? ( net-libs/libvncserver )
+	wayland? (
+		dev-libs/wayland
+		media-libs/mesa[gles2,wayland]
+		x11-libs/libxkbcommon
+	)
+	webp? ( media-libs/libwebp:= )
+	xpm? ( x11-libs/libXpm )
+	xpresent? ( x11-libs/libXpresent )
+	zeroconf? ( net-dns/avahi )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig
+	doc? ( app-doc/doxygen )
+	nls? ( sys-devel/gettext )"
+
+src_configure() {
+	local emesonargs=(
+		--buildtype=release
+
+		-D buffer=false
+		-D cocoa=false
+		-D drm-deprecated=false
+		-D g-mainloop=false
+		-D install-eo-files=true
+		-D mono-beta=false
+		-D dotnet=false
+		-D pixman=false
+		-D wl-deprecated=false
+		-D dotnet-stylecop-severity=Warning
+
+		-D edje-sound-and-video=true
+		-D eeze=true
+		-D libmount=true
+		-D native-arch-optimization=true
+		-D xinput2=true
+		-D xinput22=true
+
+		$(meson_use X x11)
+		$(meson_use debug debug-threads)
+		$(meson_use drm)
+		$(meson_use elogind)
+		$(meson_use examples build-examples)
+		$(meson_use fbcon fb)
+		$(meson_use fontconfig)
+		$(meson_use fribidi)
+		$(meson_use glib)
+		$(meson_use gstreamer)
+		$(meson_use harfbuzz)
+		$(meson_use hyphen)
+		$(meson_use luajit elua)
+		$(meson_use nls)
+		$(meson_use physics)
+		$(meson_use pulseaudio)
+		$(meson_use sdl)
+		$(meson_use sound audio)
+		$(meson_use systemd)
+		$(meson_use tslib)
+		$(meson_use v4l v4l2)
+		$(meson_use vnc vnc-server)
+		$(meson_use wayland wl)
+		$(meson_use xpresent)
+		$(meson_use zeroconf avahi)
+
+		$(meson_use !system-lz4 embedded-lz4)
+	)
+
+	if use opengl; then
+		emesonargs+=( -D opengl=full )
+	elif use gles2; then
+		emesonargs+=( -D opengl=es-egl )
+	else
+		emesonargs+=( -D opengl=none )
+	fi
+
+	if use gnutls; then
+		emesonargs+=( -D crypto=gnutls )
+	else
+		emesonargs+=( -D crypto=openssl )
+	fi
+
+	if use connman; then
+		emesonargs+=( -D network-backend=connman )
+	else
+		emesonargs+=( -D network-backend=none )
+	fi
+
+	local disabledEvasLoaders=""
+	! use bmp && disabledEvasLoaders+="bmp,wbmp,"
+	! use dds && disabledEvasLoaders+="dds,"
+	! use eet && disabledEvasLoaders+="eet,"
+	! use gstreamer && disabledEvasLoaders+="gst,"
+	! use ico && disabledEvasLoaders+="ico,"
+	! use jpeg2k && disabledEvasLoaders+="jp2k,"
+	! use json && disabledEvasLoaders+="json,"
+	! use pdf && disabledEvasLoaders+="pdf,"
+	! use pmaps && disabledEvasLoaders+="pmaps,"
+	! use postscript && disabledEvasLoaders+="ps,"
+	! use psd && disabledEvasLoaders+="psd,"
+	! use raw && disabledEvasLoaders+="raw,"
+	! use svg && disabledEvasLoaders+="rsvg,svg,"
+	! use tga && disabledEvasLoaders+="tga,"
+	! use tgv && disabledEvasLoaders+="tgv,"
+	! use tiff && disabledEvasLoaders+="tiff,"
+	! use webp && disabledEvasLoaders+="webp,"
+	! use xcf && disabledEvasLoaders+="xcf,"
+	! use xpm && disabledEvasLoaders+="xpm,"
+	[[ ! -z "$disabledEvasLoaders" ]] && disabledEvasLoaders=${disabledEvasLoaders::-1}
+	emesonargs+=( -D evas-loaders-disabler="${disabledEvasLoaders}" )
+
+	local disabledImfLoaders=""
+	! use ibus && disabledImfLoaders+="ibus,"
+	! use scim && disabledImfLoaders+="scim,"
+	! use xim && disabledImfLoaders+="xim,"
+	[[ ! -z "$disabledImfLoaders" ]] && disabledImfLoaders=${disabledImfLoaders::-1}
+	emesonargs+=( -D ecore-imf-loaders-disabler="${disabledImfLoaders}" )
+
+	local bindingsList="cxx,"
+	use luajit && bindingsList+="luajit,"
+	use mono && bindingsList+="mono,"
+	[[ ! -z "$bindingsList" ]] && bindingsList=${bindingsList::-1}
+	emesonargs+=( -D bindings="${bindingsList}" )
+
+	local luaChoice=""
+	if use luajit; then
+		luaChoice+="luajit"
+	else
+		luaChoice+="lua"
+	fi
+	emesonargs+=( -D lua-interpreter="${luaChoice}" )
+
+	meson_src_configure
+}
+
+src_compile() {
+	meson_src_compile
+
+	if use doc; then
+		cd doc/ || die "Failed to switch into doc/ dir."
+		doxygen . || die "Doxygen failed to run."
+	fi
+}
+
+src_install() {
+	use doc && local HTML_DOCS=( "${S}"/doc/html/. )
+	meson_src_install
+
+	if use examples; then
+		docompress -x /usr/share/doc/${PF}/examples/
+		dodoc -r "${BUILD_DIR}"/src/examples/
+	fi
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+	xdg_mimeinfo_database_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+	xdg_mimeinfo_database_update
+}