[gentoo-commits] gentoo-x86 commit in media-sound/squeezecenter: squeezecenter-7.0_p20080102.ebuild metadata.xml ChangeLog Manifest

[Joe Peterson (lavajoe)]

lavajoe     08/01/07 01:33:35

  Added:                squeezecenter-7.0_p20080102.ebuild metadata.xml
                        ChangeLog Manifest
  Log:
  New package that replaces media-sound/slimserver from version 7.0 on - Contributed by Stuart Hickinbottom <stuart@××××××××××××.com>
  (Portage version: 2.1.3.19)

Revision  Changes    Path
1.1                  media-sound/squeezecenter/squeezecenter-7.0_p20080102.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/squeezecenter/squeezecenter-7.0_p20080102.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/squeezecenter/squeezecenter-7.0_p20080102.ebuild?rev=1.1&content-type=text/plain

Index: squeezecenter-7.0_p20080102.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-sound/squeezecenter/squeezecenter-7.0_p20080102.ebuild,v 1.1 2008/01/07 01:33:34 lavajoe Exp $

inherit eutils

MY_PV="${PV:5:4}-${PV:9:2}-${PV:11:2}"
MY_P="SqueezeCenter_trunk_v${MY_PV}"

DESCRIPTION="Logitech SqueezeCenter music server"
HOMEPAGE="http://www.slimdevices.com/pi_features.html"
SRC_URI="http://www.slimdevices.com/downloads/nightly/SqueezeCenter_v${MY_PV}/${MY_P}.no-cpan-arch.tar.gz"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86"
IUSE="lame wavpack musepack alac ogg bonjour flac avahi"

# Note: dev-perl/module-build necessary because of SC bug#5882
# (http://bugs.slimdevices.com/show_bug.cgi?id=5882).
DEPEND="
	dev-perl/File-Which
	dev-perl/module-build
	virtual/logger
	virtual/mysql
	avahi? ( net-dns/avahi )
	ogg? ( media-sound/sox )
	"
# Note: dev-perl/GD necessary because of SC bug#6143
# (http://bugs.slimdevices.com/show_bug.cgi?id=6143).
RDEPEND="${DEPEND}
	>=dev-lang/perl-5.8.8
	>=dev-perl/GD-2.35
	>=app-admin/sudo-1.6.8
	alac? ( media-sound/alac_decoder )
	lame? ( media-sound/lame )
	wavpack? ( media-sound/wavpack )
	bonjour? ( net-misc/mDNSResponder )
	flac? ( media-libs/flac )
	musepack? ( media-sound/musepack-tools )
	"

S="${WORKDIR}/${MY_P}"

INSTROOT="/opt"
PREFS="/etc/squeezecenter.prefs"
CACHED_PREFS="/var/cache/squeezecenter/prefs/server.prefs"
DBUSER="squeezecenter"

pkg_setup() {
	# Sox has optional OGG support, so make sure it has been built that way
	if use ogg; then
		if ! built_with_use media-sound/sox ogg; then
			eerror "media-sound/sox not built with USE=ogg"
			die "media-sound/sox not built with USE=ogg"
		fi
	fi

	# Create the user and group if not already present
	enewgroup squeezecenter || die
	enewuser squeezecenter -1 -1 "${INSTROOT}/squeezecenter" squeezecenter || die
}

src_unpack() {
	unpack ${A}
	cd "${S}"

	# Apply patches
	epatch "${FILESDIR}/mDNSResponder-7.0-gentoo.patch"

	# Remove bundled binaries that are supplied by other ebuilds
	einfo "Removing binaries provided by other ebuilds ..."
	rm "${S}"/Bin/*/mDNSResponderPosix || die	# net-misc/mDNSResponder
	rm "${S}"/Bin/*/alac || die					# media-sound/alac_decoder
	rm "${S}"/Bin/*/flac || die					# media-libs/flac
	rm "${S}"/Bin/*/sox || die					# media-sound/sox
	rm "${S}"/Bin/*/wvunpack || die				# media-sound/wavpack
	rm "${S}"/Bin/*/mppdec || die				# media-sound/musepack-tools

	# Remove bundled MySQL as we depend on an external instance
	einfo "Removing bundled MySQL ..."
	rm -r "${S}"/MySQL || die
	rm "${S}"/Bin/*/mysqld || die				# virtual/mysql
}

src_compile() {
	einfo "Building required Perl modules (some warnings are normal here) ..."
	mkdir "${T}/sc_compile"
	echo -e "\n${S}\n${T}/sc_compile" | Bin/build-perl-modules.pl || die "Unable to build Perl modules"
}

src_install() {
	# Copy all files.
	dodir "${INSTROOT}/squeezecenter"
	cp -r * "${D}/${INSTROOT}/squeezecenter"

	# Install init scripts.
	newconfd "${FILESDIR}/squeezecenter-7.0.conf.d" squeezecenter
	newinitd "${FILESDIR}/squeezecenter-7.0.init.d" squeezecenter

	# Install default preferences.
	insinto /etc
	newins "${FILESDIR}/squeezecenter-7.0.prefs" squeezecenter.prefs

	# Install the SQL configuration scripts.
	insinto "${INSTROOT}/squeezecenter/SQL/mysql"
	doins "${FILESDIR}/dbdrop-7.0-gentoo.sql"
	doins "${FILESDIR}/dbcreate-7.0-gentoo.sql"

	# Initialize /var/{cache,run}.
	keepdir /var/{cache,run}/squeezecenter
	fowners squeezecenter:squeezecenter /var/{cache,run}/squeezecenter
	fperms 770 /var/{cache,run}/squeezecenter

	# Initialize /var/log.
	dodir /var/log/squeezecenter
	fowners squeezecenter:squeezecenter /var/log/squeezecenter
	fperms 770 /var/log/squeezecenter
	touch "${D}/var/log/squeezecenter/server.log"
	touch "${D}/var/log/squeezecenter/scanner.log"
	touch "${D}/var/log/squeezecenter/perfmon.log"
	fowners squeezecenter:squeezecenter /var/log/squeezecenter/server.log
	fowners squeezecenter:squeezecenter /var/log/squeezecenter/scanner.log
	fowners squeezecenter:squeezecenter /var/log/squeezecenter/perfmon.log

	# Install logrotate support.
	insinto /etc/logrotate.d
	newins "${FILESDIR}/squeezecenter-7.0.logrotate.d" squeezecenter

	# Install Avahi support (if USE flag is set).
	if use avahi; then
		insinto /etc/avahi/services
		newins "${FILESDIR}/avahi-7.0-squeezecenter.service" squeezecenter.service
	fi
}

sc_starting_instr() {
	elog "SqueezeCenter can be started with the following command:"
	elog "\t/etc/init.d/squeezecenter start"
	elog ""
	elog "SqueezeCenter can be automatically started on each boot with the"
	elog "following command:"
	elog "\trc-update add squeezecenter default"
	elog ""
	elog "You might want to examine and modify the following configuration"
	elog "file before starting SqueezeCenter:"
	elog "\t/etc/conf.d/squeezecenter"
	elog ""

	# Discover the port number from the preferences, but if it isn't there
	# then report the standard one.
	httpport=$(gawk '$1 == "httpport:" { print $2 }' "${ROOT}${CACHED_PREFS}" 2>/dev/null)
	elog "You may access and configure SqueezeCenter by browsing to:"
	elog "\thttp://localhost:${httpport:-9000}/"
}

pkg_postinst() {
	# FLAC and LAME are quite useful (but not essential) for SqueezeCenter -
	# if they're not enabled then make sure the user understands that.
	if ! use flac; then
		ewarn "'flac' USE flag is not set.  Although not essential, FLAC is required"
		ewarn "for playing lossless WAV and FLAC (for Squeezebox 1), and for"
		ewarn "playing other less common file types (if you have a Squeezebox 2, 3"
		ewarn "or Transporter)."
		ewarn "For maximum flexibility you are recommended to set the 'flac' USE flag".
		ewarn ""
	fi
	if ! use lame; then
		ewarn "'lame' USE flag is not set.  Although not essential, LAME is"
		ewarn "required if you want to limit the bandwidth your Squeezebox or"
		ewarn "Transporter uses when streaming audio."
		ewarn "For maximum flexibility you are recommended to set the 'lame' USE flag".
		ewarn ""
	fi

	# Album art requires PNG and JPEG support from GD, so if it's not there
	# then warn the user.  It's not mandatory as the user may not be using
	# album art.
	if ! built_with_use dev-perl/GD jpeg || \
	   ! built_with_use dev-perl/GD png || \
	   ! built_with_use media-libs/gd jpeg || \
	   ! built_with_use media-libs/gd png; then
		ewarn "For correct operation of album art through SqueezeCenter's web"
		ewarn "interface the GD library and Perl module must be built with PNG"
		ewarn "and JPEG support.  If necessary you can add the following lines"
		ewarn "to the file /etc/portage/package.use:"
		ewarn "\tdev-perl/GD jpeg png"
		ewarn "\tmedia-libs/gd jpeg png"
		ewarn ""
	fi

	# Point user to database configuration step
	elog "If this is a new installation of SqueezeCenter then the database"
	elog "must be configured prior to use.  This can be done by running the"
	elog "following command:"
	elog "\temerge --config =${CATEGORY}/${PF}"

	# Remind user to configure Avahi if necessary
	if use avahi; then
		elog ""
		elog "Avahi support installed.  Remember to edit the folowing file if"
		elog "you run SqueezeCenter's web interface on a port other than 9000:"
		elog "\t/etc/avahi/services/squeezecenter.service"
	fi

	elog ""
	sc_starting_instr
}

sc_remove_db_prefs() {
	MY_PREFS=$1

	einfo "Configuring SqueezeCenter database preferences (${MY_PREFS}) ..."
	TMPPREFS="${T}"/squeezecenter-prefs-$$
	touch "${ROOT}${MY_PREFS}"
	sed -e '/^dbusername:/d' -e '/^dbpassword:/d' -e '/^dbsource:/d' < "${ROOT}${MY_PREFS}" > "${TMPPREFS}"
	mv "${TMPPREFS}" "${ROOT}${MY_PREFS}"
	chown squeezecenter:squeezecenter "${ROOT}${MY_PREFS}"
	chmod 660 "${ROOT}${MY_PREFS}"
}

sc_update_prefs() {
	MY_PREFS=$1
	MY_DBUSER=$2
	MY_DBUSER_PASSWD=$3

	echo "dbusername: ${MY_DBUSER}" >> "${ROOT}${MY_PREFS}"
	echo "dbpassword: ${MY_DBUSER_PASSWD}" >> "${ROOT}${MY_PREFS}"
	echo "dbsource: dbi:mysql:database=${MY_DBUSER};mysql_socket=/var/run/mysqld/mysqld.sock" >> "${ROOT}${MY_PREFS}"
}

pkg_config() {
	einfo "Press ENTER to create the SqueezeCenter database and set proper"
	einfo "permissions on it.  You will be prompted for the MySQL 'root' user's"
	einfo "password during this process (note that the MySQL 'root' user is"
	einfo "independent of the Linux 'root' user and so may have a different"
	einfo "password)."
	einfo ""
	einfo "If you already have a SqueezeCenter database set up then this"
	einfo "process will clear the existing database (your music files will not,"
	einfo "however, be affected)."
	einfo ""
	einfo "Alternatively, press Control-C to abort now..."
	read

	# Get the MySQL root password from the user (not echoed to the terminal)
	einfo "The MySQL 'root' user password is required to create the"
	einfo "SqueezeCenter user and database."
	DONE=0
	while [ $DONE -eq 0 ]; do
		trap "stty echo; echo" EXIT
		stty -echo
		read -p "MySQL root password: " ROOT_PASSWD; echo
		stty echo
		trap ":" EXIT
		mysql --user=root --password="${ROOT_PASSWD}" </dev/null >/dev/null 2>&1 && DONE=1
		if [ $DONE -eq 0 ]; then
			eerror "Incorrect MySQL root password, or MySQL is not running"
		fi
	done

	# Get the new password for the SqueezeCenter MySQL database user, and
	# have it re-entered to confirm it.  We should trivially check it's not
	# the same as the MySQL root password.
	einfo "A new MySQL user will be added to own the SqueezeCenter database."
	einfo "Please enter the password for this new user (${DBUSER})."
	DONE=0
	while [ $DONE -eq 0 ]; do
		trap "stty echo; echo" EXIT
		stty -echo
		read -p "MySQL ${DBUSER} password: " DBUSER_PASSWD; echo
		stty echo
		trap ":" EXIT
		if [ -z "$DBUSER_PASSWD" ]; then
			eerror "The password should not be blank; try again."
		elif [ "$DBUSER_PASSWD" == "$ROOT_PASSWD" ]; then
			eerror "The ${DBUSER} password should be different to the root password"
		else
			DONE=1
		fi
	done

	# Drop the existing database and user - note we don't care about errors
	# from this as it probably just indicates that the database wasn't
	# yet present.
	einfo "Dropping old SqueezeCenter database and user ..."
	sed -e "s/__DATABASE__/${DBUSER}/" -e "s/__DBUSER__/${DBUSER}/" < "${INSTROOT}/squeezecenter/SQL/mysql/dbdrop-7.0-gentoo.sql" | mysql --user=root --password="${ROOT_PASSWD}" >/dev/null 2>&1

	# Drop and create the SqueezeCenter user and database.
	einfo "Creating SqueezeCenter MySQL user and database (${DBUSER}) ..."
	sed -e "s/__DATABASE__/${DBUSER}/" -e "s/__DBUSER__/${DBUSER}/" -e "s/__DBPASSWORD__/${DBUSER_PASSWD}/" < "${INSTROOT}/squeezecenter/SQL/mysql/dbcreate-7.0-gentoo.sql" | mysql --user=root --password="${ROOT_PASSWD}" || die "Unable to create MySQL database and user"

	# Remove the existing MySQL preferences from SqueezeCenter (if any).
	sc_remove_db_prefs "${PREFS}"
	[ -f "${CACHED_PREFS}" ] && sc_remove_db_prefs ${CACHED_PREFS}

	# Insert the external MySQL configuration into the preferences.
	sc_update_prefs "${PREFS}" "${DBUSER}" "${DBUSER_PASSWD}"
	[ -f "${CACHED_PREFS}" ] && sc_update_prefs "${CACHED_PREFS}" "${DBUSER}" "${DBUSER_PASSWD}"

	# Phew - all done.
	# Give some tips on what to do now.
	einfo "Database configuration complete."
	einfo ""
	sc_starting_instr
}



1.1                  media-sound/squeezecenter/metadata.xml

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/squeezecenter/metadata.xml?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/squeezecenter/metadata.xml?rev=1.1&content-type=text/plain

Index: metadata.xml
===================================================================
<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
<pkgmetadata>
  <herd>no-herd</herd>
  <maintainer>
    <email>lavajoe@g.o</email>
  </maintainer>
  <longdescription lang="en">
    This package provides the Logitech SqueezeCenter audio server.
    SqueezeCenter will allow access to your audio collection over local
    and wide-area networks, as well as serving content to the Logitech
    Squeezebox and Transporter streaming media players.  In addition to
    local content, SqueezeCenter will also provide access to internet
    radio and audio podcasts.  The SqueezeCenter package also includes
    SoftSqueeze - a Logitech media player emulator that you can use as a
    client.
  </longdescription>
</pkgmetadata>



1.1                  media-sound/squeezecenter/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/squeezecenter/ChangeLog?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/squeezecenter/ChangeLog?rev=1.1&content-type=text/plain

Index: ChangeLog
===================================================================
# ChangeLog for media-sound/squeezecenter
# Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
# $Header: /var/cvsroot/gentoo-x86/media-sound/squeezecenter/ChangeLog,v 1.1 2008/01/07 01:33:34 lavajoe Exp $

*squeezecenter-7.0_p20080102 (07 Jan 2008)

  07 Jan 2008; Joe Peterson <lavajoe@g.o>
  +files/mDNSResponder-7.0-gentoo.patch, +files/dbcreate-7.0-gentoo.sql,
  +files/dbdrop-7.0-gentoo.sql, +files/avahi-7.0-squeezecenter.service,
  +files/squeezecenter-7.0.conf.d, +files/squeezecenter-7.0.init.d,
  +files/squeezecenter-7.0.logrotate.d, +files/squeezecenter-7.0.prefs,
  +metadata.xml, +squeezecenter-7.0_p20080102.ebuild:
  New package that replaces media-sound/slimserver from version 7.0 on.
  Contributed by Stuart Hickinbottom <stuart@××××××××××××.com>.




1.1                  media-sound/squeezecenter/Manifest

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/squeezecenter/Manifest?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/squeezecenter/Manifest?rev=1.1&content-type=text/plain

Index: Manifest
===================================================================
AUX avahi-7.0-squeezecenter.service 326 RMD160 174b4a900bea817b3b1995449c1c0a0f3f96cacb SHA1 b84fa32fc82c84cb749d8aed2cc4f1367937a4bc SHA256 868102c1b4eb5e497e8a0f899c794023643018b66e8f3855b772908647b59b2d
MD5 e02e4f0a018b2ffffb6d89a639f1028d files/avahi-7.0-squeezecenter.service 326
RMD160 174b4a900bea817b3b1995449c1c0a0f3f96cacb files/avahi-7.0-squeezecenter.service 326
SHA256 868102c1b4eb5e497e8a0f899c794023643018b66e8f3855b772908647b59b2d files/avahi-7.0-squeezecenter.service 326
AUX dbcreate-7.0-gentoo.sql 165 RMD160 36fe87c398aee02890710f970245032488b857bb SHA1 e86a26c73addb4b74c345ec70155f2b9d079075b SHA256 d8cf85879e74dc1e429251f5bd4ae7f99e2a460fa668c0abde2c2725b90f10a1
MD5 eeded845e177f53a5b684f8aa60a2ead files/dbcreate-7.0-gentoo.sql 165
RMD160 36fe87c398aee02890710f970245032488b857bb files/dbcreate-7.0-gentoo.sql 165
SHA256 d8cf85879e74dc1e429251f5bd4ae7f99e2a460fa668c0abde2c2725b90f10a1 files/dbcreate-7.0-gentoo.sql 165
AUX dbdrop-7.0-gentoo.sql 64 RMD160 bc60b46ea56642c28ffbd8731e120722e42b66a9 SHA1 a02eab2a62e67d81ff2ad3d3700cd7695f6d31c1 SHA256 0c8e1f3cddd54d6659a014dbcefa928f6d8b9174860cb07d53e01fe9940e8aba
MD5 49d7bd6765ab5c3cd8fac26af41f6cff files/dbdrop-7.0-gentoo.sql 64
RMD160 bc60b46ea56642c28ffbd8731e120722e42b66a9 files/dbdrop-7.0-gentoo.sql 64
SHA256 0c8e1f3cddd54d6659a014dbcefa928f6d8b9174860cb07d53e01fe9940e8aba files/dbdrop-7.0-gentoo.sql 64
AUX mDNSResponder-7.0-gentoo.patch 351 RMD160 4ea506094e6cc41a6bf7e3c88b32d3315650db3c SHA1 242f74c0f9c089ab557b70e833a91e6adf18a285 SHA256 31a439f64fa825ff7fda887f7a0dbccc1566cf6ba4e2379273cc4d967ca4886e
MD5 8f311c3f2ba48703d454823a1b0ffccf files/mDNSResponder-7.0-gentoo.patch 351
RMD160 4ea506094e6cc41a6bf7e3c88b32d3315650db3c files/mDNSResponder-7.0-gentoo.patch 351
SHA256 31a439f64fa825ff7fda887f7a0dbccc1566cf6ba4e2379273cc4d967ca4886e files/mDNSResponder-7.0-gentoo.patch 351
AUX squeezecenter-7.0.conf.d 903 RMD160 e3ef773ec921e47ddb749c56ea0c87b32d4399d7 SHA1 f7aede39aca7f19772579caab9cc86f3b3769ff9 SHA256 bd64fd08949e8d1e56f9efc89a3fa141aa50ba851cedb9435be89c4b506c836a
MD5 1171414938cdd7b083c37ed566ed0849 files/squeezecenter-7.0.conf.d 903
RMD160 e3ef773ec921e47ddb749c56ea0c87b32d4399d7 files/squeezecenter-7.0.conf.d 903
SHA256 bd64fd08949e8d1e56f9efc89a3fa141aa50ba851cedb9435be89c4b506c836a files/squeezecenter-7.0.conf.d 903
AUX squeezecenter-7.0.init.d 1149 RMD160 ea5aa8e43b0f64b3bdd1c314bb95010fa0250ba2 SHA1 c6d44567e65751c91c5976ffdf97bb66b86bbaa2 SHA256 6975a89d931b3d51de927ccc3b19f7ce9ed55bc7b43c011978bfe2d745263bfc
MD5 d7088170fe5b15f6f196699e5113d39d files/squeezecenter-7.0.init.d 1149
RMD160 ea5aa8e43b0f64b3bdd1c314bb95010fa0250ba2 files/squeezecenter-7.0.init.d 1149
SHA256 6975a89d931b3d51de927ccc3b19f7ce9ed55bc7b43c011978bfe2d745263bfc files/squeezecenter-7.0.init.d 1149
AUX squeezecenter-7.0.logrotate.d 287 RMD160 be73fddc60e8f20695ef4b72c82aa164feb0e93f SHA1 8e90c1d03e71cc6f43a0a84d27b03e86b40abfa3 SHA256 5df7358e529a08944f4a9306a4e55952a8c3623a60630b6c04bccdce81fb44bc
MD5 95c70c05e661d7bb5f10a1f9c021a4e5 files/squeezecenter-7.0.logrotate.d 287
RMD160 be73fddc60e8f20695ef4b72c82aa164feb0e93f files/squeezecenter-7.0.logrotate.d 287
SHA256 5df7358e529a08944f4a9306a4e55952a8c3623a60630b6c04bccdce81fb44bc files/squeezecenter-7.0.logrotate.d 287
AUX squeezecenter-7.0.prefs 126 RMD160 b715267b10e2bc63eaa7da5aa9dd3177dc0e46ee SHA1 3354ce16a5dd453d71c475a8487b43fec34084c2 SHA256 19c74a3838f78c6a076220e749c236564d085c4ef095fa0f77bbb1be74532b2d
MD5 579f4f8f9e6a5cae8916ef5cc9b5b9f1 files/squeezecenter-7.0.prefs 126
RMD160 b715267b10e2bc63eaa7da5aa9dd3177dc0e46ee files/squeezecenter-7.0.prefs 126
SHA256 19c74a3838f78c6a076220e749c236564d085c4ef095fa0f77bbb1be74532b2d files/squeezecenter-7.0.prefs 126
DIST SqueezeCenter_trunk_v2008-01-02.no-cpan-arch.tar.gz 17338037 RMD160 78636e78ec1deeef14918f4f4d7d7e66a284181c SHA1 fff6613594afd3bdad6b8d4c63cc493f89e4ab19 SHA256 b52443fc4903e75b30302d869f8a12f6d43e7115d4ecfce82cb86cd50b216f5c
EBUILD squeezecenter-7.0_p20080102.ebuild 11081 RMD160 a53afe477f153e5d59b0e9021c318000810dd5c1 SHA1 7f4b4061b25237914820abcaffc90033fcae7385 SHA256 23aaae4b1d70d8bcb5cbe064d290d0701d320f684b45080af53b694d17143c6e
MD5 22a323406dce7efa577a285af9bdda96 squeezecenter-7.0_p20080102.ebuild 11081
RMD160 a53afe477f153e5d59b0e9021c318000810dd5c1 squeezecenter-7.0_p20080102.ebuild 11081
SHA256 23aaae4b1d70d8bcb5cbe064d290d0701d320f684b45080af53b694d17143c6e squeezecenter-7.0_p20080102.ebuild 11081
MISC ChangeLog 695 RMD160 4a1b7d798c0c6349a7949e92735d25b1d8a88f50 SHA1 1894cb2bfdc99cd568eedd18270142eaf5501ffd SHA256 1cdd699fa066c70add0f8fd2047f7690fe89a57a8ab7a31b73b8de5cd1472231
MD5 8f95b8075cc2796ce9f71fd687e1ff69 ChangeLog 695
RMD160 4a1b7d798c0c6349a7949e92735d25b1d8a88f50 ChangeLog 695
SHA256 1cdd699fa066c70add0f8fd2047f7690fe89a57a8ab7a31b73b8de5cd1472231 ChangeLog 695
MISC metadata.xml 790 RMD160 c75ebb0eda5fdc93127d453d975acebc50bec589 SHA1 e9cd926018accadcd17691d24ae22ca2620e0c30 SHA256 d886ca6099eb5d1a95fa1f5cb833b91eac229c5c1df478f73e52f6d3b1a5e135
MD5 1e4c5439e1c902e59f25ece2096160a9 metadata.xml 790
RMD160 c75ebb0eda5fdc93127d453d975acebc50bec589 metadata.xml 790
SHA256 d886ca6099eb5d1a95fa1f5cb833b91eac229c5c1df478f73e52f6d3b1a5e135 metadata.xml 790
MD5 8826eee05014ba463a36c4f09e73a1d4 files/digest-squeezecenter-7.0_p20080102 340
RMD160 eab16b8c1535078efeebd3593ae4f7b98a38500f files/digest-squeezecenter-7.0_p20080102 340
SHA256 b732ae49ae7a43631d966ce36cd575ddc982b4165d5b6fbb82c42022ac4f23c1 files/digest-squeezecenter-7.0_p20080102 340



-- 
gentoo-commits@l.g.o mailing list