[gentoo-commits] repo/gentoo:master commit in: lxqt-base/lxqt-config/

[Sam James]

commit:     6ffc41f37b9245097f120e589051671d4f85957e
Author:     Adel KARA SLIMANE <adel.ks <AT> zegrapher <DOT> com>
AuthorDate: Sat Nov  6 12:49:20 2021 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Fri Jan 21 19:06:45 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=6ffc41f3

lxqt-base/lxqt-config: version bump to 1.0.0

Signed-off-by: Adel KARA SLIMANE <adel.ks <AT> zegrapher.com>
Signed-off-by: Sam James <sam <AT> gentoo.org>

 lxqt-base/lxqt-config/Manifest                 |  1 +
 lxqt-base/lxqt-config/lxqt-config-1.0.0.ebuild | 71 ++++++++++++++++++++++++++
 2 files changed, 72 insertions(+)

diff --git a/lxqt-base/lxqt-config/Manifest b/lxqt-base/lxqt-config/Manifest
index 28c402935a68..3f0eadb0c02c 100644
--- a/lxqt-base/lxqt-config/Manifest
+++ b/lxqt-base/lxqt-config/Manifest
@@ -1 +1,2 @@
 DIST lxqt-config-0.17.1.tar.xz 339184 BLAKE2B cdb2852801b4af141213dbe680f5d9ccf4bf3738ee6c39e4df7e7915ee74209d4516d4ca2675176f31b4fa7afc4c3907ac71afe1d2a88ce39d8831dfc62946ad SHA512 2173acd18ffa5aeee9d11bd73955d0475b53a335df7d95523a2297b5ef3f9a8e4e135a290e7a720a227a92c84532a64d9fbc7a811de242dd32f9e70d036d3ca6
+DIST lxqt-config-1.0.0.tar.xz 355616 BLAKE2B 6f3ca379978c3bc52bff759b7290dbbb0a6d4376161dd8ec7d34212594b51e4380509e92f27b75f4e99e8844452e3fb9ebb17a2fc3de36c625f6ef5823a09ff6 SHA512 cb544ae4635913d693a634a675a769b5ffcae9eb542507e5c6166a85558409302e56753ffac16a2299b613313d11c5f310e530cc7b801393b6f124542245c88e

diff --git a/lxqt-base/lxqt-config/lxqt-config-1.0.0.ebuild b/lxqt-base/lxqt-config/lxqt-config-1.0.0.ebuild
new file mode 100644
index 000000000000..171030acc260
--- /dev/null
+++ b/lxqt-base/lxqt-config/lxqt-config-1.0.0.ebuild
@@ -0,0 +1,71 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+MY_PV="$(ver_cut 1-2)"
+
+inherit cmake xdg-utils
+
+DESCRIPTION="LXQt system configuration control center"
+HOMEPAGE="https://lxqt-project.org/"
+
+if [[ ${PV} = *9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/lxqt/${PN}.git"
+else
+	SRC_URI="https://github.com/lxqt/${PN}/releases/download/${PV}/${P}.tar.xz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86"
+fi
+
+LICENSE="GPL-2 GPL-2+ GPL-3 LGPL-2 LGPL-2+ LGPL-2.1+ WTFPL-2"
+SLOT="0"
+IUSE="+monitor +touchpad"
+
+BDEPEND="
+	>=dev-qt/linguist-tools-5.15:5
+"
+DEPEND="
+	>=dev-libs/libqtxdg-3.3.1
+	>=dev-qt/qtcore-5.15:5
+	>=dev-qt/qtgui-5.15:5
+	>=dev-qt/qtwidgets-5.15:5
+	>=dev-qt/qtsvg-5.15:5
+	>=dev-qt/qtx11extras-5.15:5
+	>=dev-qt/qtxml-5.15:5
+	=lxqt-base/liblxqt-${MY_PV}*:=
+	sys-libs/zlib:=
+	x11-apps/setxkbmap
+	x11-libs/libxcb:=
+	x11-libs/libX11
+	x11-libs/libXcursor
+	x11-libs/libXfixes
+	monitor? ( kde-plasma/libkscreen:5= )
+	touchpad? (
+		virtual/libudev:=
+		x11-drivers/xf86-input-libinput
+		x11-libs/libXi
+	)
+"
+RDEPEND="${DEPEND}"
+
+src_configure() {
+	local mycmakeargs=(
+		-DWITH_MONITOR=$(usex monitor)
+		-DWITH_TOUCHPAD=$(usex touchpad)
+	)
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+	doman man/*.1 liblxqt-config-cursor/man/*.1 lxqt-config-appearance/man/*.1
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+}