[gentoo-commits] gentoo-x86 commit in dev-db/mysql-gui-tools: ChangeLog mysql-gui-tools-5.0_p12-r2.ebuild mysql-gui-tools-5.0_p12-r1.ebuild

[Sven Wegener (swegener)]

swegener    07/11/28 20:11:01

  Modified:             ChangeLog
  Added:                mysql-gui-tools-5.0_p12-r2.ebuild
  Removed:              mysql-gui-tools-5.0_p12-r1.ebuild
  Log:
  Revision bump to fix a hang in mysql-query-browser, bug #170943.
  (Portage version: 2.1.3.19)

Revision  Changes    Path
1.22                 dev-db/mysql-gui-tools/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-db/mysql-gui-tools/ChangeLog?rev=1.22&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-db/mysql-gui-tools/ChangeLog?rev=1.22&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-db/mysql-gui-tools/ChangeLog?r1=1.21&r2=1.22

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-db/mysql-gui-tools/ChangeLog,v
retrieving revision 1.21
retrieving revision 1.22
diff -u -r1.21 -r1.22
--- ChangeLog	10 Nov 2007 21:26:12 -0000	1.21
+++ ChangeLog	28 Nov 2007 20:11:00 -0000	1.22
@@ -1,6 +1,13 @@
 # ChangeLog for dev-db/mysql-gui-tools
 # Copyright 1999-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-db/mysql-gui-tools/ChangeLog,v 1.21 2007/11/10 21:26:12 swegener Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-db/mysql-gui-tools/ChangeLog,v 1.22 2007/11/28 20:11:00 swegener Exp $
+
+*mysql-gui-tools-5.0_p12-r2 (28 Nov 2007)
+
+  28 Nov 2007; Sven Wegener <swegener@g.o>
+  +files/mysql-gui-tools-5.0_p12-query-browser-sps.patch,
+  -mysql-gui-tools-5.0_p12-r1.ebuild, +mysql-gui-tools-5.0_p12-r2.ebuild:
+  Revision bump to fix a hang in mysql-query-browser, bug #170943.
 
   10 Nov 2007; Sven Wegener <swegener@g.o>
   mysql-gui-tools-5.0_p12-r1.ebuild:



1.1                  dev-db/mysql-gui-tools/mysql-gui-tools-5.0_p12-r2.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-db/mysql-gui-tools/mysql-gui-tools-5.0_p12-r2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-db/mysql-gui-tools/mysql-gui-tools-5.0_p12-r2.ebuild?rev=1.1&content-type=text/plain

Index: mysql-gui-tools-5.0_p12-r2.ebuild
===================================================================
# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-db/mysql-gui-tools/mysql-gui-tools-5.0_p12-r2.ebuild,v 1.1 2007/11/28 20:11:00 swegener Exp $

GCONF_DEBUG="no"

inherit gnome2 eutils flag-o-matic

MY_P="${P/_p/r}"

DESCRIPTION="MySQL GUI Tools"
HOMEPAGE="http://www.mysql.com/products/tools/"
SRC_URI="mirror://mysql/Downloads/MySQLGUITools/${MY_P}.tar.gz"

EAPI="1"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE="nls +administrator +query-browser workbench"

RDEPEND=">=x11-libs/gtk+-2.6
	>=dev-libs/glib-2.6
	>=gnome-base/libglade-2.5
	>=dev-libs/libsigc++-2.0
	>=dev-libs/libpcre-4.4
	>=dev-libs/libxml2-2.6.2
	>=dev-cpp/glibmm-2.14
	dev-cpp/gtkmm:2.4
	>=virtual/mysql-5.0
	workbench? (
		=dev-lang/lua-5.0*
		virtual/opengl
	)
	query-browser? ( gnome-extra/gtkhtml:3.14 )"
DEPEND="${RDEPEND}
	>=dev-util/pkgconfig-0.15
	>=app-text/scrollkeeper-0.3.11"
RDEPEND="${RDEPEND}
	!dev-db/mysql-administrator
	!dev-db/mysql-query-browser"

S="${WORKDIR}"/${MY_P}

pkg_setup() {
	if ! use administrator && ! use query-browser && ! use workbench
	then
		elog "Please activate at least one of the following USE flags:"
		elog "- administrator for MySQL Administrator"
		elog "- query-browser for MySQL Query Browser"
		elog "- workbench for MySQL Workbench"
		die "Please activate at least one of the following USE flags: administrator, query-browser, workbench"
	fi
}

src_unpack() {
	gnome2_src_unpack
	cd "${S}"

	epatch "${FILESDIR}"/${PN}-5.0_p8-i18n-fix.patch
	epatch "${FILESDIR}"/${PN}-5.0_p8-lua-modules.patch
	epatch "${FILESDIR}"/${P}-workbench-lua.patch
	epatch "${FILESDIR}"/${P}-query-browser-sps.patch

	sed -i \
		-e "s/\\(^\\|[[:space:]]\\)-ltermcap\\($\\|[[:space:]]\\)/ /g" \
		mysql-gui-common/tools/grtsh/Makefile.{am,in}
}

src_compile() {
	# mysql has -fno-exceptions, but we need exceptions
	append-flags -fexceptions

	cd "${S}"/mysql-gui-common
	use nls || sed -i -e "/^SUBDIRS = / s/\\bpo\\b//" Makefile.{am,in}
	gnome2_src_compile \
		--disable-java-modules \
		$(use_enable workbench grt) \
		$(use_enable workbench canvas) \
		$(use_enable nls i18n)

	if use administrator
	then
		cd "${S}"/mysql-administrator
		use nls || sed -i -e "/^SUBDIRS = / s/\\bpo\\b//" Makefile.{am,in}
		gnome2_src_compile $(use_enable nls i18n)
	fi

	if use query-browser
	then
		cd "${S}"/mysql-query-browser
		use nls || sed -i -e "/^SUBDIRS=/ s/\\bpo\\b//" Makefile.{am,in}
		gnome2_src_compile --with-gtkhtml=libgtkhtml-3.14
	fi

	if use workbench
	then
		cd "${S}"/mysql-workbench
		use nls || sed -i -e "/^SUBDIRS=/ s/\\bpo\\b//" Makefile.{am,in}
		gnome2_src_compile
	fi
}

src_install() {
	cd "${S}"/mysql-gui-common
	gnome2_src_install

	if use administrator
	then
		cd "${S}"/mysql-administrator
		gnome2_src_install
	fi

	if use query-browser
	then
		cd "${S}"/mysql-query-browser
		gnome2_src_install
	fi

	if use workbench
	then
		cd "${S}"/mysql-workbench
		gnome2_src_install
	fi
}



-- 
gentoo-commits@g.o mailing list