[gentoo-commits] repo/gentoo:master commit in: sys-kernel/gentoo-kernel-bin/

[Sam James]

commit:     b50d674ae1803c78020c129652aeb84e9b28a8ab
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Sat Sep 18 04:50:54 2021 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Sat Sep 18 04:50:54 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=b50d674a

sys-kernel/gentoo-kernel-bin: add 5.13.18-r1 for arm64

Signed-off-by: Sam James <sam <AT> gentoo.org>

 sys-kernel/gentoo-kernel-bin/Manifest              |   1 +
 .../gentoo-kernel-bin-5.13.18-r1.ebuild            | 113 +++++++++++++++++++++
 2 files changed, 114 insertions(+)

diff --git a/sys-kernel/gentoo-kernel-bin/Manifest b/sys-kernel/gentoo-kernel-bin/Manifest
index 12d5fc07e04..0aae688bcec 100644
--- a/sys-kernel/gentoo-kernel-bin/Manifest
+++ b/sys-kernel/gentoo-kernel-bin/Manifest
@@ -76,6 +76,7 @@ DIST gentoo-kernel-5.13.16-1.x86.xpak 58509171 BLAKE2B aabdc8def008e446ee6ba12a7
 DIST gentoo-kernel-5.13.17-1.amd64.xpak 67325984 BLAKE2B d5504c4fe53f63a85bb2cc1ce3b0cff24afb6ec18306305f980546fdc28f6bca5df81ec59863f33cbe9cd831713d4701e8d628e63199eb91d04ee3aa45df022c SHA512 d08e893d3f0214a4a21a8d048ac7129bd14d2409dab0d2287cf6bc8cfca0a3b8bf250c078f07e7542fbd13fd5f7ecb82a2394db2f1cab2731cb08256e0327f81
 DIST gentoo-kernel-5.13.17-1.x86.xpak 58522737 BLAKE2B e97fbcda584ada26ee2c7963639e0c9634b52227d73a887544ed90480e1986b2598e0391506b4411b8070a55074d1864f75b1cd3044c907106757fefa3cf79c4 SHA512 1dbb7ff34fd70a0c492ab97c9d2cdbffd00155ae68e6eb3fca4ec20315cdd0ba0915fbaf257bfcb45dbb2563c503aebf0723c8164a4fb8aaa76978eed2141db9
 DIST gentoo-kernel-5.13.18-1.amd64.xpak 67341241 BLAKE2B 5c6a220b20bc426daa42c7d1affaddf90bcfe1ce2fb84560bf73f3ee5315b0f684f7eb493ecc368614ae8011c74ab33884f907c841709af99d881fbfaddd98fe SHA512 0e468de6acd60ea0b6a4cc6e7d84889645dc1873e1e0529c42ce9d7cb4fdf6142449a1649c845eb6ed6e8179585d5946f2b82c1d85ca10b9811548f9875b68a1
+DIST gentoo-kernel-5.13.18-1.arm64.xpak 62764880 BLAKE2B bb1777be907a947fa0ee5cd5df47d8bd1c5e0a5b082d545a5fd2ade99f53e553d9ec6b57d6f9b5e42703a17cfbb9775520fcd1d6015f3a45f7dad391bbf3ed25 SHA512 2f54c28b717ec76a4d7fc8a17c37c963861ae65f0e50a3ebd025ee4d993f168114cd77fbf2621a5dbd77e59f5f2590ba8524e8829462af1b5193ec8eea8b8e78
 DIST gentoo-kernel-5.13.18-1.x86.xpak 58523160 BLAKE2B 044081a07799be765552561fcfb7f3a9ff083e05d4e231041842c01c61d478bb78fb84bf628cd6f739961f622f440110578ae1ff7851e5ce10338b7abc775b6e SHA512 67b1e99eac517b1266d9d6aa88bda6885e4669ac388b78efee6e1de354580a6f795b5cbc2fba298a38dc8c95721a8d26312eeb9cc24b9396bb548cc9632ef40a
 DIST gentoo-kernel-5.4.142-1.amd64.xpak 61382010 BLAKE2B 5753309c6f0e98adf348b332ef8acad749f0501b5a0641f2436c7ca7a48c6e57d9f2b316f06d82b5e362cbdf91aa253ba69c7425b6eda0db46531e04929ac6de SHA512 c8433c79fde6bc7b31ff2d93b24e5b327166dcf00157ef91057b006b071f6c7293940285c54f282d40a09957f91831dac9f622dd477be62ec8fea713b0a6b68e
 DIST gentoo-kernel-5.4.142-1.arm64.xpak 58037550 BLAKE2B f2f047abcfc83ed15154c617a10810c3d608106d47e8ddd7f5a70e8b3d5a77e6df34b56efeacbcd14fd479db3f7c5574026bdf4d2c6910dd8e9bb5940f4443c7 SHA512 8a9f109738071ae08ea7231964d1fda529aa5bb0810e96c19b3b82c1743868545eb254fc0604586c10645583012baaa0d2a2e930e460ba0697102b081d277521

diff --git a/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.13.18-r1.ebuild b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.13.18-r1.ebuild
new file mode 100644
index 00000000000..56164dd0991
--- /dev/null
+++ b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.13.18-r1.ebuild
@@ -0,0 +1,113 @@
+# Copyright 2020-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit kernel-install toolchain-funcs
+
+MY_P=linux-${PV%.*}
+GENPATCHES_P=genpatches-${PV%.*}-$(( ${PV##*.} + 2 ))
+BINPKG=${P/-bin/}-1
+
+DESCRIPTION="Pre-built Linux kernel with genpatches"
+HOMEPAGE="https://www.kernel.org/"
+SRC_URI+="
+	https://cdn.kernel.org/pub/linux/kernel/v$(ver_cut 1).x/${MY_P}.tar.xz
+	https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.base.tar.xz
+	https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.extras.tar.xz
+	arm64? (
+		https://dev.gentoo.org/~sam/binpkg/arm64/kernel/sys-kernel/gentoo-kernel/${BINPKG}.xpak
+		-> ${BINPKG}.arm64.xpak
+	)"
+S=${WORKDIR}
+
+LICENSE="GPL-2"
+KEYWORDS="~arm64"
+
+RDEPEND="
+	!sys-kernel/gentoo-kernel:${SLOT}"
+PDEPEND="
+	>=virtual/dist-kernel-${PV}"
+BDEPEND="
+	sys-devel/bc
+	sys-devel/flex
+	virtual/libelf
+	virtual/yacc"
+
+QA_PREBUILT='*'
+
+KV_LOCALVERSION='-gentoo-dist'
+KPV=${PV}${KV_LOCALVERSION}
+
+src_unpack() {
+	default
+	ebegin "Unpacking ${BINPKG}.${ARCH}.xpak"
+	tar -x < <(xz -c -d --single-stream "${DISTDIR}/${BINPKG}.${ARCH}.xpak")
+	eend ${?} || die "Unpacking ${BINPKG} failed"
+}
+
+src_prepare() {
+	local PATCHES=(
+		# meh, genpatches have no directory
+		"${WORKDIR}"/*.patch
+	)
+	cd "${MY_P}" || die
+	default
+}
+
+src_configure() {
+	# force ld.bfd if we can find it easily
+	local LD="$(tc-getLD)"
+	if type -P "${LD}.bfd" &>/dev/null; then
+		LD+=.bfd
+	fi
+
+	tc-export_build_env
+	local makeargs=(
+		V=1
+
+		HOSTCC="$(tc-getBUILD_CC)"
+		HOSTCXX="$(tc-getBUILD_CXX)"
+		HOSTCFLAGS="${BUILD_CFLAGS}"
+		HOSTLDFLAGS="${BUILD_LDFLAGS}"
+
+		CROSS_COMPILE=${CHOST}-
+		AS="$(tc-getAS)"
+		CC="$(tc-getCC)"
+		LD="${LD}"
+		AR="$(tc-getAR)"
+		NM="$(tc-getNM)"
+		STRIP=":"
+		OBJCOPY="$(tc-getOBJCOPY)"
+		OBJDUMP="$(tc-getOBJDUMP)"
+
+		# we need to pass it to override colliding Gentoo envvar
+		ARCH=$(tc-arch-kernel)
+
+		O="${WORKDIR}"/modprep
+	)
+
+	mkdir modprep || die
+	cp "usr/src/linux-${KPV}/.config" modprep/ || die
+	emake -C "${MY_P}" "${makeargs[@]}" modules_prepare
+}
+
+src_test() {
+	kernel-install_test "${KPV}" \
+		"${WORKDIR}/usr/src/linux-${KPV}/$(dist-kernel_get_image_path)" \
+		"lib/modules/${KPV}"
+}
+
+src_install() {
+	mv lib usr "${ED}"/ || die
+
+	# strip out-of-source build stuffs from modprep
+	# and then copy built files
+	find modprep -type f '(' \
+			-name Makefile -o \
+			-name '*.[ao]' -o \
+			'(' -name '.*' -a -not -name '.config' ')' \
+		')' -delete || die
+	rm modprep/source || die
+	cp -p -R modprep/. "${ED}/usr/src/linux-${KPV}"/ || die
+}