[gentoo-commits] gentoo-x86 commit in xfce-extra/xfce4-whiskermenu-plugin: xfce4-whiskermenu-plugin-1.2.0.ebuild ChangeLog

[Julian Ospald (hasufell)]

hasufell    13/10/29 19:57:26

  Modified:             ChangeLog
  Added:                xfce4-whiskermenu-plugin-1.2.0.ebuild
  Log:
  version bump
  
  (Portage version: 2.2.7/cvs/Linux x86_64, signed Manifest commit with key E73C35B3)

Revision  Changes    Path
1.6                  xfce-extra/xfce4-whiskermenu-plugin/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/xfce-extra/xfce4-whiskermenu-plugin/ChangeLog?rev=1.6&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/xfce-extra/xfce4-whiskermenu-plugin/ChangeLog?rev=1.6&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/xfce-extra/xfce4-whiskermenu-plugin/ChangeLog?r1=1.5&r2=1.6

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/xfce-extra/xfce4-whiskermenu-plugin/ChangeLog,v
retrieving revision 1.5
retrieving revision 1.6
diff -u -r1.5 -r1.6
--- ChangeLog	14 Sep 2013 10:03:01 -0000	1.5
+++ ChangeLog	29 Oct 2013 19:57:26 -0000	1.6
@@ -1,6 +1,12 @@
 # ChangeLog for xfce-extra/xfce4-whiskermenu-plugin
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/xfce-extra/xfce4-whiskermenu-plugin/ChangeLog,v 1.5 2013/09/14 10:03:01 ago Exp $
+# $Header: /var/cvsroot/gentoo-x86/xfce-extra/xfce4-whiskermenu-plugin/ChangeLog,v 1.6 2013/10/29 19:57:26 hasufell Exp $
+
+*xfce4-whiskermenu-plugin-1.2.0 (29 Oct 2013)
+
+  29 Oct 2013; Julian Ospald <hasufell@g.o>
+  +xfce4-whiskermenu-plugin-1.2.0.ebuild:
+  version bump
 
   14 Sep 2013; Agostino Sarubbo <ago@g.o>
   xfce4-whiskermenu-plugin-1.1.1.ebuild:



1.1                  xfce-extra/xfce4-whiskermenu-plugin/xfce4-whiskermenu-plugin-1.2.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/xfce-extra/xfce4-whiskermenu-plugin/xfce4-whiskermenu-plugin-1.2.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/xfce-extra/xfce4-whiskermenu-plugin/xfce4-whiskermenu-plugin-1.2.0.ebuild?rev=1.1&content-type=text/plain

Index: xfce4-whiskermenu-plugin-1.2.0.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/xfce-extra/xfce4-whiskermenu-plugin/xfce4-whiskermenu-plugin-1.2.0.ebuild,v 1.1 2013/10/29 19:57:26 hasufell Exp $

EAPI=5

inherit gnome2-utils cmake-utils

DESCRIPTION="Alternate application launcher for Xfce"
HOMEPAGE="http://gottcode.org/xfce4-whiskermenu-plugin/"
SRC_URI="http://gottcode.org/xfce4-whiskermenu-plugin/${P}-src.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE=""

RDEPEND="
	x11-libs/gtk+:2
	xfce-base/exo
	xfce-base/garcon
	xfce-base/libxfce4ui
	xfce-base/libxfce4util
	xfce-base/xfce4-panel
	virtual/libintl"
DEPEND="${RDEPEND}
	virtual/pkgconfig
	sys-devel/gettext"

src_prepare() {
	local i
	if [[ -n "${LINGUAS+x}" ]] ; then
		for i in $(grep add_subdirectory po/CMakeLists.txt | sed 's/add_subdirectory(//;s/)$//') ; do
			has ${i} ${LINGUAS} || { sed -i -e "/add_subdirectory(${i})/d" po/CMakeLists.txt || die ; }
		done
	fi
}

src_configure() {
	local mycmakeargs=(
		-DENABLE_WERROR=OFF
		-DENABLE_AS_NEEDED=OFF
	)

	cmake-utils_src_configure
}

src_install() {
	cmake-utils_src_install
	dodoc ChangeLog CREDITS NEWS README
}

pkg_preinst() {
	gnome2_icon_savelist
}

pkg_postinst() {
	gnome2_icon_cache_update
}

pkg_postrm() {
	gnome2_icon_cache_update
}