[gentoo-commits] gentoo-x86 commit in net-libs/aqbanking: ChangeLog aqbanking-4.2.3.ebuild

[Samuli Suominen (ssuominen)]

ssuominen    10/01/07 10:24:49

  Modified:             ChangeLog
  Added:                aqbanking-4.2.3.ebuild
  Log:
  Version bump.
  (Portage version: 2.2_rc61/cvs/Linux x86_64)

Revision  Changes    Path
1.80                 net-libs/aqbanking/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-libs/aqbanking/ChangeLog?rev=1.80&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-libs/aqbanking/ChangeLog?rev=1.80&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-libs/aqbanking/ChangeLog?r1=1.79&r2=1.80

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-libs/aqbanking/ChangeLog,v
retrieving revision 1.79
retrieving revision 1.80
diff -u -r1.79 -r1.80
--- ChangeLog	4 Jan 2010 13:47:30 -0000	1.79
+++ ChangeLog	7 Jan 2010 10:24:48 -0000	1.80
@@ -1,6 +1,12 @@
 # ChangeLog for net-libs/aqbanking
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-libs/aqbanking/ChangeLog,v 1.79 2010/01/04 13:47:30 fauli Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-libs/aqbanking/ChangeLog,v 1.80 2010/01/07 10:24:48 ssuominen Exp $
+
+*aqbanking-4.2.3 (07 Jan 2010)
+
+  07 Jan 2010; Samuli Suominen <ssuominen@g.o>
+  +aqbanking-4.2.3.ebuild:
+  Version bump.
 
   04 Jan 2010; Christian Faulhammer <fauli@g.o>
   aqbanking-4.2.0.ebuild:



1.1                  net-libs/aqbanking/aqbanking-4.2.3.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-libs/aqbanking/aqbanking-4.2.3.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-libs/aqbanking/aqbanking-4.2.3.ebuild?rev=1.1&content-type=text/plain

Index: aqbanking-4.2.3.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-libs/aqbanking/aqbanking-4.2.3.ebuild,v 1.1 2010/01/07 10:24:48 ssuominen Exp $

EAPI=2
inherit multilib

DESCRIPTION="Generic Online Banking Interface"
HOMEPAGE="http://www.aquamaniac.de/aqbanking/"
SRC_URI="http://www.aquamaniac.de/sites/download/download.php?package=03&release=49&file=01&dummy=${P}.tar.gz -> ${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~ppc64 ~sparc ~x86"
IUSE="chipcard debug ofx qt4"

RDEPEND=">=sys-libs/gwenhywfar-3.11.3
	>=app-misc/ktoblzcheck-1.24
	ofx? ( >=dev-libs/libofx-0.9.1 )
	chipcard? ( >=sys-libs/libchipcard-4.2.8 )
	qt4? ( x11-libs/qt-gui:4[qt3support] )"
DEPEND="${RDEPEND}
	dev-util/pkgconfig"

MAKEOPTS="${MAKEOPTS} -j1"

RESTRICT="test"

src_configure() {
	local frontends="cbanking"
	use qt4 && frontends="${frontends} qbanking"

	local backends="aqhbci aqnone"
	use ofx && backends="${backends} aqofxconnect"

	local myconf qt3_libs qt3_includes
	if use qt4; then
		qt3_libs="$(pkg-config QtCore QtGui Qt3Support --libs)"
		qt3_includes="$(pkg-config QtCore QtGui Qt3Support --cflags-only-I)"
		myconf="--enable-qt3=yes"
	else
		myconf="--enable-qt3=no"
	fi

	econf \
		QTDIR="/usr/$(get_libdir)/qt4" \
		QT3TO4="/usr/bin/qt3to4" \
		qt3_libs="${qt3_libs}" \
		qt3_includes="${qt3_includes}" \
		--disable-dependency-tracking \
		$(use_enable debug) \
		--with-frontends="${frontends}" \
		--with-backends="${backends}" \
		--with-docpath=/usr/share/doc/${PF}/apidoc \
		${myconf}
}

src_compile() {
	if use qt4; then
		emake qt4-port || die
	fi

	emake || die
}

src_install() {
	emake DESTDIR="${D}" install || die
	rm -rf "${D}"/usr/share/doc/${PN}
	find "${D}" -name '*.la' -delete
	dodoc AUTHORS ChangeLog NEWS README TODO
}