[gentoo-commits] gentoo-x86 commit in dev-python/lxml: ChangeLog lxml-2.0.3.ebuild

[Ali Polatel (hawking)]

hawking     08/03/31 11:16:02

  Modified:             ChangeLog
  Added:                lxml-2.0.3.ebuild
  Log:
  Version bump, use cython instead of bundled pyrex.
  (Portage version: 2.1.4.4)

Revision  Changes    Path
1.34                 dev-python/lxml/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-python/lxml/ChangeLog?rev=1.34&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-python/lxml/ChangeLog?rev=1.34&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-python/lxml/ChangeLog?r1=1.33&r2=1.34

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-python/lxml/ChangeLog,v
retrieving revision 1.33
retrieving revision 1.34
diff -u -r1.33 -r1.34
--- ChangeLog	20 Mar 2008 20:30:16 -0000	1.33
+++ ChangeLog	31 Mar 2008 11:16:02 -0000	1.34
@@ -1,6 +1,12 @@
 # ChangeLog for dev-python/lxml
 # Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/lxml/ChangeLog,v 1.33 2008/03/20 20:30:16 fmccor Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/lxml/ChangeLog,v 1.34 2008/03/31 11:16:02 hawking Exp $
+
+*lxml-2.0.3 (31 Mar 2008)
+
+  31 Mar 2008; Ali Polatel <hawking@g.o>
+  +files/lxml-2.0.3-no-fake-pyrex.patch, +lxml-2.0.3.ebuild:
+  Version bump, use cython instead of bundled pyrex.
 
   20 Mar 2008; Ferris McCormick <fmccor@g.o> lxml-1.3.6.ebuild:
   Add ~sparc for Bug #213611.  Tests pass (which is not the case for 2.0.2).



1.1                  dev-python/lxml/lxml-2.0.3.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-python/lxml/lxml-2.0.3.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-python/lxml/lxml-2.0.3.ebuild?rev=1.1&content-type=text/plain

Index: lxml-2.0.3.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-python/lxml/lxml-2.0.3.ebuild,v 1.1 2008/03/31 11:16:02 hawking Exp $

NEED_PYTHON="2.3"

inherit distutils eutils multilib

DESCRIPTION="A Pythonic binding for the libxml2 and libxslt libraries"
HOMEPAGE="http://codespeak.net/lxml/"
SRC_URI="http://codespeak.net/lxml/${P}.tgz"
LICENSE="BSD ElementTree GPL-2 PSF-2.4"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="doc examples"

RDEPEND=">=dev-libs/libxml2-2.6.20
		>=dev-libs/libxslt-1.1.15"
DEPEND="${RDEPEND}
	>=dev-python/cython-0.9.6.10
	>=dev-python/setuptools-0.6_rc5"

src_unpack() {
	unpack ${A}
	cd "${S}"

	# Use cython instead of own bundled version of pyrex
	epatch "${FILESDIR}/${P}-no-fake-pyrex.patch"
}

src_install() {
	distutils_src_install

	if use doc; then
		dohtml doc/html/*
		dodoc *.txt
		docinto doc
		dodoc doc/*.txt
	fi

	if use examples; then
		insinto /usr/share/doc/${PF}/examples
		doins -r samples/*
	fi
}

src_test() {
	distutils_python_version
	python setup.py build_ext -i || die "building extensions for test use failed"
	einfo "Running test"
	"${python}" test.py || die "tests failed"
	export PYTHONPATH="${PYTHONPATH}:${S}/src"
	einfo "Running selftest"
	"${python}" selftest.py || die "selftest failed"
	einfo "Running selftest2"
	"${python}" selftest2.py || die "selftest2 failed"
}



-- 
gentoo-commits@l.g.o mailing list