[gentoo-commits] gentoo-x86 commit in net-libs/libproxy: libproxy-0.2.3-r2.ebuild ChangeLog libproxy-0.2.3-r1.ebuild

[Mart Raudsepp (leio)]

leio        09/06/29 19:26:13

  Modified:             ChangeLog
  Added:                libproxy-0.2.3-r2.ebuild
  Removed:              libproxy-0.2.3-r1.ebuild
  Log:
  Fix automagic mozilla-js provider picking, so that with USE=xulrunner xulrunner-1.9 is always picked, and with USE="seamonkey -xulrunner" seamonkey-js is always picked. Depend on a xulrunner:1.9 that has its mozilla-js pkgconfig file usable for us while building to fix bug 275318 once and for all
  (Portage version: 2.2_rc22/cvs/Linux 2.6.30-gentoo-r1 x86_64, RepoMan options: --force)

Revision  Changes    Path
1.16                 net-libs/libproxy/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-libs/libproxy/ChangeLog?rev=1.16&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-libs/libproxy/ChangeLog?rev=1.16&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-libs/libproxy/ChangeLog?r1=1.15&r2=1.16

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-libs/libproxy/ChangeLog,v
retrieving revision 1.15
retrieving revision 1.16
diff -u -r1.15 -r1.16
--- ChangeLog	25 Jun 2009 20:53:37 -0000	1.15
+++ ChangeLog	29 Jun 2009 19:26:13 -0000	1.16
@@ -1,6 +1,14 @@
 # ChangeLog for net-libs/libproxy
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-libs/libproxy/ChangeLog,v 1.15 2009/06/25 20:53:37 mrpouet Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-libs/libproxy/ChangeLog,v 1.16 2009/06/29 19:26:13 leio Exp $
+
+  29 Jun 2009; Mart Raudsepp <leio@g.o>
+  +files/libproxy-0.2.3-fix-automagic-mozjs.patch:
+  Fix automagic mozilla-js provider picking, so that with USE=xulrunner
+  xulrunner-1.9 is always picked, and with USE="seamonkey -xulrunner"
+  seamonkey-js is always picked. Depend on a xulrunner:1.9 that has its
+  mozilla-js pkgconfig file usable for us while building to fix bug 275318
+  once and for all
 
   25 Jun 2009; Romain Perier <mrpouet@g.o>
   files/libproxy-0.2.3-fix-mozjs-cflags.patch:



1.1                  net-libs/libproxy/libproxy-0.2.3-r2.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-libs/libproxy/libproxy-0.2.3-r2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-libs/libproxy/libproxy-0.2.3-r2.ebuild?rev=1.1&content-type=text/plain

Index: libproxy-0.2.3-r2.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-libs/libproxy/libproxy-0.2.3-r2.ebuild,v 1.1 2009/06/29 19:26:13 leio Exp $

EAPI="2"

inherit autotools eutils python portability

DESCRIPTION="Library for automatic proxy configuration management"
HOMEPAGE="http://code.google.com/p/libproxy/"
SRC_URI="http://${PN}.googlecode.com/files/${P}.tar.gz"

LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd"
IUSE="gnome kde networkmanager python seamonkey webkit xulrunner"

RDEPEND="
	gnome? (
		x11-libs/libX11
		x11-libs/libXmu
		gnome-base/gconf )
	kde? (
		x11-libs/libX11
		x11-libs/libXmu )
	networkmanager? ( net-misc/networkmanager )
	python? ( >=dev-lang/python-2.5 )
	webkit? ( net-libs/webkit-gtk )
	xulrunner? ( >=net-libs/xulrunner-1.9.0.11-r1:1.9 )
	!xulrunner? ( seamonkey? ( www-client/seamonkey ) )
"
# Since xulrunner-1.9.0.11-r1 its shipped mozilla-js.pc is fixed so we can use it

DEPEND="${RDEPEND}
	>=dev-util/pkgconfig-0.19"

src_prepare() {
	# http://code.google.com/p/libproxy/issues/detail?id=23
	epatch "${FILESDIR}/${P}-fix-dbus-includes.patch"

	# http://code.google.com/p/libproxy/issues/detail?id=24
	epatch "${FILESDIR}/${P}-fix-python-automagic.patch"

	# http://code.google.com/p/libproxy/issues/detail?id=25
	epatch "${FILESDIR}/${P}-fix-as-needed-problem.patch"

	# Bug 275127 and 275318
	epatch "${FILESDIR}/${P}-fix-automagic-mozjs.patch"

	# Fix implicit declaration QA, bug #268546
	epatch "${FILESDIR}/${P}-implicit-declaration.patch"

	epatch "${FILESDIR}/${P}-fbsd.patch" # drop at next bump

	# Fix test to follow POSIX (for x86-fbsd).
	# FIXME: This doesn't actually fix all == instances when two are on the same line
	sed -e 's/\(test.*\)==/\1=/g' -i configure.ac configure || die "sed failed"

	eautoreconf
}

src_configure() {
	local myconf

	# xulrunner:1.9 => mozilla;   seamonkey => seamonkey;
	# xulrunner:1.8 => xulrunner; (firefox => mozilla-firefox[-xulrunner] ?)
	if use xulrunner; then myconf="--with-mozjs=mozilla"
	elif use seamonkey; then myconf="--with-mozjs=seamonkey"
	else myconf="--without-mozjs"
	fi

	econf --with-envvar \
		--with-file \
		--disable-static \
		$(use_with gnome) \
		$(use_with kde) \
		$(use_with webkit) \
		${myconf} \
		$(use_with networkmanager) \
		$(use_with python)
}

src_compile() {
	emake LIBDL="$(dlopen_lib)" || die
}

src_install() {
	emake DESTDIR="${D}" LIBDL="$(dlopen_lib)" install || die "emake install failed!"
	dodoc AUTHORS NEWS README ChangeLog || die "dodoc failed"
}

pkg_postinst() {
	if use python; then
		python_need_rebuild
		python_mod_optimize "$(python_get_sitedir)/${PN}.py"
	fi
}

pkg_postrm() {
	python_mod_cleanup /usr/$(get_libdir)/python*/site-packages/${PN}.py
}