[gentoo-commits] repo/gentoo:master commit in: games-emulation/dosbox-staging/, games-emulation/dosbox-staging/files/

[Bernard Cafarelli]

commit:     0d7dc6ce882f0189e8340630c9bd1fdf75f02d10
Author:     Bernard Cafarelli <voyageur <AT> gentoo <DOT> org>
AuthorDate: Fri Sep  4 21:25:48 2020 +0000
Commit:     Bernard Cafarelli <voyageur <AT> gentoo <DOT> org>
CommitDate: Fri Sep  4 21:26:21 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=0d7dc6ce

games-emulation/dosbox-staging: small fixes

Do not call ar directly
Fix icon installation
Use provided desktop file

Closes: https://bugs.gentoo.org/738116
Closes: https://bugs.gentoo.org/738470
Package-Manager: Portage-3.0.5, Repoman-3.0.1
Signed-off-by: Bernard Cafarelli <voyageur <AT> gentoo.org>

 .../dosbox-staging/dosbox-staging-0.75.1-r2.ebuild | 51 ++++++++++++++++++++++
 .../files/dosbox-staging-0.75.1-ar.patch           | 11 +++++
 2 files changed, 62 insertions(+)

diff --git a/games-emulation/dosbox-staging/dosbox-staging-0.75.1-r2.ebuild b/games-emulation/dosbox-staging/dosbox-staging-0.75.1-r2.ebuild
new file mode 100644
index 00000000000..12e1e297030
--- /dev/null
+++ b/games-emulation/dosbox-staging/dosbox-staging-0.75.1-r2.ebuild
@@ -0,0 +1,51 @@
+# Copyright 2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit autotools desktop xdg
+
+DESCRIPTION="Modernized DOSBox soft-fork"
+HOMEPAGE="https://dosbox-staging.github.io/"
+SRC_URI="https://github.com/dosbox-staging/dosbox-staging/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="alsa debug dynrec network opengl opus"
+
+RDEPEND="alsa? ( media-libs/alsa-lib )
+	debug? ( sys-libs/ncurses:0= )
+	network? ( media-libs/sdl2-net )
+	opengl? ( virtual/opengl )
+	opus? ( media-libs/opusfile )
+	media-libs/libpng:0=
+	media-libs/libsdl2[joystick,opengl?,video,X]
+	sys-libs/zlib
+	!games-emulation/dosbox"
+DEPEND="${RDEPEND}"
+BDEPEND=""
+
+PATCHES=( "${FILESDIR}"/${P}-ar.patch
+	"${FILESDIR}"/${P}-pthread.patch )
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		$(use_enable alsa alsa-midi) \
+		$(use_enable debug) \
+		$(use_enable !dynrec dynamic-x86) \
+		$(use_enable dynrec) \
+		$(use_enable network) \
+		$(use_enable opengl) \
+		$(use_enable opus opus-cdda)
+}
+
+src_install() {
+	default
+	doicon -s scalable contrib/icons/${PN}.svg
+	domenu contrib/linux/dosbox-staging.desktop
+}

diff --git a/games-emulation/dosbox-staging/files/dosbox-staging-0.75.1-ar.patch b/games-emulation/dosbox-staging/files/dosbox-staging-0.75.1-ar.patch
new file mode 100644
index 00000000000..fb2c24267f0
--- /dev/null
+++ b/games-emulation/dosbox-staging/files/dosbox-staging-0.75.1-ar.patch
@@ -0,0 +1,11 @@
+diff -Naur dosbox-staging-0.75.1.orig/configure.ac dosbox-staging-0.75.1/configure.ac
+--- dosbox-staging-0.75.1.orig/configure.ac	2020-08-19 10:49:45.000000000 +0200
++++ dosbox-staging-0.75.1/configure.ac	2020-09-04 23:03:11.375920481 +0200
+@@ -17,6 +17,7 @@
+ AC_CONFIG_HEADER(config.h)
+ 
+ dnl Checks for programs.
++AM_PROG_AR
+ AC_PROG_MAKE_SET
+ AC_PROG_CC
+ AC_PROG_CPP