[gentoo-commits] proj/mozilla:master commit in: www-client/seamonkey/

[Ian Stakenvicius]

commit:     3c2d7007f9e4897e51c1a982b3274dcdf9b5adc8
Author:     Ian Stakenvicius <axs <AT> gentoo <DOT> org>
AuthorDate: Sat Oct  1 14:48:43 2016 +0000
Commit:     Ian Stakenvicius <axs <AT> gentoo <DOT> org>
CommitDate: Sat Oct  1 14:48:43 2016 +0000
URL:        https://gitweb.gentoo.org/proj/mozilla.git/commit/?id=3c2d7007

www-client/seamonkey-2.42: bump to build from thunderbird-45.4

 www-client/seamonkey/Manifest                     |   1 +
 www-client/seamonkey/seamonkey-2.42.4.0_p0.ebuild | 394 ++++++++++++++++++++++
 2 files changed, 395 insertions(+)

diff --git a/www-client/seamonkey/Manifest b/www-client/seamonkey/Manifest
index 53ec62d..126a749 100644
--- a/www-client/seamonkey/Manifest
+++ b/www-client/seamonkey/Manifest
@@ -62,3 +62,4 @@ DIST seamonkey-2.40.source.tar.xz 193702432 SHA256 7ecccc039d03f38d197b123b59ea4
 DIST seamonkey-2.42-patches-01.tar.xz 812 SHA256 289b36a4538e4f3ec3633c08084d018e52fd2edfbdd1748c341accd452d20ee0 SHA512 7c727324671c242940876acfce6a95ac1b47713c83be502c8a5dba26be3d5e7998a13ae93c8874d51c3250bd3916d4468cb51b3beb26e74ff7d9d6ffa4c63c95 WHIRLPOOL 4c90988ce1364e38848caf92fb3f565cab4d8ab990eb1eed2c11655eff81d3a77b02577cb43fd35102c04b03c18963989f61ef32c6e9c29bbed2d0e6f9cc78a5
 DIST seamonkey-2.42.3.0-l10n-sources.tar.xz 16552028 SHA256 2d348468c041b29b5ba5defb968dd42ff31733d4c6311c18ff95a9a2b170d649 SHA512 17c75e754ffff1e0d5789a3e9f1435367d68802a754a1b2fe6d1349fc7202a123c50b33a0ae6ebd820ff9069c3f89501c4062851cad83257ceb3577a8726b731 WHIRLPOOL 6b86cd6495e33894a7a1ed7e93bd7d77f7f0070fa5f036acd58fc7aca85994132af6251b1c1b074a557893668a738b37859423bf370e44f7732223ec05dd6165
 DIST thunderbird-45.3.0.source.tar.xz 201005896 SHA256 231f6a7a073344659e436a2b1ae58004c3a29e74375af2c8d0de13f3bc79fac7 SHA512 1226b35535d68b9c088ab8692f61120c99951e1ecbae4739ced711665a3237d248202831831f00536c724e2f6359db4601fa5c90f2793433eab4bd9dab0c1165 WHIRLPOOL 86c4145859ee39d4fcf48eacd5a0b61f6f9f70fee3c2e38fe5b225c06e17ea4b7c1c5ccfa2c9f4d0696e9d807a6b612990ccda7d35bd22a8687ef15a9c3747be
+DIST thunderbird-45.4.0.source.tar.xz 201094212 SHA256 36f66edbb9b0f1ff9d0de8f12eab6cccbfa23db79e01db307fb2186904a38e61 SHA512 9c601d9625b43103b64e111da3a88fccdc30d4a52aa8a66ee02120bc13f3c5600d24fa1cfd3817975a0e58be9078d192334dd3099aa462468d8ab0cd05a3bcd5 WHIRLPOOL 7370f6063a71eeec3f7df7ada6bfed5582414afa7287dd04905655470a99eaa1a2eabf4549807ac2cbea93e59df3542d3cee9aaf939aa7612532bd66402ee5e2

diff --git a/www-client/seamonkey/seamonkey-2.42.4.0_p0.ebuild b/www-client/seamonkey/seamonkey-2.42.4.0_p0.ebuild
new file mode 100644
index 0000000..9d3aaee
--- /dev/null
+++ b/www-client/seamonkey/seamonkey-2.42.4.0_p0.ebuild
@@ -0,0 +1,394 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+WANT_AUTOCONF="2.1"
+
+# This list can be updated with scripts/get_langs.sh from the mozilla overlay
+# note - could not roll langpacks for: ca fi
+MOZ_LANGS=(be cs de en en-GB en-US es-AR es-ES fr gl hu it ja lt nb-NO nl
+	    pl pt-PT ru sk sv-SE tr uk zh-CN zh-TW)
+
+MOZ_PV="${PV/_pre*}"
+MOZ_PV="${MOZ_PV/_alpha/a}"
+MOZ_PV="${MOZ_PV/_beta/b}"
+MOZ_PV="${MOZ_PV/_rc/rc}"
+MOZ_PV="${MOZ_PV/_p0}"
+MOZ_P="${P}"
+MY_MOZ_P="${PN}-${MOZ_PV}"
+
+if [[ ${PV} == *_pre* ]] ; then
+# the following are for upstream build candidates
+#	MOZ_HTTP_URI="https://archive.mozilla.org/pub/${PN}/candidates/${MOZ_PV}-candidates/build${PV##*_pre}"
+#	MOZ_LANGPACK_PREFIX="linux-i686/xpi/"
+	# And the langpack stuff stays at eclass defaults
+# the following is for self-rolled releases
+	MOZ_HTTP_URI="https://dev.gentoo.org/~axs/distfiles"
+	MOZ_LANGPACK_PREFIX="${MY_MOZ_P}."
+	MOZ_LANGPACK_SUFFIX=".langpack.xpi"
+	SRC_URI="${SRC_URI}
+	${MOZ_HTTP_URI}/${P}.source.tar.xz
+	"
+elif [[ ${PV} == *_p0 ]]; then
+	# gentoo-unofficial release using thunderbird distfiles to build seamonkey instead
+	TB_MAJOR=45
+	SMPV="${PV%.[0-9].*}"
+	MOZ_P="${PN}-${SMPV}"
+	MOZ_HTTP_URI="https://archive.mozilla.org/pub/thunderbird/releases/${MOZ_PV/${SMPV}/${TB_MAJOR}}"
+	MOZ_GENERATE_LANGPACKS=1
+	S="${WORKDIR}/thunderbird-${MOZ_PV/${SMPV}/${TB_MAJOR}}"
+	SRC_URI="${SRC_URI}
+	${MOZ_HTTP_URI}/source/${MY_MOZ_P/${MOZ_P}/thunderbird-${TB_MAJOR}}.source.tar.xz
+	https://dev.gentoo.org/~axs/distfiles/${PN}-2.42.3.0-l10n-sources.tar.xz
+	https://dev.gentoo.org/~axs/distfiles/chatzilla-2.42.tar.xz
+	https://dev.gentoo.org/~axs/distfiles/dom-inspector-2.0.16.tar.xz
+	"
+else
+	MOZ_HTTP_URI="https://archive.mozilla.org/pub/${PN}/releases/${MOZ_PV}"
+	MOZ_LANGPACK_PREFIX="langpack/${MY_MOZ_P}."
+	MOZ_LANGPACK_SUFFIX=".langpack.xpi"
+	S="${WORKDIR}/${PN}-${MOZ_PV}"
+	SRC_URI="${SRC_URI}
+	${MOZ_HTTP_URI}/source/${MY_MOZ_P}.source.tar.xz -> ${P}.source.tar.xz
+	"
+fi
+
+MOZCONFIG_OPTIONAL_WIFI=1
+MOZCONFIG_OPTIONAL_JIT="enabled"
+inherit check-reqs flag-o-matic toolchain-funcs eutils mozconfig-v6.45 multilib pax-utils fdo-mime autotools mozextension nsplugins mozlinguas-v2
+
+PATCHFF="firefox-45.0-patches-04"
+PATCH="${PN}-2.42-patches-01"
+EMVER="1.9.1"
+
+DESCRIPTION="Seamonkey Web Browser"
+HOMEPAGE="http://www.seamonkey-project.org"
+KEYWORDS="~alpha ~amd64 ~arm ~ppc ~ppc64 ~x86"
+
+SLOT="0"
+LICENSE="MPL-2.0 GPL-2 LGPL-2.1"
+IUSE="+chatzilla +crypt +gmp-autoupdate +ipc minimal pulseaudio +roaming selinux test"
+
+SRC_URI="${SRC_URI}
+	https://dev.gentoo.org/~anarchy/mozilla/patchsets/${PATCHFF}.tar.xz
+	https://dev.gentoo.org/~axs/mozilla/patchsets/${PATCHFF}.tar.xz
+	https://dev.gentoo.org/~axs/mozilla/patchsets/${PATCH}.tar.xz
+	https://dev.gentoo.org/~polynomial-c/mozilla/patchsets/${PATCHFF}.tar.xz
+	https://dev.gentoo.org/~polynomial-c/mozilla/patchsets/${PATCH}.tar.xz
+	crypt? ( https://www.enigmail.net/download/source/enigmail-${EMVER}.tar.gz )"
+
+ASM_DEPEND=">=dev-lang/yasm-1.1"
+
+RDEPEND=">=dev-libs/nss-3.22.3
+	>=dev-libs/nspr-4.12
+	crypt? ( || (
+			( >=app-crypt/gnupg-2.0
+				|| (
+					app-crypt/pinentry[gtk]
+					app-crypt/pinentry[qt4]
+				)
+			)
+			=app-crypt/gnupg-1.4* ) )"
+
+DEPEND="${RDEPEND}
+	!elibc_glibc? ( !elibc_uclibc?  ( dev-libs/libexecinfo ) )
+	crypt? ( dev-lang/perl )
+	amd64? ( ${ASM_DEPEND}
+		virtual/opengl )
+	x86? ( ${ASM_DEPEND}
+		virtual/opengl )"
+
+BUILD_OBJ_DIR="${S}/seamonk"
+
+pkg_setup() {
+	if [[ ${PV} == *_pre* ]] ; then
+		ewarn "You're using an unofficial release of ${PN}. Don't file any bug in"
+		ewarn "Gentoo's Bugtracker against this package in case it breaks for you."
+		ewarn "Those belong to upstream: https://bugzilla.mozilla.org"
+	fi
+
+	moz_pkgsetup
+}
+
+pkg_pretend() {
+	# Ensure we have enough disk space to compile
+	if use debug || use test ; then
+		CHECKREQS_DISK_BUILD="8G"
+	else
+		CHECKREQS_DISK_BUILD="4G"
+	fi
+	check-reqs_pkg_setup
+}
+
+src_unpack() {
+	unpack ${A}
+
+	# Unpack language packs
+	mozlinguas_src_unpack
+
+	# move the irc and inspector code into the correct locations
+	mv "${WORKDIR}"/irc "${S}"/mozilla/extensions/irc || die
+	mv "${WORKDIR}"/inspector "${S}"/mozilla/extensions/inspector || die
+}
+
+src_prepare() {
+	# Apply our patches
+	eapply "${WORKDIR}"/seamonkey \
+		"${FILESDIR}"/${PN}-2.42.3.0-fix-chatzillaless-locale-building.patch
+
+	# browser patches go here
+	pushd "${S}"/mozilla &>/dev/null || die
+	rm -f "${WORKDIR}"/firefox/2000-firefox_gentoo_install_dirs.patch
+	eapply "${WORKDIR}"/firefox
+	popd &>/dev/null || die
+
+	# Shell scripts sometimes contain DOS line endings; bug 391889
+	grep -rlZ --include="*.sh" $'\r$' . |
+	while read -r -d $'\0' file ; do
+		einfo edos2unix "${file}"
+		edos2unix "${file}"
+	done
+
+	# Allow user to apply any additional patches without modifing ebuild
+	eapply_user
+
+	local ms="${S}/mozilla"
+
+	# Enable gnomebreakpad
+	if use debug ; then
+		sed -i -e "s:GNOME_DISABLE_CRASH_DIALOG=1:GNOME_DISABLE_CRASH_DIALOG=0:g" \
+			"${ms}"/build/unix/run-mozilla.sh || die "sed failed!"
+	fi
+
+	# Ensure that are plugins dir is enabled as default
+	sed -i -e "s:/usr/lib/mozilla/plugins:/usr/lib/nsbrowser/plugins:" \
+		"${ms}"/xpcom/io/nsAppFileLocationProvider.cpp || die "sed failed to replace plugin path for 32bit!"
+	sed -i -e "s:/usr/lib64/mozilla/plugins:/usr/lib64/nsbrowser/plugins:" \
+		"${ms}"/xpcom/io/nsAppFileLocationProvider.cpp || die "sed failed to replace plugin path for 64bit!"
+
+	# Don't exit with error when some libs are missing which we have in
+	# system.
+	sed '/^MOZ_PKG_FATAL_WARNINGS/s@= 1@= 0@' \
+		-i "${S}"/suite/installer/Makefile.in || die
+	# Don't error out when there's no files to be removed:
+	sed 's@\(xargs rm\)$@\1 -f@' \
+		-i "${ms}"/toolkit/mozapps/installer/packager.mk || die
+
+	eautoreconf
+	cd "${S}"/mozilla || die
+	eautoconf
+	cd "${S}"/mozilla/js/src || die
+	eautoconf
+	cd "${S}"/mozilla/memory/jemalloc/src || die
+	WANT_AUTOCONF= eautoconf
+}
+
+src_configure() {
+	MOZILLA_FIVE_HOME="/usr/$(get_libdir)/${PN}"
+	MEXTENSIONS="default"
+	# Google API keys (see http://www.chromium.org/developers/how-tos/api-keys)
+	# Note: These are for Gentoo Linux use ONLY. For your own distribution, please
+	# get your own set of keys.
+	_google_api_key=AIzaSyDEAOvatFo0eTgsV_ZlEzx0ObmepsMzfAc
+
+	####################################
+	#
+	# mozconfig, CFLAGS and CXXFLAGS setup
+	#
+	####################################
+
+	mozconfig_init
+	mozconfig_config
+
+	# It doesn't compile on alpha without this LDFLAGS
+	use alpha && append-ldflags "-Wl,--no-relax"
+
+	if ! use chatzilla ; then
+		MEXTENSIONS+=",-irc"
+	fi
+	if ! use roaming ; then
+		MEXTENSIONS+=",-sroaming"
+	fi
+
+	# Setup api key for location services
+	echo -n "${_google_api_key}" > "${S}"/google-api-key
+	mozconfig_annotate '' --with-google-api-keyfile="${S}/google-api-key"
+
+	mozconfig_annotate '' --enable-extensions="${MEXTENSIONS}"
+	mozconfig_annotate '' --enable-jsd
+	mozconfig_annotate '' --enable-canvas
+
+	# Other sm-specific settings
+	mozconfig_annotate '' --with-default-mozilla-five-home=${MOZILLA_FIVE_HOME}
+
+	mozconfig_annotate '' --enable-safe-browsing
+
+	mozlinguas_mozconfig
+
+	# Use an objdir to keep things organized.
+	echo "mk_add_options MOZ_OBJDIR=${BUILD_OBJ_DIR}" \
+		>> "${S}"/.mozconfig
+
+	# Finalize and report settings
+	mozconfig_final
+
+	if use crypt ; then
+		pushd "${WORKDIR}"/enigmail &>/dev/null || die
+		econf
+		popd &>/dev/null || die
+	fi
+
+	# Work around breakage in makeopts with --no-print-directory
+	MAKEOPTS="${MAKEOPTS/--no-print-directory/}"
+
+	if [[ $(gcc-major-version) -lt 4 ]] ; then
+		append-cxxflags -fno-stack-protector
+	elif [[ $(gcc-major-version) -gt 4 || $(gcc-minor-version) -gt 3 ]] ; then
+		if use amd64 || use x86 ; then
+			append-flags -mno-avx
+		fi
+	fi
+
+	emake V=1 -f client.mk configure
+}
+
+src_compile() {
+	CC="$(tc-getCC)" CXX="$(tc-getCXX)" LD="$(tc-getLD)" \
+	MOZ_MAKE_FLAGS="${MAKEOPTS}" SHELL="${SHELL}" \
+	emake V=1 -f client.mk
+
+	mozlinguas_src_compile
+
+	# Only build enigmail extension if conditions are met.
+	if use crypt ; then
+		einfo "Building enigmail"
+		pushd "${WORKDIR}"/enigmail &>/dev/null || die
+		emake -j1
+		emake xpi
+		popd &>/dev/null || die
+	fi
+}
+
+src_install() {
+	MOZILLA_FIVE_HOME="/usr/$(get_libdir)/${PN}"
+	DICTPATH="\"${EPREFIX}/usr/share/myspell\""
+
+	local emid
+	cd "${BUILD_OBJ_DIR}" || die
+
+	# Pax mark xpcshell for hardened support, only used for startupcache creation.
+	pax-mark m "${BUILD_OBJ_DIR}/dist/bin/xpcshell"
+
+	# Copy our preference before omnijar is created.
+	sed "s|SEAMONKEY_PVR|${PVR}|" "${FILESDIR}"/all-gentoo-1.js > \
+		"${BUILD_OBJ_DIR}/dist/bin/defaults/pref/all-gentoo.js" \
+		|| die
+
+	# Set default path to search for dictionaries.
+	echo "pref(\"spellchecker.dictionary_path\", ${DICTPATH});" \
+		>> "${BUILD_OBJ_DIR}/dist/bin/defaults/pref/all-gentoo.js" \
+		|| die
+
+	echo 'pref("extensions.autoDisableScopes", 3);' >> \
+		"${BUILD_OBJ_DIR}/dist/bin/defaults/pref/all-gentoo.js" \
+		|| die
+
+	local plugin
+	if ! use gmp-autoupdate ; then
+		for plugin in gmp-gmpopenh264 ; do
+			echo "pref(\"media.${plugin}.autoupdate\", false);" >> \
+				"${S}/${BUILD_OBJ_DIR}/dist/bin/browser/defaults/preferences/all-gentoo.js" \
+				|| dir
+		done
+	fi
+
+	MOZ_MAKE_FLAGS="${MAKEOPTS}" \
+	emake DESTDIR="${D}" install
+	cp "${FILESDIR}"/${PN}.desktop "${T}" || die
+
+	if use crypt ; then
+		local em_dir="${WORKDIR}/enigmail/build"
+		pushd "${T}" &>/dev/null || die
+		unzip "${em_dir}"/enigmail*.xpi install.rdf || die
+		emid=$(sed -n '/<em:id>/!d; s/.*\({.*}\).*/\1/; p; q' install.rdf)
+		#'
+		dodir ${MOZILLA_FIVE_HOME}/extensions/${emid}
+		cd "${D}"${MOZILLA_FIVE_HOME}/extensions/${emid} || die
+		unzip "${em_dir}"/enigmail*.xpi || die
+
+		popd &>/dev/null || die
+	fi
+
+	sed 's|^\(MimeType=.*\)$|\1text/x-vcard;text/directory;application/mbox;message/rfc822;x-scheme-handler/mailto;|' \
+		-i "${T}"/${PN}.desktop || die
+	sed 's|^\(Categories=.*\)$|\1Email;|' -i "${T}"/${PN}.desktop \
+		|| die
+
+	# Install language packs
+	mozlinguas_src_install
+
+	# Add StartupNotify=true bug 290401
+	if use startup-notification ; then
+		echo "StartupNotify=true" >> "${T}"/${PN}.desktop || die
+	fi
+
+	# Install icon and .desktop for menu entry
+	newicon "${S}"/suite/branding/nightly/content/icon64.png ${PN}.png
+	domenu "${T}"/${PN}.desktop
+
+	# Required in order to use plugins and even run seamonkey on hardened.
+	pax-mark m "${ED}"${MOZILLA_FIVE_HOME}/{seamonkey,seamonkey-bin,plugin-container}
+
+	if use minimal ; then
+		rm -rf "${ED}"/usr/include "${ED}${MOZILLA_FIVE_HOME}"/{idl,include,lib,sdk}
+	fi
+
+	if use chatzilla ; then
+		local emid='{59c81df5-4b7a-477b-912d-4e0fdf64e5f2}'
+
+		# remove the en_US-only xpi file so a version with all requested locales can be installed
+		if [[ -e "${ED}"${MOZILLA_FIVE_HOME}/distribution/extensions/${emid}.xpi ]]; then
+			rm -f "${ED}"${MOZILLA_FIVE_HOME}/distribution/extensions/${emid}.xpi || die
+		fi
+
+		# merge the extra locales into the main extension
+		mozlinguas_xpistage_langpacks "${BUILD_OBJ_DIR}"/dist/xpi-stage/chatzilla
+
+		# install the merged extension
+		mkdir -p "${T}/${emid}" || die
+		cp -RLp -t "${T}/${emid}" "${BUILD_OBJ_DIR}"/dist/xpi-stage/chatzilla/* || die
+		insinto ${MOZILLA_FIVE_HOME}/distribution/extensions
+		doins -r "${T}/${emid}"
+	fi
+
+	# Handle plugins dir through nsplugins.eclass
+	share_plugins_dir
+
+	#doman "${BUILD_OBJ_DIR}/suite/app/${PN}.1"
+
+	# revdep-rebuild entry
+	insinto /etc/revdep-rebuild
+	echo "SEARCH_DIRS_MASK=${MOZILLA_FIVE_HOME}*" >> ${T}/11${PN}
+	doins "${T}"/11${PN}
+}
+
+pkg_preinst() {
+	MOZILLA_FIVE_HOME="${ROOT}/usr/$(get_libdir)/${PN}"
+
+	if [ -d ${MOZILLA_FIVE_HOME}/plugins ] ; then
+		rm ${MOZILLA_FIVE_HOME}/plugins -rf
+	fi
+}
+
+pkg_postinst() {
+	MOZILLA_FIVE_HOME="/usr/$(get_libdir)/${PN}"
+
+	# Update mimedb for the new .desktop file
+	fdo-mime_desktop_database_update
+
+	if use chatzilla ; then
+		elog "chatzilla is now an extension which can be en-/disabled and configured via"
+		elog "the Add-on manager."
+	fi
+}