[gentoo-commits] repo/gentoo:master commit in: sci-libs/gsl/

[Benda XU]

commit:     dc5c06fd1e256673003eb9dea74cc0e131b208db
Author:     Benda Xu <heroxbd <AT> gentoo <DOT> org>
AuthorDate: Wed Jun 26 16:05:41 2019 +0000
Commit:     Benda XU <heroxbd <AT> gentoo <DOT> org>
CommitDate: Wed Jun 26 16:07:01 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=dc5c06fd

sci-libs/gsl: strip the cblas provider role.

  Computationally sci-libs/gsl as a cblas provider has no significant
  advantage over the reference implementation.  Providing sci-libs/gsl
  as a general cblas provider introduces possibility circular
  dependency.  sci-libs/gsl should rather be a cblas user than a
  provider.

Closes: https://bugs.gentoo.org/688742
Package-Manager: Portage-2.3.52, Repoman-2.3.12
RepoMan-Options: --force
Signed-off-by: Benda Xu <heroxbd <AT> gentoo.org>

 sci-libs/gsl/gsl-2.5-r1.ebuild | 58 ++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 58 insertions(+)

diff --git a/sci-libs/gsl/gsl-2.5-r1.ebuild b/sci-libs/gsl/gsl-2.5-r1.ebuild
new file mode 100644
index 00000000000..0c95bb68c55
--- /dev/null
+++ b/sci-libs/gsl/gsl-2.5-r1.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools flag-o-matic toolchain-funcs
+
+DESCRIPTION="The GNU Scientific Library"
+HOMEPAGE="https://www.gnu.org/software/gsl/"
+SRC_URI="mirror://gnu/${PN}/${P}.tar.gz
+	https://dev.gentoo.org/~mgorny/dist/${PN}-2.3-cblas.patch.bz2"
+
+LICENSE="GPL-3"
+SLOT="0/23"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd ~amd64-linux ~x86-linux ~x86-macos ~sparc-solaris ~x86-solaris"
+IUSE="cblas-external +deprecated static-libs"
+
+RDEPEND="cblas-external? ( virtual/cblas:= )"
+DEPEND="${RDEPEND}"
+
+PATCHES=( "${WORKDIR}"/${PN}-2.3-cblas.patch )
+
+src_prepare() {
+	# bug 349005
+	[[ $(tc-getCC)$ == *gcc* ]] && \
+		[[ $(tc-getCC)$ != *apple* ]] && \
+		[[ $(gcc-major-version)$(gcc-minor-version) -eq 44 ]] \
+		&& filter-mfpmath sse
+	filter-flags -ffast-math
+
+	default
+	if use deprecated; then
+		sed -i -e "/GSL_DISABLE_DEPRECATED/,+2d" configure.ac || die
+	fi
+	eautoreconf
+}
+
+src_configure() {
+	if use cblas-external; then
+		export CBLAS_LIBS="$($(tc-getPKG_CONFIG) --libs cblas)"
+		export CBLAS_CFLAGS="$($(tc-getPKG_CONFIG) --cflags cblas)"
+	fi
+	econf \
+		--enable-shared \
+		$(use_with cblas-external) \
+		$(use_enable static-libs static)
+}
+
+src_test() {
+	local MAKEOPTS="${MAKEOPTS} -j1"
+	default
+}
+
+src_install() {
+	default
+
+	find "${ED}" -name '*.la' -exec rm -f {} +
+}