[gentoo-commits] gentoo-x86 commit in dev-python/numba: numba-0.19.2.ebuild ChangeLog numba-0.17.0.ebuild

[Ian Delaney (idella4)]

idella4     15/06/28 10:06:51

  Modified:             ChangeLog
  Added:                numba-0.19.2.ebuild
  Removed:              numba-0.17.0.ebuild
  Log:
  bump; add patch to facilitate new doc build, upgrade install of docs
  
  (Portage version: 2.2.20/cvs/Linux x86_64, signed Manifest commit with key 0xB8072B0D)

Revision  Changes    Path
1.18                 dev-python/numba/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/numba/ChangeLog?rev=1.18&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/numba/ChangeLog?rev=1.18&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/numba/ChangeLog?r1=1.17&r2=1.18

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-python/numba/ChangeLog,v
retrieving revision 1.17
retrieving revision 1.18
diff -u -r1.17 -r1.18
--- ChangeLog	7 Jun 2015 14:22:05 -0000	1.17
+++ ChangeLog	28 Jun 2015 10:06:51 -0000	1.18
@@ -1,6 +1,13 @@
 # ChangeLog for dev-python/numba
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/numba/ChangeLog,v 1.17 2015/06/07 14:22:05 jlec Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/numba/ChangeLog,v 1.18 2015/06/28 10:06:51 idella4 Exp $
+
+*numba-0.19.2 (28 Jun 2015)
+
+  28 Jun 2015; Ian Delaney <idella4@g.o>
+  +files/numba-0.19.2-docbuild.patch, +numba-0.19.2.ebuild,
+  -numba-0.17.0.ebuild:
+  bump; add patch to facilitate new doc build, upgrade install of docs
 
   07 Jun 2015; Justin Lecher <jlec@g.o> metadata.xml:
   Add github to remote-id in metadata.xml



1.1                  dev-python/numba/numba-0.19.2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/numba/numba-0.19.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/numba/numba-0.19.2.ebuild?rev=1.1&content-type=text/plain

Index: numba-0.19.2.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-python/numba/numba-0.19.2.ebuild,v 1.1 2015/06/28 10:06:51 idella4 Exp $

EAPI=5

# test phase is pointless since it errors in circa 60% of 1984 tests
RESTRICT="test"

PYTHON_COMPAT=( python{2_7,3_3,3_4} )

inherit distutils-r1

DESCRIPTION="NumPy aware dynamic Python compiler using LLVM"
HOMEPAGE="http://numba.pydata.org/"
SRC_URI="https://github.com/${PN}/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~x86"

IUSE="doc examples test"

RDEPEND="
	dev-python/llvmlite[${PYTHON_USEDEP}]
	>=dev-python/numpy-1.6[${PYTHON_USEDEP}]
	$(python_gen_cond_dep 'dev-python/enum34[${PYTHON_USEDEP}]' python{2_7,3_3})
	$(python_gen_cond_dep 'dev-python/funcsigs[${PYTHON_USEDEP}]' python2_7)"
DEPEND="test? ( ${RDEPEND} )
	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )"

# Delete intersphinx & entry to set sphinxjp.themecore, which is absent from portage, from conf.py
PATCHES=( "${FILESDIR}"/${P}-docbuild.patch )

python_prepare_all() {
	# Re-set them of doc build to one provided by sphinx
	if has_version ">=dev-python/sphinx-1.3.1"; then
		sed -e 's:basicstrap:classic:' -i docs/source/conf.py || die
	else
		sed -e 's:basicstrap:default:' -i docs/source/conf.py || die
	fi
	distutils-r1_python_prepare_all
}

python_compile() {
	if ! python_is_python3; then
		local CFLAGS="${CFLAGS} -fno-strict-aliasing"
		export CFLAGS
	fi
	distutils-r1_python_compile
}

python_compile_all() {
	use doc && emake -C docs/ html
}

python_test() {
	cd "${BUILD_DIR}"/lib* || die
	${PYTHON} -c "import numba; numba.test()" || die
}

python_install_all() {
	# doc needs obsolete sphinxjp package
#	use doc && dodoc docs/Numba.pdf
	use examples && local EXAMPLES=( examples/. )
	use doc && local HTML_DOCS=( docs/_build/html/. )

	distutils-r1_python_install_all
}