[gentoo-commits] repo/gentoo:master commit in: app-i18n/ibus-libpinyin/

[Yixun Lan]

commit:     d53d3e23b353806cc69433674efae755be17a720
Author:     Christian Tietz <christian.tietz <AT> mailbox <DOT> org>
AuthorDate: Wed Jun 15 14:55:21 2022 +0000
Commit:     Yixun Lan <dlan <AT> gentoo <DOT> org>
CommitDate: Thu Jun 23 23:12:49 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=d53d3e23

app-i18n/ibus-libpinyin: Bump to 1.12.1, enable py3.10

Closes: https://github.com/gentoo/gentoo/pull/25910
Package-Manager: Portage-3.0.30, Repoman-3.0.3
Signed-off-by: Christian Tietz <christian.tietz <AT> mailbox.org>
Signed-off-by: Yixun Lan <dlan <AT> gentoo.org>

 app-i18n/ibus-libpinyin/Manifest                   |  1 +
 .../ibus-libpinyin/ibus-libpinyin-1.12.1.ebuild    | 69 ++++++++++++++++++++++
 2 files changed, 70 insertions(+)

diff --git a/app-i18n/ibus-libpinyin/Manifest b/app-i18n/ibus-libpinyin/Manifest
index 4e4bf9ae6f8d..49e8d1e5a765 100644
--- a/app-i18n/ibus-libpinyin/Manifest
+++ b/app-i18n/ibus-libpinyin/Manifest
@@ -1 +1,2 @@
 DIST ibus-libpinyin-1.11.92.tar.gz 1730065 BLAKE2B 376bec6fa7616364c8ed4dc5b269edabda892ba4759ff03e93b4099c99440925126800ea3bf11eef91ea62c558fa7dbf05f3d68be5e25e701aaaeb37618b90a8 SHA512 b875b2fed6875806971b91e2abc62cdab1f70baef78840915f89466a7bcf3d1dfc70438ba85e7580bba92dec0ade50a2b05955fe6cd148bffd3888fa69f1c851
+DIST ibus-libpinyin-1.12.1.tar.gz 1766803 BLAKE2B 1de8a51b52688dede32c572b39bd379296480ab2b0f909357465370e346bdf50f4cade5ab3f105f62a74e59cf2dc5e8d5235aedde7571b70d3c5dcee86d2e36b SHA512 ad6e7507bdb468d506071135449383e5bd4fc878bcffda4be6e4e7915b79dbaf919d2fa941b92b177dc7790bd895eaa9a6d04a2610f85e1e80e8eb50f188211d

diff --git a/app-i18n/ibus-libpinyin/ibus-libpinyin-1.12.1.ebuild b/app-i18n/ibus-libpinyin/ibus-libpinyin-1.12.1.ebuild
new file mode 100644
index 000000000000..7f8fdf0ab762
--- /dev/null
+++ b/app-i18n/ibus-libpinyin/ibus-libpinyin-1.12.1.ebuild
@@ -0,0 +1,69 @@
+# Copyright 2015-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+LUA_COMPAT=( lua5-{1..3} )
+PYTHON_COMPAT=( python3_{8..10} )
+
+inherit autotools gnome2-utils lua-single python-single-r1
+
+DESCRIPTION="Intelligent Pinyin and Bopomofo input methods based on LibPinyin for IBus"
+HOMEPAGE="https://github.com/libpinyin/ibus-libpinyin https://sourceforge.net/projects/libpinyin/"
+SRC_URI="https://github.com/libpinyin/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="boost lua opencc"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}
+	lua? ( ${LUA_REQUIRED_USE} )"
+
+BDEPEND="dev-db/sqlite:3
+	virtual/pkgconfig"
+
+DEPEND="${PYTHON_DEPS}
+	>=app-i18n/libpinyin-2.2.1:=
+	dev-db/sqlite:3
+	dev-libs/glib:2
+	virtual/libintl
+	$(python_gen_cond_dep '
+		app-i18n/ibus[python(+),${PYTHON_USEDEP}]
+		dev-python/pygobject:3[${PYTHON_USEDEP}]
+	')
+	boost? ( dev-libs/boost:= )
+	lua? ( ${LUA_DEPS} )
+	opencc? ( app-i18n/opencc:= )"
+
+RDEPEND="${DEPEND}"
+
+pkg_setup() {
+	python-single-r1_pkg_setup
+
+	if use lua; then
+		lua-single_pkg_setup
+	fi
+}
+
+src_prepare() {
+	sed -i \
+		-e "/^appdatadir/s:/appdata:/metainfo:" \
+		data/Makefile.am || die
+	default
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		--enable-english-input-mode \
+		$(use_enable boost) \
+		$(use_enable lua lua-extension) \
+		$(use_enable opencc)
+}
+
+pkg_postinst() {
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	gnome2_schemas_update
+}