[gentoo-commits] gentoo-x86 commit in sys-kernel/spl: spl-9999.ebuild spl-0.6.1.ebuild ChangeLog

[Richard Yao (ryao)]

ryao        13/03/28 22:19:21

  Modified:             spl-9999.ebuild ChangeLog
  Added:                spl-0.6.1.ebuild
  Log:
  Version bump to 0.6.1; Simplify hostid logic
  
  (Portage version: 2.2.0_alpha169/cvs/Linux x86_64, signed Manifest commit with key 0xBEE84C64)

Revision  Changes    Path
1.34                 sys-kernel/spl/spl-9999.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-kernel/spl/spl-9999.ebuild?rev=1.34&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-kernel/spl/spl-9999.ebuild?rev=1.34&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-kernel/spl/spl-9999.ebuild?r1=1.33&r2=1.34

Index: spl-9999.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-kernel/spl/spl-9999.ebuild,v
retrieving revision 1.33
retrieving revision 1.34
diff -u -r1.33 -r1.34
--- spl-9999.ebuild	23 Mar 2013 23:48:08 -0000	1.33
+++ spl-9999.ebuild	28 Mar 2013 22:19:21 -0000	1.34
@@ -1,6 +1,6 @@
 # Copyright 1999-2013 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/sys-kernel/spl/spl-9999.ebuild,v 1.33 2013/03/23 23:48:08 ryao Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-kernel/spl/spl-9999.ebuild,v 1.34 2013/03/28 22:19:21 ryao Exp $
 
 EAPI="4"
 AUTOTOOLS_AUTORECONF="1"
@@ -62,17 +62,8 @@
 
 	if [ ${PV} != "9999" ]
 	then
-		# Fix x86 build failures on Linux 3.4 and later, bug #450646
-		epatch "${FILESDIR}/${P}-fix-atomic64-checks.patch"
-
-		# Fix autotools check that fails on ~ppc64
-		epatch "${FILESDIR}/${P}-fix-mutex-owner-check.patch"
-
-		# Linux 3.9 Support
-		epatch "${FILESDIR}/${P}-linux-3.9-compat.patch"
-
-		# Free memory under load quickly
-		epatch "${FILESDIR}/${P}-no-cond_resched.patch"
+		# Be more like FreeBSD and Illumos when handling hostids
+		epatch "${FILESDIR}/${PN}-0.6.0_rc14-simplify-hostid-logic.patch"
 	fi
 
 	# splat is unnecessary unless we are debugging
@@ -106,19 +97,16 @@
 	dosym "$(basename $(echo "${ED}/usr/src/spl-"*))/${KV_FULL}" /usr/src/spl
 }
 
-src_test() {
-	if [[ ! -e /proc/modules ]]
-	then
-		die  "Missing /proc/modules"
-	elif [[ $UID -ne 0 ]]
-	then
-		ewarn "Cannot run make check tests with FEATURES=userpriv."
-		ewarn "Skipping make check tests."
-	elif grep -q '^spl ' /proc/modules
+pkg_postinst() {
+	linux-mod_pkg_postinst
+
+	# Remove old modules
+	if [ -d "${EROOT}lib/modules/${KV_FULL}/addon/spl" ]
 	then
-		ewarn "Cannot run make check tests with module spl loaded."
-		ewarn "Skipping make check tests."
-	else
-		autotools-utils_src_test
+		ewarn "${PN} now installs modules in ${EROOT}lib/modules/${KV_FULL}/extra/spl"
+		ewarn "Old modules were detected in ${EROOT}lib/modules/${KV_FULL}/addon/spl"
+		ewarn "Automatically removing old modules to avoid problems."
+		rm -r "${EROOT}lib/modules/${KV_FULL}/addon/spl" || die "Cannot remove modules"
+		rmdir --ignore-fail-on-non-empty "${EROOT}lib/modules/${KV_FULL}/addon"
 	fi
 }



1.51                 sys-kernel/spl/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-kernel/spl/ChangeLog?rev=1.51&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-kernel/spl/ChangeLog?rev=1.51&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-kernel/spl/ChangeLog?r1=1.50&r2=1.51

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-kernel/spl/ChangeLog,v
retrieving revision 1.50
retrieving revision 1.51
diff -u -r1.50 -r1.51
--- ChangeLog	23 Mar 2013 23:48:08 -0000	1.50
+++ ChangeLog	28 Mar 2013 22:19:21 -0000	1.51
@@ -1,6 +1,13 @@
 # ChangeLog for sys-kernel/spl
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-kernel/spl/ChangeLog,v 1.50 2013/03/23 23:48:08 ryao Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-kernel/spl/ChangeLog,v 1.51 2013/03/28 22:19:21 ryao Exp $
+
+*spl-0.6.1 (28 Mar 2013)
+
+  28 Mar 2013; Richard Yao <ryao@g.o>
+  +files/spl-0.6.0_rc14-simplify-hostid-logic.patch, +spl-0.6.1.ebuild,
+  spl-9999.ebuild:
+  Version bump to 0.6.1; Simplify hostid logic
 
 *spl-0.6.0_rc14-r3 (23 Mar 2013)
 



1.1                  sys-kernel/spl/spl-0.6.1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-kernel/spl/spl-0.6.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-kernel/spl/spl-0.6.1.ebuild?rev=1.1&content-type=text/plain

Index: spl-0.6.1.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-kernel/spl/spl-0.6.1.ebuild,v 1.1 2013/03/28 22:19:21 ryao Exp $

EAPI="4"
AUTOTOOLS_AUTORECONF="1"

inherit flag-o-matic linux-info linux-mod autotools-utils

if [[ ${PV} == "9999" ]] ; then
	inherit git-2
	EGIT_REPO_URI="git://github.com/zfsonlinux/${PN}.git"
else
	inherit eutils versionator
	MY_PV=$(replace_version_separator 3 '-')
	SRC_URI="https://github.com/zfsonlinux/${PN}/archive/${PN}-${MY_PV}.tar.gz"
	S="${WORKDIR}/${PN}-${PN}-${MY_PV}"
	KEYWORDS="~amd64"
fi

DESCRIPTION="The Solaris Porting Layer is a Linux kernel module which provides many of the Solaris kernel APIs"
HOMEPAGE="http://zfsonlinux.org/"

LICENSE="GPL-2"
SLOT="0"
IUSE="custom-cflags debug debug-log"
RESTRICT="test"

COMMON_DEPEND="virtual/awk"

DEPEND="${COMMON_DEPEND}"

RDEPEND="${COMMON_DEPEND}
	!sys-devel/spl"

AT_M4DIR="config"
AUTOTOOLS_IN_SOURCE_BUILD="1"

pkg_setup() {
	linux-info_pkg_setup
	CONFIG_CHECK="
		!DEBUG_LOCK_ALLOC
		!GRKERNSEC_HIDESYM
		MODULES
		KALLSYMS
		!PAX_KERNEXEC_PLUGIN_METHOD_OR
		ZLIB_DEFLATE
		ZLIB_INFLATE
	"

	kernel_is ge 2 6 26 || die "Linux 2.6.26 or newer required"

	[ ${PV} != "9999" ] && \
		{ kernel_is le 3 9 || die "Linux 3.9 is the latest supported version."; }

	check_extra_config
}

src_prepare() {
	# Workaround for hard coded path
	sed -i "s|/sbin/lsmod|/bin/lsmod|" scripts/check.sh || die

	if [ ${PV} != "9999" ]
	then
		# Be more like FreeBSD and Illumos when handling hostids
		epatch "${FILESDIR}/${PN}-0.6.0_rc14-simplify-hostid-logic.patch"
	fi

	# splat is unnecessary unless we are debugging
	use debug || sed -e 's/^subdir-m += splat$//' -i "${S}/module/Makefile.in"

	autotools-utils_src_prepare
}

src_configure() {
	use custom-cflags || strip-flags
	filter-ldflags -Wl,*

	set_arch_to_kernel
	local myeconfargs=(
		--bindir="${EPREFIX}/bin"
		--sbindir="${EPREFIX}/sbin"
		--with-config=all
		--with-linux="${KV_DIR}"
		--with-linux-obj="${KV_OUT_DIR}"
		$(use_enable debug)
		$(use_enable debug-log)
	)
	autotools-utils_src_configure
}

src_install() {
	autotools-utils_src_install
	dodoc AUTHORS DISCLAIMER README.markdown

	# Provide /usr/src/spl symlink for lustre
	dosym "$(basename $(echo "${ED}/usr/src/spl-"*))/${KV_FULL}" /usr/src/spl
}

pkg_postinst() {
	linux-mod_pkg_postinst

	# Remove old modules
	if [ -d "${EROOT}lib/modules/${KV_FULL}/addon/spl" ]
	then
		ewarn "${PN} now installs modules in ${EROOT}lib/modules/${KV_FULL}/extra/spl"
		ewarn "Old modules were detected in ${EROOT}lib/modules/${KV_FULL}/addon/spl"
		ewarn "Automatically removing old modules to avoid problems."
		rm -r "${EROOT}lib/modules/${KV_FULL}/addon/spl" || die "Cannot remove modules"
		rmdir --ignore-fail-on-non-empty "${EROOT}lib/modules/${KV_FULL}/addon"
	fi
}