[gentoo-commits] gentoo-x86 commit in app-text/evince: ChangeLog evince-2.20.2.ebuild

[Gilles Dartiguelongue (eva)]

eva         07/12/06 21:17:30

  Modified:             ChangeLog
  Added:                evince-2.20.2.ebuild
  Log:
  bump to 2.20.2
  (Portage version: 2.1.4_rc7)

Revision  Changes    Path
1.129                app-text/evince/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-text/evince/ChangeLog?rev=1.129&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-text/evince/ChangeLog?rev=1.129&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-text/evince/ChangeLog?r1=1.128&r2=1.129

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-text/evince/ChangeLog,v
retrieving revision 1.128
retrieving revision 1.129
diff -u -r1.128 -r1.129
--- ChangeLog	14 Nov 2007 22:13:55 -0000	1.128
+++ ChangeLog	6 Dec 2007 21:17:29 -0000	1.129
@@ -1,6 +1,11 @@
 # ChangeLog for app-text/evince
 # Copyright 1999-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-text/evince/ChangeLog,v 1.128 2007/11/14 22:13:55 dertobi123 Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-text/evince/ChangeLog,v 1.129 2007/12/06 21:17:29 eva Exp $
+
+*evince-2.20.2 (06 Dec 2007)
+
+  06 Dec 2007; Gilles Dartiguelongue <eva@g.o> +evince-2.20.2.ebuild:
+  bump to 2.20.2
 
   14 Nov 2007; Tobias Scherbaum <dertobi123@g.o>
   evince-2.20.1.ebuild:



1.1                  app-text/evince/evince-2.20.2.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-text/evince/evince-2.20.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-text/evince/evince-2.20.2.ebuild?rev=1.1&content-type=text/plain

Index: evince-2.20.2.ebuild
===================================================================
# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-text/evince/evince-2.20.2.ebuild,v 1.1 2007/12/06 21:17:29 eva Exp $

WANT_AUTOMAKE="1.9"
inherit eutils gnome2 autotools

DESCRIPTION="Simple document viewer for GNOME"
HOMEPAGE="http://www.gnome.org/projects/evince/"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd"
IUSE="dbus djvu doc dvi gnome t1lib tiff"

RDEPEND="
	dbus? ( >=dev-libs/dbus-glib-0.71 )
	>=x11-libs/gtk+-2.10
	gnome-base/gnome-keyring
	>=gnome-base/libgnomeui-2.14
	>=gnome-base/libgnome-2.14
	dev-libs/libxml2
	>=x11-themes/gnome-icon-theme-2.17.1
	>=gnome-base/gnome-vfs-2.0
	>=gnome-base/libglade-2
	>=dev-libs/glib-2
	gnome? ( >=gnome-base/nautilus-2.10 )
	>=app-text/poppler-bindings-0.6
	dvi? (
		virtual/tetex
		t1lib? ( >=media-libs/t1lib-5.0.0 )
	)
	tiff? ( >=media-libs/tiff-3.6 )
	>=gnome-base/gconf-2
	djvu? ( >=app-text/djvu-3.5.17 )
	virtual/ghostscript"

DEPEND="${RDEPEND}
	app-text/scrollkeeper
	>=app-text/gnome-doc-utils-0.3.2
	>=dev-util/pkgconfig-0.9
	>=sys-devel/automake-1.9
	>=dev-util/intltool-0.35"

DOCS="AUTHORS ChangeLog NEWS README TODO"
ELTCONF="--portage"
RESTRICT="test"

pkg_setup() {
	G2CONF="--disable-scrollkeeper \
		--enable-comics		\
		--enable-impress	\
		$(use_enable dbus)  \
		$(use_enable djvu)  \
		$(use_enable dvi)   \
		$(use_enable t1lib) \
		$(use_enable tiff)  \
		$(use_enable gnome nautilus)"

	if ! built_with_use app-text/poppler-bindings gtk; then
		einfo "Please re-emerge app-text/poppler-bindings with the gtk USE flag set"
		die "poppler-bindings needs gtk flag set"
	fi
}

src_unpack() {
	gnome2_src_unpack

	# Fix .desktop file so menu item shows up
	epatch "${FILESDIR}"/${PN}-0.7.1-display-menu.patch

	# Make dbus actually switchable
	epatch "${FILESDIR}"/${PN}-0.6.1-dbus-switch.patch

	cp aclocal.m4 old_macros.m4
	AT_M4DIR="." eautoreconf
}



-- 
gentoo-commits@g.o mailing list