[gentoo-commits] gentoo-x86 commit in net-wireless/blueman: ChangeLog blueman-1.10.ebuild

[Tiziano Mueller (dev-zero)]

dev-zero    09/04/23 08:01:42

  Modified:             ChangeLog
  Added:                blueman-1.10.ebuild
  Log:
  Version bump (bug #266901).
  (Portage version: 2.2_rc31/cvs/Linux x86_64)

Revision  Changes    Path
1.3                  net-wireless/blueman/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-wireless/blueman/ChangeLog?rev=1.3&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-wireless/blueman/ChangeLog?rev=1.3&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-wireless/blueman/ChangeLog?r1=1.2&r2=1.3

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-wireless/blueman/ChangeLog,v
retrieving revision 1.2
retrieving revision 1.3
diff -u -r1.2 -r1.3
--- ChangeLog	2 Mar 2009 09:49:03 -0000	1.2
+++ ChangeLog	23 Apr 2009 08:01:42 -0000	1.3
@@ -1,6 +1,11 @@
 # ChangeLog for net-wireless/blueman
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-wireless/blueman/ChangeLog,v 1.2 2009/03/02 09:49:03 dev-zero Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-wireless/blueman/ChangeLog,v 1.3 2009/04/23 08:01:42 dev-zero Exp $
+
+*blueman-1.10 (23 Apr 2009)
+
+  23 Apr 2009; Tiziano Müller <dev-zero@g.o> +blueman-1.10.ebuild:
+  Version bump (bug #266901).
 
   02 Mar 2009; Tiziano Müller <dev-zero@g.o> blueman-1.02.ebuild:
   Added gnome USE flag for gconf-python dependency. Added



1.1                  net-wireless/blueman/blueman-1.10.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-wireless/blueman/blueman-1.10.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-wireless/blueman/blueman-1.10.ebuild?rev=1.1&content-type=text/plain

Index: blueman-1.10.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-wireless/blueman/blueman-1.10.ebuild,v 1.1 2009/04/23 08:01:42 dev-zero Exp $

EAPI="2"

inherit multilib python

DESCRIPTION="GTK+ Bluetooth Manager, designed to be simple and intuitive for everyday bluetooth tasks."
HOMEPAGE="http://blueman-project.org/"
SRC_URI="http://download.tuxfamily.org/${PN}/${P}.tar.gz"
LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="gnome network nls"

CDEPEND="dev-libs/glib:2
	>=x11-libs/gtk+-2.12:2
	x11-libs/startup-notification
	>=dev-lang/python-2.5
	dev-python/pygobject
	net-wireless/bluez"
DEPEND="${CDEPEND}
	nls? ( dev-util/intltool sys-devel/gettext )
	dev-util/pkgconfig
	>=dev-python/pyrex-0.9.8"
RDEPEND="${CDEPEND}
	>=app-mobilephone/obex-data-server-0.4.4
	gnome-extra/policykit-gnome
	x11-misc/notification-daemon
	sys-apps/dbus
	dev-python/pygtk
	dev-python/notify-python
	dev-python/dbus-python
	gnome? ( dev-python/gconf-python )
	network? ( || ( net-dns/dnsmasq =net-misc/dhcp-3* ) )"

src_prepare() {
	# disable pyc compiling
	rm py-compile
	ln -s $(type -P true) py-compile
}

src_configure() {
	econf \
		--with-no-runtime-deps-check \
		$(use_enable nls)
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"
	dodoc AUTHORS ChangeLog NEWS README

	if ! use gnome ; then
		python_version
		rm "${D}/usr/$(get_libdir)/python${PYVER}/site-packages/blueman/plugins/config/Gconf.py"
	fi

	python_need_rebuild
}

pkg_postinst() {
	python_version
	python_mod_optimize /usr/$(get_libdir)/python${PYVER}/site-packages/blueman
}

pkg_postrm() {
	python_mod_cleanup
}