[gentoo-commits] repo/gentoo:master commit in: x11-misc/nitrogen/

[Jeroen Roovers]

commit:     9ea8c165defb5e798b2aa7be3b31ef95a82c4d76
Author:     Jeroen Roovers <jer <AT> gentoo <DOT> org>
AuthorDate: Thu Nov  7 22:09:42 2019 +0000
Commit:     Jeroen Roovers <jer <AT> gentoo <DOT> org>
CommitDate: Thu Nov  7 22:10:16 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=9ea8c165

x11-misc/nitrogen: Add live ebuild

Package-Manager: Portage-2.3.78, Repoman-2.3.17
Signed-off-by: Jeroen Roovers <jer <AT> gentoo.org>

 x11-misc/nitrogen/nitrogen-99999.ebuild | 52 +++++++++++++++++++++++++++++++++
 1 file changed, 52 insertions(+)

diff --git a/x11-misc/nitrogen/nitrogen-99999.ebuild b/x11-misc/nitrogen/nitrogen-99999.ebuild
new file mode 100644
index 00000000000..dec80fb27a1
--- /dev/null
+++ b/x11-misc/nitrogen/nitrogen-99999.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit autotools flag-o-matic git-r3 xdg-utils
+
+DESCRIPTION="A background browser and setter for X"
+HOMEPAGE="https://github.com/l3ib/nitrogen"
+EGIT_REPO_URI="https://github.com/l3ib/${PN}"
+
+IUSE="nls xinerama"
+KEYWORDS=""
+LICENSE="GPL-2"
+SLOT="0"
+
+RDEPEND="
+	>=dev-cpp/gtkmm-2.10:2.4
+	>=gnome-base/librsvg-2.20:2
+	>=x11-libs/gtk+-2.10:2
+	xinerama? ( x11-libs/libXinerama )
+"
+BDEPEND="
+	${RDEPEND}
+	virtual/pkgconfig
+	nls? ( sys-devel/gettext )
+	xinerama? ( x11-base/xorg-proto )
+"
+
+src_prepare() {
+	default
+
+	sed -i -e '/^UPDATE_DESKTOP/s#=.*#= :#g' data/Makefile.am || die
+
+	eautoreconf
+}
+
+src_configure() {
+	append-cxxflags -std=c++11
+	econf \
+		$(use_enable nls) \
+		$(use_enable xinerama)
+}
+
+pkg_postinst() {
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+}