[gentoo-commits] repo/gentoo:master commit in: net-misc/streamlink/

[Mart Raudsepp]

commit:     9be7115353ff7fe6aa3533309551d4f5664ab276
Author:     Mart Raudsepp <leio <AT> gentoo <DOT> org>
AuthorDate: Mon Feb 11 18:36:50 2019 +0000
Commit:     Mart Raudsepp <leio <AT> gentoo <DOT> org>
CommitDate: Mon Feb 11 19:24:40 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=9be71153

net-misc/streamlink: bump to 1.0.0

Closes: https://bugs.gentoo.org/677192
Package-Manager: Portage-2.3.52, Repoman-2.3.12
Signed-off-by: Mart Raudsepp <leio <AT> gentoo.org>

 net-misc/streamlink/Manifest                |  1 +
 net-misc/streamlink/streamlink-1.0.0.ebuild | 71 +++++++++++++++++++++++++++++
 2 files changed, 72 insertions(+)

diff --git a/net-misc/streamlink/Manifest b/net-misc/streamlink/Manifest
index 9c6a7457aeb..5396078b353 100644
--- a/net-misc/streamlink/Manifest
+++ b/net-misc/streamlink/Manifest
@@ -1 +1,2 @@
 DIST streamlink-0.14.2.tar.gz 643695 BLAKE2B ea28daac32903738206226bce85a4615338b6039be1e4cce18325e977112c3301d6e6ed90d1210f4f362c898397fd980c136a98d8a0d5ff7ee2b6c5cf077f2c6 SHA512 0d9f1db32915392f9d29bcfb40743058352a924435a8ee77f1218c108e937204e88041c908d2f93546beaa70e18db62c961ea31fbdd85c5e7e4315a18118e276
+DIST streamlink-1.0.0.tar.gz 674393 BLAKE2B 091272bae71f1e89cf14872578091a01f9d05ee372d4b9379e672280735c6800a33ae198bf019fbb3e970aa060ef059e5106e1be3a20602874be6206b6303bf6 SHA512 22ba96ac0ec27fe923b99898c45548df88ed3dda3bcbcb10b55fea145e20731eb8aa3a90212a5863b4ef5a7387d4bcf3d09d447ea2789762a8cf5eaa87f263d7

diff --git a/net-misc/streamlink/streamlink-1.0.0.ebuild b/net-misc/streamlink/streamlink-1.0.0.ebuild
new file mode 100644
index 00000000000..07f15c0c5a6
--- /dev/null
+++ b/net-misc/streamlink/streamlink-1.0.0.ebuild
@@ -0,0 +1,71 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python{2_7,3_4,3_5,3_6} )
+PYTHON_REQ_USE='xml(+),threads(+)'
+DISTUTILS_SINGLE_IMPL=1
+
+inherit distutils-r1
+
+DESCRIPTION="CLI for extracting streams from websites to a video player of your choice"
+HOMEPAGE="https://streamlink.github.io/"
+SRC_URI="https://github.com/${PN}/${PN}/releases/download/${PV}/${P}.tar.gz"
+
+KEYWORDS="~amd64 ~x86"
+LICENSE="BSD-2 Apache-2.0"
+SLOT="0"
+IUSE="doc test"
+
+# >=urllib3-1.23 only needed for python2, but requests pulls some version anyways, so we might as well guarantee at least that ver for py3 too
+RDEPEND="
+	virtual/python-futures[${PYTHON_USEDEP}]
+	virtual/python-singledispatch[${PYTHON_USEDEP}]
+	>dev-python/requests-2.21.0[${PYTHON_USEDEP}]
+	>=dev-python/urllib3-1.23[${PYTHON_USEDEP}]
+	dev-python/isodate[${PYTHON_USEDEP}]
+	dev-python/websocket-client[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep 'dev-python/backports-shutil_which[${PYTHON_USEDEP}]' 'python2*')
+	$(python_gen_cond_dep 'dev-python/backports-shutil_get_terminal_size[${PYTHON_USEDEP}]' 'python2*')
+	dev-python/pycountry[${PYTHON_USEDEP}]
+	>=dev-python/pycryptodome-3.4.3[${PYTHON_USEDEP}]
+"
+DEPEND="${RDEPEND}
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? (
+		dev-python/sphinx[${PYTHON_USEDEP}]
+		dev-python/docutils[${PYTHON_USEDEP}]
+		dev-python/recommonmark[${PYTHON_USEDEP}]
+	)
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/requests-mock[${PYTHON_USEDEP}]
+		dev-python/pytest[${PYTHON_USEDEP}]
+		dev-python/freezegun[${PYTHON_USEDEP}]
+	)"
+RDEPEND="${RDEPEND}
+	media-video/rtmpdump
+	virtual/ffmpeg
+"
+
+python_configure_all() {
+	# Avoid iso-639, iso3166 dependencies since we use pycountry.
+	export STREAMLINK_USE_PYCOUNTRY=1
+}
+
+python_compile_all() {
+	use doc && emake -C docs html man
+}
+
+python_test() {
+	esetup.py test
+}
+
+python_install_all() {
+	if use doc; then
+		local HTML_DOCS=( docs/_build/html/. )
+		doman docs/_build/man/*
+	fi
+	distutils-r1_python_install_all
+}