[gentoo-commits] repo/gentoo:master commit in: sys-auth/ssh-ldap-pubkey/

[Thomas Deutschmann]

commit:     1a2d49ef9bfb9c155f532a290a05acfe79b9c780
Author:     Thomas Deutschmann <whissi <AT> gentoo <DOT> org>
AuthorDate: Sat Aug  4 20:21:17 2018 +0000
Commit:     Thomas Deutschmann <whissi <AT> gentoo <DOT> org>
CommitDate: Sat Aug  4 20:21:17 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=1a2d49ef

sys-auth/ssh-ldap-pubkey: new package

Bug: https://bugs.gentoo.org/658044
Package-Manager: Portage-2.3.44, Repoman-2.3.10

 sys-auth/ssh-ldap-pubkey/Manifest                  |  1 +
 sys-auth/ssh-ldap-pubkey/metadata.xml              | 12 ++++
 .../ssh-ldap-pubkey/ssh-ldap-pubkey-1.3.0.ebuild   | 64 ++++++++++++++++++++++
 3 files changed, 77 insertions(+)

diff --git a/sys-auth/ssh-ldap-pubkey/Manifest b/sys-auth/ssh-ldap-pubkey/Manifest
new file mode 100644
index 00000000000..dc55673bcde
--- /dev/null
+++ b/sys-auth/ssh-ldap-pubkey/Manifest
@@ -0,0 +1 @@
+DIST ssh-ldap-pubkey-1.3.0.tar.gz 14530 BLAKE2B 1de6913e4abb25d441731b3c36b64361f5fa8900c289b1f4ef58776ab0018414d20b4b24716833e1e27e5dc18079ec77c283bab88879e3fb719fc9ad054267ea SHA512 0c675b0bf68ccecdabda5f4f559772fd0d34151794c2a3855e063befffe9777ceb79e99b5649f15e5bd0c4ea40c22f734d1748a8053d49bffea58077b72efe16

diff --git a/sys-auth/ssh-ldap-pubkey/metadata.xml b/sys-auth/ssh-ldap-pubkey/metadata.xml
new file mode 100644
index 00000000000..798419df911
--- /dev/null
+++ b/sys-auth/ssh-ldap-pubkey/metadata.xml
@@ -0,0 +1,12 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="project">
+		<email>base-system@g.o</email>
+		<name>Gentoo Base System</name>
+	</maintainer>
+	<upstream>
+		<bugs-to>https://github.com/jirutka/ssh-ldap-pubkey/issues</bugs-to>
+		<remote-id type="github">jirutka/ssh-ldap-pubkey</remote-id>
+	</upstream>
+</pkgmetadata>

diff --git a/sys-auth/ssh-ldap-pubkey/ssh-ldap-pubkey-1.3.0.ebuild b/sys-auth/ssh-ldap-pubkey/ssh-ldap-pubkey-1.3.0.ebuild
new file mode 100644
index 00000000000..861c41ba1ef
--- /dev/null
+++ b/sys-auth/ssh-ldap-pubkey/ssh-ldap-pubkey-1.3.0.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="6"
+
+PYTHON_COMPAT=( python2_7 python3_{4,5,6} )
+inherit distutils-r1
+
+DESCRIPTION="Utility to manage SSH public keys stored in LDAP"
+HOMEPAGE="https://github.com/jirutka/ssh-ldap-pubkey"
+
+if [[ ${PV} == "9999" ]]; then
+	EGIT_REPO_URI="https://github.com/jirutka/${PN}/${PN}.git"
+
+	inherit git-r3
+else
+	SRC_URI="https://github.com/jirutka/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+LICENSE="MIT"
+SLOT="0"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+MY_CDEPEND="
+	dev-python/docopt[${PYTHON_USEDEP}]
+	dev-python/pyldap[${PYTHON_USEDEP}]
+	virtual/logger"
+
+DEPEND="
+	${MY_CDEPEND}
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	test? (
+		dev-python/pytest[${PYTHON_USEDEP}]
+		dev-python/pytest-describe[${PYTHON_USEDEP}]
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+	)"
+
+# We need to block previous net-misc/openssh packages
+# to avoid file collision on "/etc/openldap/schema/openssh-lpk.schema"
+RDEPEND="${MY_CDEPEND}
+	!net-misc/openssh[ldap]"
+
+DOCS=( README.md CHANGELOG.adoc )
+
+python_test() {
+	pytest -vv || die "Tests failed under ${EPYTHON}"
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	insinto /etc/openldap/schema
+	doins etc/openssh-lpk.schema
+
+	local MY_DOCDIR="/usr/share/doc/${PF}/examples"
+	insinto "${MY_DOCDIR}"
+	doins etc/ldap.conf
+
+	# We don't want to compress this small file to allow user
+	# to diff configuration against upstream's default
+	docompress -x "${MY_DOCDIR}"
+}